지점별로 일련번호 매기기

Step 1: 어떤 질문이었을까요?

질문에 나온 표는 아래와 같은 모양입니다. 팀별로 팀원 수가 제각각이고, 순번 부분은 병합되어 있습니다.

만약 팀명 부분이 병합되어 있다면 함수를 사용하여 간단하게 해결할 수 있지만 위와 같은 형태에서 순번 부분에 일련번호를 삽입해야 한다면 VBA를 사용하여 해결할 수 있습니다.

지점이 몇 개이든 팀원이 몇 명이든 상관없이 되지요?

Step 2: 코드 살펴보기

Const strID As String = "www.iExceller.com"
' 프로시저 바깥에 상수를 선언하고 값을 지정해 두었습니다.
' 이렇게 하면 다른 프로시저에서도 매번 별도로 선언할 필요없이 사용할 수 있게 됩니다.

Sub SerialNumber()

    Dim rngCell As Range
    Dim rngTarget As Range
    Dim i As Integer
    Dim strMsg As String

    Set rngTarget = Columns(3).SpecialCells(xlTextValues).Offset(1, -1)
    Set rngTarget = rngTarget.Resize(rngTarget.Cells.Count - 1, 1)
    ' 작업 영역은 Workplace 시트의 B3:B28 셀 입니다.
    ' 이것을 찾아내는 방법을 눈여겨 보시기 바랍니다.
    ' 일단 C열에서 값이 들어있는 영역을 찾아낸 다음 옆으로 1열 이동하고 Resize 메서드를
    ' 이용하여 크기를 조정합니다.

    strMsg = "작업 대상 영역의 내용을 모두 지웠습니다." & vbCr
    strMsg = strMsg & "이제 순번을 새로 매깁니다."

    rngTarget.ClearContents
    MsgBox strMsg, , "www.iExceller.com"

    For Each rngCell In rngTarget
        With rngCell
            If .MergeCells Then
            ' rngTarget 영역 내의 셀이 병합된 셀인지 여부를 하나씩 점검해 나갑니다.
            ' 병합된 셀이라면 병합된 영역을 rngTarget으로 다시 지정(assign)하고
            '  rngCell의 셀 주소와 rngTarget 중 첫번째 셀의 주소가 같은 지를 비교합니다.
            ' 같으면 변수 i 값을 1 증가시킨 다음 셀에 표시합니다.

                Set rngTarget = .MergeArea

                If .Address = rngTarget.Cells(1).Address Then
                    i = i + 1
                    .Value = i
                End If
            Else
            ' 그렇지 않으면, 즉 셀에 병합되지 않았으면 변수 i 값을 1 증가시키고 셀에 표시합니다.

                i = i + 1
                .Value = i
            End If
        End With
    Next rngCell

End Sub

이번 강좌 역시 지난 시간과 마찬가지로 수작업으로 한다면 어떤 과정을 거쳐 처리하는가를 잘 고민해 보시면 실마리를 찾을 수 있는 그런 유형이 되겠습니다.

다음에 또…

정리 — 팀별 일련번호 코드 핵심

자주 묻는 질문 (FAQ)

마치며

수작업으로 한다면 어떤 과정을 거칠지를 먼저 고민해 보면 실마리가 보입니다. 병합된 셀은 첫 번째 셀에만 값이 있다는 점만 기억하시면 됩니다.