중복 없이 하나로 합치고 정렬하기

Step 1: 어떤 질문이었을까요?

Workplace 시트를 보면, A열과 B열에 데이터가 입력되어 있습니다. 그런데 데이터 중간 중간에 중복되는 번호(예를 들면 40과 80)가 있는데, 이것을 중복되지 않게 E열에 표시한 다음 오름차순 정렬을 하고 싶다는 것입니다.

아이엑셀러

아래 버튼을 클릭해 보세요.

Step 2: 고급 필터를 이용한 방법

게시판에서 많은 활동을 하고 계시는 신정수님께서 이런 코드를 올려 주셨습니다. 기억을 더듬어 작성한 것이므로 원래의 소스 코드와 다를 수 있습니다. 혹시라도 크게 차이나는 부분이 있을 경우, 알려주시면 수정해 드리겠습니다.

Sub UniqueItem()

    Dim rngCell As Range
    Dim rngMyRng1 As Range
    Dim rngMyRng2 As Range
    Dim rngUnion As Range
    Dim rngTarget As Range
    Dim intNum As Integer

    '작업에 필요한 범위들을 지정해 줍니다.
    'Union 메서드를 이용하여 rngMyRng1과 rngMyRng2, 즉 Workplace 시트의 A열과 B열에서
    '데이터가 있는 부분을 하나로 합친 부분만 주의해서 보시면 되겠습니다.
    '나머지 부분은 대부분 아주 직설적인(straight-forward) 표현이므로 별도의 설명은 없어도
    '이해하시리라 생각합니다.

    Set rngTarget = Range("A2").Offset(0, 4)
    Set rngMyRng1 = Range(Range("A2"), Range("A2").End(xlDown))
    Set rngMyRng2 = Range(Range("A2"), Range("B2").End(xlDown))
    Set rngUnion = Union(rngMyRng1, rngMyRng2)

    rngTarget.EntireColumn.ClearContents

    For Each rngCell In rngUnion
        rngTarget.Offset(intNum).Value = rngCell.Value
        intNum = intNum + 1
    Next

    rngTarget.Offset(-1, 0) = "결과"

    Set rngTarget = rngTarget.EntireColumn.SpecialCells(xlTextValues)
    rngTarget.AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Range("F1"), Unique:=True
    rngTarget.EntireColumn.ClearContents
    Columns(6).Copy Columns(5)
    Columns(6).ClearContents

    rngTarget.Sort Key1:=rngTarget, Order1:=xlAscending, Header:=xlGuess

End Sub

Step 3: 컬렉션 오브젝트를 이용한 방법

위와 같은 방법으로도 가능하며, 다음처럼 컬렉션 오브젝트를 사용할 수도 있습니다.

Sub UniqueItem2()

    Dim rngCell As Range
    Dim rngUnion As Range
    Dim rngMyRng1 As Range
    Dim rngMyRng2 As Range
    Dim rngTarget As Range
    Dim X As New Collection
    '컬렉션 오브젝트 변수인 X를 선언합니다.

    Dim varItem
    Dim sht As Worksheet
    Dim intNum As Integer
    On Error Resume Next
    '컬렉션 오브젝트를 사용할 때에는 반드시 이 구문을 써 주어야 합니다.

    '작업 대상 영역을 설정하는 것은 앞에서와 같고…
    Set rngTarget = Range("A2").Offset(0, 4)
    Set rngMyRng1 = Range(Range("A2"), Range("A2").End(xlDown))
    Set rngMyRng2 = Range(Range("A2"), Range("B2").End(xlDown))
    Set rngUnion = Union(rngMyRng1, rngMyRng2)

    rngTarget.EntireColumn.ClearContents

    For Each rngCell In rngUnion
        X.Add rngCell.Value, CStr(rngCell.Value)
        '컬렉션 오브젝트는 [오브젝트명.Add Item, key, (before), (after)]의 형태로 사용합니다.
        '여기서 key argument는 unique한 텍스트, 즉 중복되지 않는 텍스트일 경우에만 유효합니다.
        '만약에 앞에서 나왔던 값이 뒤에 또 나오면 에러가 발생하게 되고, 따라서 컬렉션 오브젝트에
        '추가가 되지 않게 됩니다.

    Next rngCell

    For Each varItem In X
        rngTarget.Offset(intNum, 0) = varItem
        intNum = intNum + 1
        '컬렉션 오브젝트인 X에 저장된 값들을 지정한 위치에 차례로 뿌려줍니다.

    Next varItem

    rngTarget.Offset(-1, 0) = "결과"
    rngTarget.Sort Key1:=rngTarget, Order1:=xlAscending, Header:=xlGuess

End Sub

물론 이런 방법들말고도 다양한 방법으로 해결이 가능합니다. 나머지 방법들에 대해서는 여러분이 직접 연구해 보시기 바랍니다.

오늘은 여기까지…

정리 — 두 가지 방법 비교

자주 묻는 질문 (FAQ)

마치며

같은 문제도 고급 필터로 풀 수 있고 컬렉션으로도 풀 수 있습니다. 여러 가지 방법을 비교해 보면서 여러분에게 맞는 방식을 골라 보세요!