엑셀 숨은 함수 4가지 — GESTEP·REPT·CONVERT·ROMAN (ft. AI로 최적 함수 찾는 법)

목표 달성 여부 판정(GESTEP), 셀 안의 미니 막대 차트(REPT), 단위 변환(CONVERT), 로마 숫자 자동 번호(ROMAN + SEQUENCE). 이름은 낯설어도 실무에서 바로 쓸 수 있는 함수 네 가지를 예제와 함께 정리합니다.

이번 영상에서 습득할 수 있는 주요 내용

26년 경력 Microsoft MVP 권현욱(엑셀러) 지음 얼리버드 11월 20일까지

📈 신간 전자책(PDF) · 375쪽 · 12,000원9,500원

AI도 알려주지 않는 엑셀 고급 차트, 클릭 순서까지 그대로 따라 만듭니다

• 머릿속 아이디어를 실제 차트로 구현
• 스파크라인·히트맵부터 폭포·덤벨·간트·게이지까지 55개 레슨
• 중간마진 없는 합리적인 가격 / 오직 아이엑셀러에서만!

완성 차트 미리보기 지금 구매하기

1. GESTEP: 목표 달성 여부 판정

4개 팀, 수십 명의 실적이 집계되어 있는 데이터가 있습니다. 목표를 달성한 사람을 좀 더 직관적으로 파악하고자 합니다.

간단한 함수 하나면 해결할 수 있습니다. 바로 GESTEP("지이스텝"이라고 읽습니다) 함수입니다. Microsoft는 이 함수 이름의 뜻을 따로 풀어서 소개하지 않지만, Greater than or Equal to STEP, 즉 "기준값 이상인가?"의 줄임말로 이해하면 기억하기 쉽습니다.

사용법은 아주 간단합니다. 앞에는 판정할 값(월 실적), 뒤에는 기준값(월 목표)을 넣습니다. 실적이 목표 이상이면 1, 미만이면 0을 돌려줍니다.

G5: =GESTEP(F5,E5)

단순히 결과를 구하는 것이 목적이라면 IF 함수를 사용해도 됩니다. 하지만 GESTEP은 더 짧고, 함수 이름만 봐도 "기준 이상인지 확인하는구나" 하고 의도를 바로 파악할 수 있습니다.

=IF(F5>=E5,1,0)

더 짧게 비교식만 쓸 수도 있습니다.

=F5>=E5

하지만 결과가 TRUE, FALSE인 논리값이라 SUM으로 합계를 구할 수 없습니다. 반면 GESTEP은 1과 0을 돌려주므로 바로 SUM으로 셀 수 있습니다.

L6: =SUM(G5:G40)   → 20 (36명 중 20명 달성)
L7: =L6/L5         → 56% (L5의 전체 인원 36명 대비 달성 비율)

달성 인원을 세려고 따로 COUNTIF를 쓸 필요가 없습니다.

2. REPT: 셀 안의 미니 차트

두 번째는 REPT(Repeat)입니다. 지정한 문자를 지정한 횟수만큼 반복하는 평범한 함수인데, 이를 이용하면 셀 안에 막대 차트를 만들 수 있습니다.

달성률을 열 칸짜리 막대로 바꿉니다.

I5: =REPT("■",INT(MIN(1,H5)*10))&REPT("□",10-INT(MIN(1,H5)*10))

수식이 길어 보이지만 구조는 단순합니다. 달성률에 10을 곱해 채울 칸 수를 정하고, 채운 만큼은 검은 사각형, 나머지는 빈 사각형으로 이어 붙인 것입니다. 중간의 MIN 함수는 100%를 넘는 담당자 때문에 넣었습니다. MIN이 없으면 빈 칸 수가 음수가 되어 #VALUE! 오류가 나기 때문입니다.

수식에서 사용된 특수문자(■, □)는 어떻게 입력하나요?

ROUND가 아니라 INT 함수를 사용한 이유

어느 담당의 달성률이 96%인 경우, ROUND를 쓰면 9.6이 10으로 올라가 열 칸이 꽉 차 보입니다. 달성하지 못했는데 달성한 것처럼 보이는 셈입니다. INT는 소수점 아래를 버리므로 아홉 칸이 됩니다. 데이터 시각화에서는 이런 작은 차이를 파악하고 대처 방법을 마련해 두는 것이 중요합니다.

3. CONVERT: 단위 변환

세 번째는 단위를 바꿔 주는 CONVERT입니다. 해외에서 가구를 수입하는 업체가 미국 공급사에서 SKU별 규격표를 받았습니다. 가로·세로·높이는 인치, 무게는 파운드로 되어 있는데, 우리는 센티미터와 킬로그램으로 봐야 합니다.

이때 핵심은 단위를 수식 안에 쓰지 않고 셀로 빼 두는 것입니다.

