여러 제품 차트를 한꺼번에 만들어 주는 Code

멀티 차트란?

예제 파일에서 그룹 상자 안에 있는 옵션 버튼을 클릭하면 A3:F12 영역의 데이터를 이용하여 각 팀의 제품 유형별 실적을 보여주는 여러 개의 차트가 한꺼번에 만들어집니다. 이러한 차트를 '멀티 차트(Multi-chart)'라고 이름 붙여 보았습니다.

Step 1: 주 프로시저 코딩

(1) '개발 도구 - 삽입' 메뉴를 선택하고 '그룹 상자' 안에 세 개의 '옵션 단추'를 삽입합니다. 이 때 '그룹 상자'는 '양식 컨트롤'을, '옵션 단추'는 'ActiveX 컨트롤'에 있는 것을 사용한 것에 유의하세요.

(2) 삽입한 ActiveX 컨트롤의 속성은 해당 컨트롤을 더블 클릭하면 나타나는 '속성 창'에서 변경할 수 있습니다. 다른 부분은 그냥 두고 'Caption' 속성만 위 그림과 같이 원형, 3차원 원형, 도넛형으로 각각 지정합니다.

(3) 'Sheet1' 개체를 더블 클릭한 다음 코드 창에 다음과 같이 세 개의 프로시저를 작성합니다. 이 프로시저들은 워크시트에 작성되어 있는 ActiveX 컨트롤을 클릭했을 때 실행되는 프로시저입니다. 하위 프로시저(MakeMultiChart)를 불러와서 실행하며, 이 때 어떤 형태의 차트를 작성할지에 대한 정보를 함께 건네줍니다.

Private Sub OptionButton1_Click()
    MakeMultiChart xlPie          ' 원형 차트
End Sub

Private Sub OptionButton2_Click()
    MakeMultiChart xl3DPie        ' 3차원 원형 차트
End Sub

Private Sub OptionButton3_Click()
    MakeMultiChart xlDoughnut     ' 도넛형 차트
End Sub

Step 2: 하위 프로시저 코딩

(1) Visual Basic Editor 상태(<Alt> + <F11>)에서 모듈을 하나 삽입하고 다음 코드를 작성합니다.

Sub MakeMultiChart(intX)
' 이 프로시저는 다른 외부 프로시저에서 호출하는 형태로 사용됩니다. 즉, 주 프로시저에 의해
' 호출되는 하위(또는 종속) 프로시저입니다. 이 때 주 프로시저로부터 매개 변수(intX)를
' 전달받아서 실행합니다.

    Dim rngSource As Range            ' 차트 영역 지정을 위한 개체 변수
    Dim shtSheet As Worksheet         ' 워크시트 개체에 접근하기 위한 개체 변수
    Dim i As Integer                  ' For ~ Next 문에서 사용되는 변수
    Dim intRow As Integer             ' 차트 계열 수를 카운팅 할 변수
    Dim intLeft As Integer            ' 차트의 왼쪽 끝 위치를 지정할 변수
    Dim intTop As Integer             ' 차트의 위쪽 끝 위치를 지정할 변수
    Dim lngWidth As Long              ' 차트의 너비를 지정할 변수
    Dim lngHeight As Long             ' 차트의 높이를 지정할 변수

    ' 만들려는 시트와 같은 시트가 이미 있으면 지우기 위한 부분임.
    On Error Resume Next
    Application.DisplayAlerts = False
    Worksheets("다중차트").Delete
    Application.DisplayAlerts = True
    On Error GoTo 0

    Set rngSource = Range("Start").CurrentRegion    ' 차트 작성 영역 지정
    intRow = rngSource.Rows.Count       ' 테이블의 행 수를 카운팅하여 변수에 저장
    Set shtSheet = Worksheets.Add       ' 새로운 워크시트를 변수에 할당
    ActiveSheet.Name = "다중차트"        ' 시트 이름 지정
    lngWidth = Range("A1").Width        ' 차트의 너비 크기 지정
    lngHeight = Range("A1").Height      ' 차트의 높이 크기 지정

    For i = 4 To intRow + 2             ' 데이터 수만큼 For ~ Next 문 반복
        With Worksheets("Source")
            Set rngSource = Union(.Range("A3:F3"), .Range(.Cells(i, 1), .Cells(i, 6)))
            ' 팀별로 차트를 만들기 위해 표의 제목 부분과 실적 부분을 Union 메서드를
            ' 이용하여 생성함
        End With

        With shtSheet.Shapes.AddChart2(201, intX, intLeft, intTop, lngWidth * 5, lngHeight * 12).Chart
        ' 지정한 위치에, 지정한 크기로 차트 생성. 이 때 작성되는 차트의 형태는
        ' 매개 변수로 전달받은 intX에 의해 결정됨

            .SetSourceData rngSource
            .SeriesCollection(1).ApplyDataLabels ShowCategoryName:=True, _
                ShowPercentage:=True, ShowValue:=False
            .ChartColor = 15
            .ChartTitle.Font.Size = 12
            .ChartTitle.Font.Bold = True
            .Legend.Delete
        End With

        ' 차트를 한 행에 3개씩 표시하기 위해 Mod 함수를 사용함.
        If (i - 1) Mod 3 = 2 Then
            intLeft = 0                       ' 차트 왼쪽 위치 값 초기화
            intTop = intTop + lngHeight * 12  ' 아래로 이동하기 위해 intTop 변수 값은 증가시킴
        Else                                  ' 그렇지 않으면...
            intLeft = intLeft + lngWidth * 5  ' 차트를 지정한 크기만큼 옆으로 옮기기 위해
                                              ' intLeft 변수 값만 증가시킴.
        End If
    Next i
End Sub

(2) 'Source' 시트로 가서 '옵션 단추'를 클릭하면 지정한 차트가 '다중 차트' 시트에 한꺼번에 작성됩니다. 만약 프로시저가 실행되지는 않고 옵션 버튼이 선택되기만 한다면 '개발 도구'의 '디자인 모드' 아이콘을 클릭하여 선택 모드를 해제하세요.

정리 — 멀티 차트 만들기 코드의 구성

구성 요소	역할
옵션 단추 Click 프로시저 (주 프로시저)	선택한 차트 유형(원형, 3차원 원형, 도넛형)을 인수로 MakeMultiChart 호출
MakeMultiChart (하위 프로시저)	'다중차트' 시트를 새로 만들고 팀 수만큼 차트를 작성
Union 메서드	표의 제목 행과 각 팀의 실적 행을 하나의 차트 원본 범위로 묶음
AddChart2 메서드	지정한 위치와 크기, 유형으로 차트 생성
Mod 연산자	차트를 한 행에 3개씩 배치하도록 위치 변수 조정
디자인 모드	해제해야 옵션 단추 클릭 시 프로시저가 실행됨

자주 묻는 질문 (FAQ)

마치며

차트를 하나씩 만들던 수고가 옵션 단추 한 번으로 끝납니다. 예제 파일에서 직접 눌러 보세요!
VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 닷컴 사이트 정문 왼쪽에 있는 'VBA 강좌 - VBA 입문강좌'를 읽어보시면 이해가 빠릅니다.