선택한 영역 바깥 쪽은 숨기는 Code

선택한 부분만 남기고 나머지 숨기기

범위를 지정하고 단축키를 누르면 선택한 부분만 남겨두고 나머지 영역은 모두 숨기는 코드를 작성해 보겠습니다. 단축키를 한 번 더 누르면 숨겨졌던 영역이 다시 나타납니다.

Step 1: 코드 작성

Visual Basic Editor 상태(<Alt> + <F11>)에서 모듈을 삽입하고 코드를 작성합니다. VBA 강좌를 보시는 분 중에 이게 무슨 말인지 모르는 분은 설마 없으리라 생각합니다. ^^;

Sub HideArea()
    Dim lngRowStart As Long      ' 남겨 둘 영역의 행 시작 위치
    Dim lngRowEnd As Long        ' 남겨 둘 영역의 행 끝 위치
    Dim lngColStart As Long      ' 남겨 둘 영역의 열 시작 위치
    Dim lngColEnd As Long        ' 남겨 둘 영역의 열 끝 위치
    On Error GoTo ET             ' 오류 발생 시 ET 레이블로 이동

    ' 특정한 영역이 이미 숨겨져 있는 경우, 이 영역을 표시해 주기 위한 부분임.
    ' 마지막 행이나 열이 숨겨져 있을 경우, EntireRow나 EntireColumn의
    ' Hidden 속성 값을 False로 설정하면 숨겨진 영역이 화면에 표시됨.
    If Rows(Rows.Count).EntireRow.Hidden Or _
            Columns(Columns.Count).EntireColumn.Hidden Then
        Cells.EntireRow.Hidden = False
        Cells.EntireColumn.Hidden = False
        Exit Sub
    End If

    ' 선택된 영역의 첫 번째 행 번호, 마지막 행 번호, 첫 번째 열 번호, 마지막 열 번호를
    ' 각각의 변수에 할당(저장)함.
    lngRowStart = Selection.Rows(1).Row
    lngRowEnd = lngRowStart + Selection.Rows.Count - 1
    lngColStart = Selection.Columns(1).Column
    lngColEnd = lngColStart + Selection.Columns.Count - 1

    ' 1행부터 선택된 영역이 시작되기 이전까지 행과
    ' 선택된 영역 바로 다음 행부터 맨 아래쪽 행까지의 영역을 숨김.
    Range(Cells(1, 1), Cells(lngRowStart - 1, 1)).EntireRow.Hidden = True
    Range(Cells(lngRowEnd + 1, 1), Cells(Rows.Count, 1)).EntireRow.Hidden = True

    ' 1열부터 선택된 영역이 시작되기 이전까지 열과
    ' 선택된 영역 바로 다음 열부터 맨 오른쪽 열까지의 영역을 숨김.
    Range(Cells(1, 1), Cells(1, lngColStart - 1)).EntireColumn.Hidden = True
    Range(Cells(1, lngColEnd + 1), Cells(1, Columns.Count)).EntireColumn.Hidden = True

ET:                       ' 오류 발생 시 이곳으로 와서 아래 구문을 실행함.
    If Err <> 0 Then
        MsgBox Err.Description, , "에러 코드: " & Err.Number
    End If
End Sub

Step 2: 단축키 설정

(1) '개발 도구 - 매크로' 아이콘을 클릭합니다.

(2) '매크로' 대화상자에서 단축키를 설정할 매크로를 선택합니다. '옵션' 버튼을 클릭하고, '바로 가기 키'를 지정합니다. 여기서는 <Ctrl> + <Shift> + <H> 키로 설정합니다.

이제 워크시트로 가서 범위를 지정하고 <Ctrl> + <Shift> + <H> 키를 누를 때마다 선택된 범위 밖의 영역은 사라졌다가 나타났다가를 반복합니다.

정리 — 선택 영역 바깥 숨기기 코드의 구성

단계	코드에서 하는 일
복원 판단	마지막 행이나 열이 숨겨져 있으면 전체 행과 열을 다시 표시하고 종료
영역 파악	Selection에서 첫 행, 마지막 행, 첫 열, 마지막 열 번호를 변수에 저장
숨기기	선택 영역 앞뒤의 행과 열을 EntireRow.Hidden, EntireColumn.Hidden으로 숨김
단축키	개발 도구 - 매크로 - 옵션에서 바로 가기 키 지정 (예: Ctrl+Shift+H)

자주 묻는 질문 (FAQ)

마치며

범위를 선택하고 단축키만 누르면 보고 싶은 부분만 남길 수 있습니다. 매일 쓰는 도구일수록 이런 작은 자동화가 큰 차이를 만드니 꼭 해 보세요!
VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 사이트 정문 왼쪽에 있는 'VBA 강좌 - VBA 입문강좌'를 읽어보시면 이해가 빠릅니다.