CONVERT는 변환할 값, 원래 단위, 바꿀 단위 순서로 입력합니다.

G9: =CONVERT(C9,$B$3,$B$4)    → 가로 (18in → 45.72cm)
J9: =CONVERT(F9,$B$5,$B$6)    → 무게 (14lbm → 약 6.35kg)

G9의 수식을 오른쪽으로 복사해 세로와 높이도 채우고, 무게는 단위 셀이 다르므로 참조만 바꿉니다. 이렇게 만든 네 열을 아래로 채우면 끝입니다.

수식은 그대로, 단위만 바꾸기

이제 길이 단위 셀(B4)을 cm에서 m으로 바꿔 보겠습니다. 수식은 하나도 건드리지 않았는데 가로·세로·높이가 전부 미터로 바뀝니다. 피트(ft)나 야드(yd)도 단위 셀만 바꾸면 됩니다. 데이터 유효성 검사(목록)로 드롭다운을 만들어 두면 선택만으로 단위를 바꿀 수 있어 더 편리합니다.

4. ROMAN + SEQUENCE: 로마 숫자 자동 생성

다음은, 숫자를 로마 숫자로 바꿔 주는 ROMAN입니다. '목차' 시트는 영업관리 업무 매뉴얼의 목차인데, 장이 30개이고 장 번호 칸이 비어 있습니다. 여기에 로마자 번호를 매겨 보겠습니다.

기본 사용법은 간단합니다.

=ROMAN(3)   → III

이것만으로는 편리함이 와닿지 않을 수 있습니다. SEQUENCE 함수와 만나면 아주 강력해집니다. 다음과 같이 입력하고 Enter를 누르면 I부터 X까지 열 개가 한 번에 만들어집니다.

A5: =ROMAN(SEQUENCE(10))

SEQUENCE가 1부터 10까지 숫자를 만들고, ROMAN이 한꺼번에 변환한 것입니다. 그런데 장이 30개이니, 숫자 10을 고치는 대신 또 다른 함수를 추가하여 자동화 하겠습니다. 우리가 잘 알고 있는 COUNTA 함수를 사용하면 됩니다.

A5: =ROMAN(SEQUENCE(COUNTA(B5:B34)))

이렇게 하면 제목 수만큼 정확히 만들어집니다. 장이 늘어나더라도 범위만 넓혀 주면 번호가 알아서 따라옵니다.

=ROMAN(ROW()-4)

5. AI로 함수 찾기 [멤버십 회원용]

여기까지 네 개의 함수를 살펴봤지만, 이 함수들도 이름을 알아야 쓸 수 있습니다. 그렇다면 이름을 모르는 함수는 쓸 수 없는 걸까요?

멤버십 전용 풀 버전에서는 이 질문에 대한 답을 보여드립니다. 함수 이름을 전혀 몰라도 AI의 도움으로 원하는 함수를 찾아내고, 업무에 바로 적용하는 과정을 실제 업무 예제로 처음부터 끝까지 따라가 봅니다. 같은 AI를 쓰는데도 어떤 사람은 정확한 수식을 받고 어떤 사람은 엉뚱한 답을 받는 이유가 어디에 있는지도 확인하실 수 있습니다.

MVP TIP — 숨은 함수를 내 것으로 만드는 법

1. 함수 이름을 외우지 말고, 찾아보는 습관을 들이세요

500개가 넘는 함수를 다 외울 필요는 없습니다(그럴 수도 없습니다). '이런 걸 해 주는 함수가 있지 않을까?'라는 생각이 들 때 검색하거나 AI에게 물어보는 습관이면 충분합니다.

2. 바뀔 수 있는 값은 셀로 빼 두세요

CONVERT의 단위처럼 나중에 바뀔 수 있는 값을 수식에 직접 쓰지 않고 셀에서 참조하면, 수식을 건드리지 않고 결과를 바꿀 수 있습니다. 같은 원리로 ROMAN 예제의 숫자 10을 COUNTA로 대체한 것도 하드코딩을 피하는 방법입니다.

3. AI가 준 결과(수식)는 반드시 직접 확인하세요

AI가 알려준 수식이라도 결과가 맞는지는 내 눈으로 확인해야 합니다. 함수 이름을 모를 때 AI에게 제대로 물어보는 방법은 멤버십 회원용 풀 버전에서 다룹니다.

자주 묻는 질문 (FAQ)

마치며

오늘 소개한 네 개 함수는 하나하나는 작아 보여도, 알고 나면 일이 줄어듭니다. 이제 예전처럼 무조건 많은 함수를 외우려고 할 필요는 없습니다. 찾아보는 습관과 AI를 활용하세요. 그렇다면 이름조차 모르는 함수는 어떻게 찾아야 할까요? 멤버십 회원용 풀 버전에서 이어서 확인해보세요.