지정한 영역을 html 파일로 저장하기

방법 1: '다른 이름으로 저장' 명령 이용하기

(1) 내보내기 할 영역을 선택하고 'Office 단추 - 다른 이름으로 저장 - 다른 형식'을 선택합니다.

(2) '다른 이름으로 저장' 대화상자에서 '파일 형식 - 웹 페이지'로 지정합니다. '선택 영역' 항목을 클릭한 다음 '게시' 버튼을 클릭합니다.

(3) '웹 페이지로 게시' 대화상자가 나타납니다. 이상 여부를 확인한 다음 '게시' 버튼을 클릭하면 지정한 위치에 html 파일이 만들어집니다.

방법 2: VBA를 이용하는 방법

매번 대화상자를 여러 번 거쳐야 하는 번거로움을 덜기 위해 VBA를 이용하여 자동화할 수도 있습니다. 표준 모듈에 다음 코드를 입력합니다.

Sub ExportToHtml()

    Dim strHtmlFileName As String
    Dim strAddress As String
    Dim strOpenTag As String
    Dim strCloseTag As String
    Dim strCell As String
    Dim strMsg As String
    Dim rngRange As Range
    Dim lngRow As Long
    Dim lngCol As Long

    Application.Goto Worksheets("Workplace").Range("A1"), True

    strAddress = Range("B3").CurrentRegion.Address
    Set rngRange = Application.InputBox("대상영역을 선택하세요.", _
        Default:=strAddress, Type:=8)
    ' Workplace 시트의 B3 셀 주변 영역을 rngRange 변수에 할당합니다.
    ' 물론 InputBox 함수를 이용하여 다른 영역을 지정할 수도 있습니다.

    If rngRange Is Nothing Then
        MsgBox "대상 영역을 다시 확인하세요!", vbCritical
        Exit Sub
    End If

    Do
        strHtmlFileName = Application.GetSaveAsFilename(Format(Int(Now), "yyyymmdd"), _
            fileFilter:="Html Files (*.htm), *.htm")
        ' 파일을 저장할 위치를 지정합니다. GetSaveAsFilename 메서드를 이용하면
        ' '다른 이름으로 저장' 대화상자가 나타나므로 사용자가 편리하게 폴더 위치와
        ' 파일 이름을 지정할 수 있습니다.
    Loop Until strHtmlFileName <> ""

    Open strHtmlFileName For Output As #1
    ' Open 문은 파일을 가져오거나(Importing) 내보내기(Exporting) 하기 전에
    ' 반드시 적어주어야 합니다.

    Print #1, "<HTML>"
    Print #1, "<TABLE BORDER=1 CELLPADDING=1>"

    For lngRow = 1 To rngRange.Rows.Count
        Print #1, "<TR>"

        For lngCol = 1 To rngRange.Columns.Count
            Select Case rngRange.Cells(lngRow, lngCol).HorizontalAlignment
                Case xlHAlignLeft
                    strOpenTag = "<TD ALIGN=LEFT>"
                Case xlHAlignCenter
                    strOpenTag = "<TD ALIGN=CENTER>"
                Case xlHAlignGeneral
                    If IsNumeric(rngRange.Cells(lngRow, lngCol)) Then
                        strOpenTag = "<TD ALIGN=RIGHT>"
                    Else
                        strOpenTag = "<TD ALIGN=LEFT>"
                    End If
                Case xlHAlignRight
                    strOpenTag = "<TD ALIGN=RIGHT>"
            End Select

            strCloseTag = "</TD>"

            If rngRange.Cells(lngRow, lngCol).Font.Bold Then
                strOpenTag = strOpenTag & "<B>"
                strCloseTag = "</B>" & strCloseTag
            End If

            strCell = rngRange.Cells(lngRow, lngCol).Text
            Print #1, strOpenTag & strCell & strCloseTag
        Next lngCol

        Print #1, "</TR>"

    Next lngRow

    Print #1, "</TABLE>"
    Print #1, "</HTML>"

    Close #1

    strMsg = "HTML 파일로 내보내기 작업이 완료되었습니다." & vbCr
    strMsg = strMsg & strHtmlFileName & "파일을 열어보세요!"
    MsgBox strMsg, , "아이엑셀러 닷컴"

End Sub

두 방법의 장단점 비교

이 ExportToHtml 프로시저를 이용하면 좋은 점은, 불필요한 서식을 지정하지 않으므로 파일 크기를 크게 줄일 수 있다는 것입니다. 예를 들어 Workplace 시트의 A1:F22 영역을 내보낼 때, (방법 1)을 사용하면 20.1KB 정도의 크기가 됩니다만, ExportToHtml 프로시저로 내보낸 경우에는 5.19KB밖에 되지 않습니다(약 1/4 수준, Exceller PC 기준).

반면, ExportToHtml 프로시저는 워크시트 상에서 표현되는 모든 셀 서식을 유지하지는 못합니다. 지정할 수 있는 서식은 굵게, 이탤릭, 수평 정렬 정도가 전부입니다.

정리 — 영역을 html로 저장하는 두 가지 방법 비교

구분	방법 1(다른 이름으로 저장)	방법 2(ExportToHtml)
조작 방식	대화상자를 여러 번 거쳐야 함	버튼 한 번으로 자동화
파일 크기(예시)	약 20.1KB	약 5.19KB
지원 서식	워크시트 서식 대부분 유지	굵게·이탤릭·수평 정렬만 지원

자주 묻는 질문 (FAQ)

마치며

기본 기능과 VBA, 어느 쪽이 정답이라기보다는 상황에 맞게 골라 쓰면 됩니다. 서식을 최대한 살리고 싶다면 방법 1을, 가볍고 빠른 결과물이 필요하다면 방법 2를 선택해 보세요!