다양한 방식으로 시트 정렬하기

버블 소트 알고리즘으로 시트 정렬하기

시트를 정렬하는 데에는 여러 가지 방법이 있습니다. 흔한 방법 중 하나가 '버블소트 알고리즘'을 이용하는 것입니다. 인접한 두 개의 값을 비교해서 순서가 맞지 않으면 자리를 바꾸는 과정을, 마치 3개의 공을 가지고 저글링하듯 전체를 훑으며 반복하는 방식입니다.

이 과정을 엑셀이 알아듣게 코딩하면 아래와 같은 형태가 됩니다. 시트 이름을 배열 변수에 담아 두고, 인접한 이름끼리 비교해 순서가 맞지 않으면 배열 값을 바꾸는 동시에 실제 시트도 Worksheets.Move로 옮깁니다.

Sub SortSheetByBubbleSort()
    Dim i As Integer
    Dim j As Integer
    Dim strTemp As String
    Dim strSheetName() As String

    i = Worksheets.Count
    ReDim strSheetName(i)

    For i = 1 To UBound(strSheetName())
        strSheetName(i) = Worksheets(i).Name
    Next i

    For i = UBound(strSheetName()) - 1 To 1 Step -1
        For j = 1 To i
            If strSheetName(j) > strSheetName(j + 1) Then
                strTemp = strSheetName(j)
                strSheetName(j) = strSheetName(j + 1)
                strSheetName(j + 1) = strTemp
                Worksheets(strTemp).Move after:=Worksheets(strSheetName(j))
            End If
        Next j
    Next i

    Application.Goto Sheets("Preface").Range("A1"), True

End Sub

중첩 For ~ Next 문으로 정렬하기

그런가 하면, 중첩 For ~ Next 문을 이용하여 해결할 수도 있습니다. 코드는 따로 설명하고 말고 할 것도 없을 정도로 간단합니다.

Sub SortSheetsByName()
    Dim i As Integer
    Dim j As Integer
    Dim intNum As Integer

    intNum = Sheets.Count

    For i = 1 To intNum
        For j = 1 To i - 1
            If Sheets(j).Name > Sheets(i).Name Then _
                Sheets(i).Move Before:=Sheets(j)
        Next j
    Next i

End Sub

사용자가 지정한 순서로 정렬하기

그런데 시트를 '가나다' 순서가 아니라 사용자가 지정하는 순서로 정렬하려면 어떻게 해야 할까요? 예를 들어 강동, 강서, 강남, 강북, 부산, 대구, 대전, 광주, 제주 순서로 정렬되어야 한다면 말이지요.

시트 정렬하는 과정을 제대로 이해했다면 조금만 응용하면 됩니다. 원하는 순서대로 시트 이름을 셀에 나열해 두고(예제에서는 'Start'라는 이름으로 정의된 영역), 그 순서대로 시트를 맨 앞부터 차례로 옮기면 됩니다.

Sub SortSheetByUserOrder()
    Dim rngTarget As Range
    Dim rngCell As Range
    Dim i As Integer
    Dim strTemp As String

    Set rngTarget = Range("Start").CurrentRegion.Cells

    For Each rngCell In rngTarget
        i = i + 1
        strTemp = rngCell
        Sheets(strTemp).Move Before:=Sheets(i)
    Next rngCell

End Sub

탭 색을 기준으로 정렬하기

하나 더 해 볼까요? 엑셀 2007 버전부터는 시트 탭에 색상을 지정할 수 있습니다. 따라서 탭 색을 기준으로 정렬할 수도 있습니다.

Sub SortSheetByTabColor()
    Dim i As Integer
    Dim j As Integer
    Dim intNum As Integer

    intNum = Sheets.Count

    For i = 1 To intNum
        For j = 1 To i - 1
            If Sheets(j).Tab.ColorIndex > Sheets(i).Tab.ColorIndex Then _
                    Sheets(i).Move Before:=Sheets(j)
        Next j
    Next i

End Sub

이것 말고도 얼마든지 다른 방법으로 시트를 정렬할 수 있습니다. 늘 그렇듯, 응용은 여러분들 몫으로 남깁니다.

정리 — 네 가지 시트 정렬 프로시저

프로시저	정렬 기준
SortSheetByBubbleSort	버블소트 알고리즘으로 시트 이름 오름차순 정렬
SortSheetsByName	중첩 For 문으로 시트 이름 오름차순 정렬
SortSheetByUserOrder	'Start'로 이름 정의된 범위에 나열한 사용자 지정 순서
SortSheetByTabColor	시트 탭의 Tab.ColorIndex 값 순서

자주 묻는 질문 (FAQ)

마치며

시트를 정렬하는 방법은 이 네 가지 말고도 얼마든지 더 있을 수 있습니다. 코드의 원리를 이해했다면, 여러분만의 기준으로 또 다른 정렬 방식을 만들어 보세요!