제품 이름을 단축키로 입력하게 해주는 Code

자동 고침 목록 추가

(1) 단축키로 설정할 제품 목록을 '추가List' 시트에 작성합니다. 헷갈리지 않을 자신이 있다면 얼마든지 더 많은 목록을 작성해두고 사용할 수 있습니다만, 5개 정도가 적당하지 않나 생각됩니다.

(2) VBE(Visual Basic Editor)로 가서 '삽입 - 모듈' 메뉴를 클릭하여 모듈을 삽입하고 다음 코드를 입력합니다. VBE로 어떻게 가냐구요? (이런...) 워크시트 상태에서 '개발 도구 - Visual Basic'을 클릭하거나 <Alt> + <F11> 키를 누르세요.

Sub AddAutoCorrectList()
    Dim shtSheet As Worksheet      ' 워크시트 개체에 접근하기 위한 개체 변수
    Dim rngCell As Range           ' For Each 문에서 사용할 개체 변수
    Dim intNum As Integer          ' 추가할 자동 고침 목록 수 저장을 위한 변수

    Set shtSheet = Worksheets("추가List")  ' 워크시트를 shtSheet 변수에 할당

    For Each rngCell In shtSheet.UsedRange.Columns(1).Cells
                  ' '추가List' 시트의 A열에서 값이 있는 셀 수만큼 For Each 문 반복 실행

        Application.AutoCorrect.AddReplacement rngCell, rngCell.Offset(0, 1)
                  ' AddReplacement 메서드를 이용하여 자동 고침 목록에 추가
                  ' 앞의 것(rngCell)을 뒤에 것(rngCell.Offset(0, 1))으로 대체
    Next rngCell
End Sub

자동 고침 목록 제거

빛이 있으면 어둠이 있고, 블랙홀이 있으면 화이트홀이 있듯, 자동 고침 목록을 추가하는 코드가 있다면 삭제하는 코드도 있을 것 같은 생각이 불현듯 드시지요?(빙고~~)

Sub DeleteAutoCorrectList()
    Dim varList As Variant
    Dim intNum As Integer
    varList = Application.AutoCorrect.ReplacementList

    ' DeleteReplacement 메서드를 이용하여 'S'자로 시작되는 자동 고침 목록이 있으면 제거
    For intNum = 1 To UBound(varList)
        If Left(varList(intNum, 1), 1) = "S" Then
            Application.AutoCorrect.DeleteReplacement varList(intNum, 1)
        End If
    Next intNum
End Sub

만약 '자동 고침' 기능 자체를 사용하지 않으려면 다음 코드를 사용하면 됩니다.

Application.AutoCorrect.ReplaceText = False

자동 고침 기능 속성 조정

워크시트 상태에서 '파일 - 옵션 - 언어 교정' 메뉴를 선택하고 '자동 고침 옵션' 버튼을 클릭하면 대화상자가 나타납니다. 자동 고침 기능의 여러 가지 속성 값을 이 대화상자를 통해 조정할 수 있습니다.

다음은 자동 고침 기능의 속성 값을 VBA 코드를 통해 제어하는 코드입니다. False 값을 True로 바꾸면 위 대화상자의 각 항목을 체크해 준 것과 같은 효과가 나타나겠죠?

Sub AutoCorrectProperty()
    With Application.AutoCorrect
        .TwoInitialCapitals = True
        .CorrectSentenceCap = True
        .CapitalizeNamesOfDays = True
        .CorrectCapsLock = True
    End With
End Sub

등록된 '자동 고침 목록' 모두 보기

내 컴퓨터에 등록되어 있는 '자동 고침 목록'을 모두 표시하려면 다음 코드를 사용하세요.

Sub ShowAutoCorrectList()
    Dim varList As Variant
    Dim intNum As Integer

    varList = Application.AutoCorrect.ReplacementList    ' 등록된 자동 고침 목록을 배열로 가져옴
    Worksheets.Add                                       ' 결과를 표시할 새 워크시트 추가

    For intNum = 1 To UBound(varList)
        Cells(intNum, 1) = varList(intNum, 1)            ' 입력할 내용
        Cells(intNum, 2) = varList(intNum, 2)            ' 바꿀 내용
    Next intNum
End Sub

정리 — 자동 고침 관련 VBA 코드

하려는 일	코드
목록 추가	Application.AutoCorrect.AddReplacement 입력, 바꿀 내용
목록 삭제	Application.AutoCorrect.DeleteReplacement 입력
목록 가져오기	Application.AutoCorrect.ReplacementList (2차원 배열)
자동 고침 끄기	Application.AutoCorrect.ReplaceText = False
옵션 속성 제어	.TwoInitialCapitals, .CorrectSentenceCap, .CapitalizeNamesOfDays, .CorrectCapsLock

자주 묻는 질문 (FAQ)

마치며

자주 쓰는 긴 이름은 자동 고침 목록에 한꺼번에 등록해 두면 입력이 훨씬 빨라집니다. 제품 목록을 만들어 직접 등록해 보세요!
VBA에 대한 기초 지식을 공부하실 분은 아이엑셀러 사이트 정문 왼쪽에 있는 'VBA 강좌 - VBA 입문강좌'를 읽어보시면 이해가 빠릅니다.