하위 폴더를 검색하고 하이퍼링크로 연결하는 Code

폴더 검색하기 버튼 실행해 보기

예제 파일의 '폴더 검색하기' 버튼을 클릭하면 InputBox가 나타납니다. 폴더명을 입력하면 지정한 폴더에서 확장자가 'xlsm'이거나 'xlsx'인 파일들이 표시됩니다. 폴더 아래에 있는 하위 폴더들까지 모두 검색하여 워크시트에 표시해 줍니다.

그냥 화면에 표시만 해주는 것이 아니라 하이퍼링크가 자동으로 설정되므로 파일 이름을 클릭하면 해당 파일이 열립니다.

'폴더 검색하기' 버튼에 연결된 코드

'폴더 검색하기' 버튼에 연결된 코드를 보도록 하죠.

Dim r As Long          ' 여러 프로시저에서 공통적으로 사용할 변수를 프로시저 외부에 선언

Sub SearchSubFolder()
    Dim strFolder As String        ' 폴더 이름을 저장할 변수

    strFolder = InputBox(prompt:="검색할 폴더를 입력하세요", _
        Default:=ThisWorkbook.Path & "\")
        ' InputBox 함수를 이용하여 검색할 폴더를 입력받음.
        ' Default 인수를 지정하여 디폴트 값이 대화상자에 표시되도록 함.

    If strFolder = "" Then        ' 만약 '취소' 버튼을 눌렀다면 프로시저 실행 종료
        MsgBox "아무 폴더도 선택되지 않았으므로 종료합니다"
        Exit Sub
    End If

    If Right(strFolder, 1) <> "\" Then strFolder = strFolder & "\"
                                  ' 폴더명 뒤에 '\' 표시를 붙이지 않았다면 추가
    Worksheets.Add after:=Sheets(1)    ' 첫 번째 시트 뒤에 새로운 워크시트 추가
    r = 1                         ' 변수 r값 지정

    ' A1:C1 영역에 표의 제목을 입력하고 서식 지정
    Cells(r, 1) = "파일명"
    Cells(r, 2) = "크기"
    Cells(r, 3) = "작성일자"
    Range("a1:c1").Font.Name = "Arial"
    Columns("A").ColumnWidth = 60
    Columns("A").ShrinkToFit = True
    Columns("C").ColumnWidth = 16

    RecursiveCall strFolder    ' 외부 프로시저를 호출함. 이 때 strFolder 값 함께 전달
End Sub

핵심은 RecursiveCall 프로시저

중요한 것은 프로시저 마지막에 호출한 'RecursiveCall'이라는 외부 프로시저입니다.

Sub RecursiveCall(Path As String)
    Dim i As Integer               ' For ~ Next 문에서 사용할 Flag 변수
    Dim intFolder As Integer
    Dim strFile As String          ' 파일 이름을 저장할 변수
    Dim strFolder() As String      ' 하위 폴더가 있을 경우를 대비하여 동적 배열 변수로 선언
    Dim strTemp As String          ' 파일 확장자에 접근하기 위한 임시 문자열 변수

    strFile = Dir(Path)            ' 지정한 폴더에 있는 첫 번째 파일을 변수에 지정

    Do While strFile <> ""         ' 폴더 내에 파일이 있는 동안 순환문 반복 실행
        strTemp = Split(Path & strFile, ".")(1)
        ' Split 함수를 이용하여 첫 번째 콤마 이후 부분(즉 확장자)을 추출하고 변수에 저장

        If strTemp = "xlsm" Or strTemp = "xlsx" Then
        ' Split 함수로 분리해 낸 문자열 값이 xlsm 또는 xlsx이면...

            strTemp = ActiveCell.Offset(r, 0).Value
            ' 활성화 된 셀에서 1행 이동한 셀 값을 strTemp 변수에  저장

            With ActiveCell        ' 활성화 된 셀에 대하여...
                .Offset(r, 0) = Path & strFile
                ' 행 방향으로 1, 열 방향으로 0만큼 이동한 셀에 폴더명과 파일명 표시

                ActiveSheet.Hyperlinks.Add Anchor:=ActiveCell.Offset(r, 0), _
                    Address:=ActiveCell.Offset(r, 0).Value, TextToDisplay:=strTemp
                    ' 같은 셀에 하이퍼링크 설정

                .Offset(r, 1) = FileLen(Path & strFile)       ' 같은 행 1열 옆에 파일 길이 표시
                .Offset(r, 2) = FileDateTime(Path & strFile)  ' 같은 행 2열 옆에 파일 생성 일자 표시
            End With

            r = r + 1            ' 다음 작업을 위해 변수 값 1증가
        End If

        strFile = Dir()          ' 다음 파일 검색
    Loop

    strFile = Dir(Path, vbDirectory)

    Do While strFile <> ""       ' 하위 폴더 검색
        If strFile <> "." And strFile <> ".." Then
        ' 폴더명이 '.' 또는 '..'가 아닌 경우에만 다음 명령을 실행함.

            ' 하위 폴더가 발견될 때마다 동적 배열 변수에 담아둠.
            If GetAttr(Path & strFile) = vbDirectory Then  ' 하위 폴더가 있다면...
                intFolder = intFolder + 1                  ' 변수 값 1 증가
                ReDim Preserve strFolder(intFolder)        ' 동적 배열의 크기 재지정(기존 내용은 보존)
                strFolder(intFolder) = Path & strFile      ' 하위 폴더 경로를 배열에 저장
            End If
        End If
        strFile = Dir()
    Loop

    For i = 1 To intFolder                   ' 발견된 하위 폴더 수만큼 반복 실행
        RecursiveCall strFolder(i) & "\"     ' 자기가 자기를 불러오는 재귀적 호출
    Next i
End Sub

이 코드에서는 'RecursiveCall strFolder(i)' 이 부분이 핵심입니다. "재귀적(Recursive) 방식"에 의해서 폴더 내에 하위 폴더 수만큼 "자기 자신을 다시 호출하는 구조"입니다. 이 때 폴더명 뒤에 '\' 표시를 붙여주어야 에러가 생기지 않는다는 점에 유의하세요!

정리 — 하위 폴더 검색 코드의 구성

구성 요소	역할
SearchSubFolder	InputBox로 폴더를 입력받고 새 워크시트와 제목 행을 만든 뒤 RecursiveCall 호출
RecursiveCall	Dir 함수로 xlsx, xlsm 파일을 찾아 하이퍼링크와 함께 표시하고, 하위 폴더 수만큼 자기 자신을 다시 호출
Hyperlinks.Add	파일 경로 셀에 하이퍼링크를 설정하여 클릭하면 파일이 열리게 함
모듈 수준 변수 r	여러 프로시저가 함께 사용하는 결과 행 번호 카운터

자주 묻는 질문 (FAQ)

마치며

재귀 호출만 이해하면 아무리 깊은 폴더 구조도 코드 몇 줄로 훑을 수 있습니다. 디버깅 도구로 한 단계씩 따라가 보세요!
VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 닷컴 사이트 정문 왼쪽에 있는 'VBA 강좌 - VBA 입문강좌'를 읽어보시면 이해가 빠릅니다.