테이블 형태 변경하기

Step 1: 두 가지 형태의 테이블

다음과 같은 두 가지 형태의 테이블이 있습니다. 만약 <표 2>와 같은 테이블이 있다면 이것을 이용해서 <표 1>의 형태로 만드는 것은 일도 아닐 것입니다. 피벗 테이블을 이용하면 간단하게 해결할 수 있으니까요.

<표 1>

아이엑셀러

<표 2>

아이엑셀러

그런데 그 반대의 경우라면 어떻게 하면 좋을까요? 즉, <표 1>과 같은 데이터를 이용하여 <표 2>를 만들어야 한다면 말입니다. 아래 버튼을 클릭해 보세요.

Step 2: 코드 살펴보기

보신 것처럼 간단히 해결됩니다. 코드를 살펴볼까요?

Sub ChangeTableFormat()

    Dim rngSource As Range
    Dim rngOutput As Range
    Dim lngRow As Long
    Dim lngCol As Long
    Dim lngSourceRow As Long
    On Error GoTo ET

    Application.Goto Worksheets("Workplace").Range("A1"), True
    MsgBox "지금부터 테이블 형태 변경 작업을 시작합니다", , "www.iExceller.com"

    Set rngSource = Range("Source")
    ' Workplace 시트에 'Source'라는 이름을 미리 정의해 두었으니 확인해 보세요.

    Set rngOutput = Worksheets("Workplace").Range("B15")

    ' 새로운 테이블을 작성하려는 위치에 다른 내용이 있으면 지웁니다.
    If rngOutput <> "" Then
        MsgBox "이미 작성된 것이 있으므로 지우고 시작합니다"
        rngOutput.CurrentRegion.Clear
    End If

    rngOutput.CurrentRegion.Clear
    lngSourceRow = 2
    rngOutput.Range("A1:C1") = Array("담당명", "브랜드명", "매출수량")
    ' 새로 작성하는 테이블의 제목 부분을 기입합니다.

    For lngRow = 2 To rngSource.Rows.Count
        For lngCol = 2 To rngSource.Columns.Count
        ' <표 1>을 보면 데이터가 행/열 방향으로 배치되어 있으므로 For ~ Next 문을 두 번
        ' 중첩해서 사용 하였습니다.

            With rngOutput
            ' <표 1>의 행과 열 방향을 순차적으로 이동해 가면서 데이터를 B15 셀을 중심으로
            ' 가로/세로 방향으로 하나씩 적어 나갑니다. 빈 종이를 가져다 놓고 세 번 정도만
            ' 숫자를 대입해 보시면 로직을 쉽게 이해하실 수 있을 것입니다.

                .Cells(lngSourceRow, 1) = rngSource.Cells(lngRow, 1)
                .Cells(lngSourceRow, 2) = rngSource.Cells(1, lngCol)
                .Cells(lngSourceRow, 3) = rngSource.Cells(lngRow, lngCol)
            End With

            lngSourceRow = lngSourceRow + 1
            ' <표 1>의 한 행에 대해 끝마쳤으면 다음 행으로 이동하기 위한 카운터 값을 1 증가시킵니다.

        Next lngCol
    Next lngRow

    ActiveSheet.ListObjects.Add(xlSrcRange, Range(rngOutput.CurrentRegion.Address), , xlYes).Name = "MyTable"
    ActiveSheet.ListObjects("MyTable").TableStyle = "TableStyleLight16"
    ' 이것은 Excel 2007에서 지원하는 것으로써 그 이전 버전까지 제공되던 '자동 서식'과
    ' 비슷합니다. 즉 테이블의 형태를 자동으로 꾸며주기 위한 것입니다.

    MsgBox "테이블 형태 변경 작업이 완료되었습니다!", , "www.iExceller.com"

ET:
    If Err.Number <> 0 Then
        MsgBox Err.Description, , "오류 번호 : " & Err.Number
        Err.Clear
    End If

End Sub

그런데… 사실 <표 1>과 같은 데이터를 <표 2>와 같은 형태로 만드는 것이라면 머리 아프게 VBA로 코딩을 하고 말고 할 것도 없습니다. 피벗 테이블 기능을 이용하면 더 간편하게 해결할 수 있습니다(X0348 강좌를 살펴 보세요!!).

세상에 믿을 OX 없다더니… 이제 Exceller도 믿을 게 못되는군! 이렇게 쉽게 해결할 수 있는데 어려운 것을 알려 주다니… 이런 생각이 드셨나요?

어떤 일을 간단하게 해 치우듯(!) 하는 것도 중요하겠습니다만, 그보다 더 중요한 것은, 어떤 원리에 의해 그렇게 되는지를 이해하는 것과 그 과정에서 얻게 되는 사고력, 응용력 등이 더욱 중요한 것이라 생각합니다.

다음에 또…

정리 — 테이블 형태 변경 코드 핵심

자주 묻는 질문 (FAQ)

마치며

간단히 해치우는 것도 중요하지만, 어떤 원리로 그렇게 되는지 이해하고 그 과정에서 사고력과 응용력을 기르는 것이 더 중요합니다.