선택한 영역만 표시하기

Step 1: 선택한 영역만 남기고 나머지 숨기기

이번 시간에는 사용자가 범위를 지정하고 <Ctrl+Shift+H> 키를 누르면, 선택한 영역만 남겨두고 나머지는 모두 숨기는 방법에 대해 살펴보도록 하겠습니다(단축키를 한번 더 누르면 숨겨졌던 영역은 다시 나타납니다).

Sub HideRestArea()

    Dim lngRowStart As Long
    Dim lngRowEnd As Long
    Dim lngColStart As Long
    Dim lngColEnd As Long
    On Error GoTo ET

    If Rows(Rows.Count).EntireRow.Hidden Or Columns(Columns.Count).EntireColumn.Hidden Then
    '특정한 영역이 이미 숨겨져 있는 경우, 이 영역을 표시하기 위한 과정입니다.
    '맨 마지막 행이나 열이 숨겨져 있을 경우 EntireRow나 EntireColumn 속성의 Hidden 속성을
    'False, 즉 화면에 표시합니다.

        Cells.EntireRow.Hidden = False
        Cells.EntireColumn.Hidden = False

        MsgBox "숨겨져 있던 영역을 모두 표시하였습니다", , "www.iExceller.com"
        Exit Sub
    End If

    '선택된 영역의 크기와 관련하여, 행이 시작되는 위치와 끝나는 위치, 그리고 열이 시작되는 위치와
    '끝나는 위치 정보를 각각의 변수에 저장해 둡니다.
    lngRowStart = Selection.Rows(1).Row
    lngRowEnd = lngRowStart + Selection.Rows.Count - 1
    lngColStart = Selection.Columns(1).Column
    lngColEnd = lngColStart + Selection.Columns.Count - 1

    '1행부터 선택된 영역이 시작되기 이전까지 행, 선택된 영역 바로 다음 행부터 맨 아래쪽 행까지
    '영역을 Hidden 속성을 이용하여 숨깁니다.
    If lngRowStart > 1 Then Range(Cells(1, 1), Cells(lngRowStart - 1, 1)).EntireRow.Hidden = True
    If lngRowEnd < Rows.Count Then Range(Cells(lngRowEnd + 1, 1), Cells(Rows.Count, 1)).EntireRow.Hidden = True

    '1열부터 선택된 영역이 시작되기 이전까지 열, 선택된 영역 바로 다음 열부터 맨 오른쪽 열까지
    '영역을 Hidden 속성을 이용하여 숨깁니다.
    If lngColStart > 1 Then Range(Cells(1, 1), Cells(1, lngColStart - 1)).EntireColumn.Hidden = True
    If lngColEnd < Columns.Count Then Range(Cells(1, lngColEnd + 1), Cells(1, Columns.Count)).EntireColumn.Hidden = True

ET:
    If Err <> 0 Then
        MsgBox Err.Description, , "에러코드 : " & Err.Number
    End If

End Sub

Step 2: 단축 키 지정과 저장 위치

이렇게 해서 작성된 프로시저에 단축 키를 지정하는 방법은 강좌 도입부에 소개해 드린 내용을 참고하시면 되겠습니다. 오늘 소개해 드린 내용을 빈번하게 사용하실 예정이라면 '개인용 매크로 통합문서(Personal.xls)'에 저장해 두시면 되겠습니다.

참고로 '개인용 매크로 통합문서'는 엑셀 2007 버전에서는 Personal.xlsb로 확장자가 변경되었으니 참고하세요.

다음 시간에 또…

정리 — 선택 영역만 표시하기 코드 핵심

자주 묻는 질문 (FAQ)

마치며

선택한 영역의 시작과 끝 위치만 알면 나머지 영역을 숨기는 일은 간단합니다. 개인용 매크로 통합 문서에 저장해 단축 키로 자주 활용해 보세요!