매크로 실행 취소 관련 아이디어 두 가지

내용을 지우는 매크로와 실행 취소 문제

어쩌다보니 최근에는 Excel 강좌를, 그것도 차트에 대한 것들만 주야장천(?)으로 올렸습니다. 해서 모처럼 만에 VBA 강좌를 올립니다. 그렇다고 'VBA로 차트 건드리기'를 주제로 할까요?(설마...)

아래와 같은 데이터가 있다고 할 때, 빨간 네모 안의 내용을 삭제하려면 ClearContents 메서드를 이용합니다. 빨간 네모 영역에 'MyRange'라는 이름을 미리 정의해 두었습니다.

"내용 지우기" 버튼을 클릭하면 지정한 영역 안의 내용이 말끔히 지워집니다. "내용 지우기" 버튼에 연결된 코드는 이렇습니다. 코드는 따로 설명을 하고 말고 할 것도 없을 만큼 단순합니다.

Sub ClearData()
    Range("MyRange").ClearContents
End Sub

문제는 이렇게 매크로(VBA도 마찬가지)를 이용하여 작업을 한 경우, '실행 취소(UnDo)'가 되지 않는다는 겁니다. 어떻게 하면 좋을까요?

방법 1: SendKeys 메서드 이용

예제 파일에서 "지우기: SendKeys"와 "복구하기: SendKeys" 버튼을 차례로 눌러 보세요. 빨간 네모 상자 안(MyRange)의 내용이 지워졌다가 다시 나타나지요?

버튼에 연결된 코드입니다.

Sub ClearBySendKeys()                ' [지우기: SendKeys] 버튼에 연결된 코드
    Range("MyRange").Select          ' MyRange 영역을 선택하고...
    Application.SendKeys "{DELETE}"  ' SendKeys 메서드를 이용하여 <Del> 키를
End Sub                              ' 누른 것과 같은 효과를 줍니다.

Sub RecoverBySendKeys()              ' [복구하기: SendKeys] 버튼에 연결된 코드
    Application.SendKeys "^z"        ' SendKeys 메서드를 이용하여 <Ctrl>+z 키를
End Sub                              ' 누른 것과 같은 효과를 줍니다.

Application.SendKeys "^z" 대신 Undo 메서드를 사용하여 다음과 같이 해도 됩니다.

Application.Undo

방법 2: 배열(Array) 이용

이번에는 맨 아래에 있는 "지우기/복구하기" 버튼을 눌러 보세요. MyRange 범위 내의 데이터가 지워진 다음 MsgBox가 나타납니다. "예" 버튼을 클릭하면 지워졌던 데이터가 다시 나타납니다.

"지우기/복구하기" 버튼에 연결된 코드를 살펴볼까요.

Sub ClearAndRecoverData()
    Dim i As Integer                    ' For~Next 문에서 사용할 변수
    Dim intNum As Integer               ' 선택 영역의 셀 수를 카운팅하기 위한 변수
    Dim strCell() As String             ' 각 셀의 내용을 저장할 동적 배열 변수
    Dim strYesNo As String              ' MsgBox의 선택 결과를 저장할 변수
    Dim rngTarget As Range              ' 작업 대상 범위를 지정할 변수(빨간 네모 부분)

    Set rngTarget = Range("MyRange")    ' 작업 대상 범위를 변수에 할당
    intNum = rngTarget.Cells.Count      ' 작업 대상 범위의 셀 수 카운팅
    ReDim strCell(intNum)               ' 동적 배열의 크기 지정

    For i = 1 To intNum                 ' 선택된 영역의 셀 수만큼 반복 실행
        strCell(i) = rngTarget.Cells(i) ' 각 셀의 값을 배열 변수에 차례로 저장
    Next i

    rngTarget.ClearContents             ' 작업 대상 범위의 내용을 지움

    strYesNo = MsgBox("내용을 지웠습니다. 원래대로 돌릴까요?", vbYesNo)
    If strYesNo = vbNo Then Exit Sub

    With rngTarget                      ' 작업 대상 영역에 대하여...
        For i = 1 To intNum             ' 선택된 영역의 셀 수만큼 반복 실행
            .Cells(i) = strCell(i)      ' 배열 변수에 있던 값을 각 셀에 표시
        Next i
    End With
End Sub

SendKeys 메서드를 사용했을 때보다 복잡해 보입니다만, 배열 변수를 이용하면 다양한 상황에 적용할 수 있는 장점이 있으니 잘 익혀두시기 바랍니다.

정리 — 매크로 실행 취소 두 가지 방법

방법	핵심 코드	특징
방법 1 SendKeys	Application.SendKeys "{DELETE}" / "^z", Application.Undo	키 입력을 흉내 내는 방식으로 코드가 간단
방법 2 배열	셀 값을 배열에 저장 → ClearContents → MsgBox 응답에 따라 복구	코드는 길지만 다양한 상황에 적용 가능

자주 묻는 질문 (FAQ)

마치며

매크로로 작업한 내용은 기본적으로 되돌릴 수 없으니, 필요할 때는 SendKeys나 배열로 복구 장치를 마련해 두세요.
VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 닷컴 사이트 정문 왼쪽에 있는 'VBA 강좌 - VBA 입문강좌'를 읽어보시면 이해가 빠릅니다.