엑셀로 못하는게 머야 시리즈(5) - 로또번호 생성기

Step 1: 어떤 질문이었을까요?

역량(?)을 발휘할 수 있을 지는 확신할 수 없지만… 한번 만들어 보도록 하지요. 사실은 '로또번호 생성기'라는 자극적인(?) 제목보다 '중복없는 난수 생성기'라는 표현이 더 맞을 것 같습니다.

Anyway… 적당한 숫자를 입력하고 아래의 '난수 추출하기' 버튼을 클릭해 보세요.

버튼을 클릭하면 아래와 같이 중복 없이 뽑힌 숫자가 오름차순으로 표시됩니다. (예: 8, 9, 14, 18, 22, 23, 34, 38)

각 입력 칸은 다음과 같은 의미를 가집니다.

• From: 시작되는 숫자 입력
• To: 끝나는 숫자 입력
• How Many?: 생성할 숫자의 개수 입력(10개 이하로 지정하세요!)

From에 1, To에는 45, How Many? 부분에는 6을 각각 입력하면 바로… 로또번호 생성기가 되는 것입니다.

Step 2: 코드 살펴보기

코드의 내용을 살펴보도록 하지요.

Const strID As String = "www.iExceller.com"

Sub MakeRandomNum()

    Dim X As New Collection
    Dim i As Integer
    Dim j As Integer
    Dim intMin As Integer
    Dim intMax As Integer
    Dim intNum As Integer
    Dim intStart As Integer
    Dim intResult() As Integer
    Dim intCount As Integer
    Dim lngCount As Long
    Dim strMsg As String
    Dim rngResult As Range
    '필요한 변수들을 선언합니다.

    On Error GoTo ET
    Randomize

    Set rngResult = Range("From").Offset(6, -1)
    Set rngResult = Range(rngResult, rngResult.End(xlDown))
    rngResult.ClearContents
    intStart = rngResult.Row - 1
    '추출된 숫자가 표시될 영역을 지정합니다. 만약 이미 입력된 것이 있을 경우에는 삭제합니다.

    Do
    '만약 유효하지 않은 값이 입력되면 계속 입력되도록 하거나 혹은 프로시저를 종료합니다.

        If Range("From") = "" Or Range("To") = "" Or Range("HowMany") = "" Then
            MsgBox "입력값들을 확인하세요!", , strID
            Exit Sub
        End If

        If Range("HowMany") > 10 Then
            MsgBox "추출할 숫자의 갯수는 10개 이하로 지정하세요!", , strID
            Exit Sub
        End If
    Loop While Range("From") = "" Or Range("To") = "" Or Range("HowMany") = ""

    intMin = Range("From")
    intMax = Range("To")
    intNum = Range("HowMany")

    ReDim intResult(1 To intNum, 1)

    For i = intMin To intMax
        X.Add i
    Next i

    For i = 1 To intNum
        j = Int(Rnd * (intMax - intMin - i + 2)) + 1
        intResult(i, 1) = X(j)
        X.Remove j
        '지정한 숫자 범위 내에서 난수를 발생시킵니다. 컬렉션 오브젝트의 값을 intResult 배열 변수에
        '할당하고 나서 제거하는 과정입니다.

    Next i

    For i = 1 To intNum
    '컬렉션 오브젝트에 담긴 값들을 지정한 위치에 표시합니다.

        For intCount = 1 To intResult(i, 1)
            Cells(intStart + i, 1) = intCount
        Next intCount

        For lngCount = 1 To 10000
            'Doing Nothing
            '속도 조절을 위한 더미 순환문(Dummy Looping) 입니다. 만약 PC 상황에 따라서 순환
            '속도가 너무 느리면 이 부분을 제거하세요.
        Next lngCount
    Next i

    rngResult.Sort key1:=rngResult, order1:=xlAscending
    ' 화면에 표시된 숫자값들을 오름차순으로 정렬합니다.

    strMsg = intMin & " 에서 " & intMax & " 사이의 값 중에서 " & vbCr
    strMsg = strMsg & intNum & " 개의 중복되지 않는 숫자를 추출하였습니다"
    MsgBox strMsg, , strID

ET:
    If Err.Number <> 0 Then
        MsgBox Err.Description, , "오류 번호 : " & Err.Number
        Err.Clear
    End If

End Sub

=SORT(TAKE(SORTBY(SEQUENCE(45), RANDARRAY(45)), 6))

'이런 것을 엑셀로 만들어 보았으면…' 하는 것이 있는 분은 알려주시기 바랍니다. '엑셀로 못하는게 머야 씨리즈'를 통해 다루어 보도록 하겠습니다.

다음에 또…

정리 — 중복 없는 난수 생성 코드 핵심

자주 묻는 질문 (FAQ)

마치며

로또번호 생성기라는 자극적인 제목보다는 중복 없는 난수 생성기라는 표현이 더 어울립니다. 컬렉션을 활용한 이 방법은 다양한 추첨 프로그램에 응용할 수 있습니다.