값이 있는 셀에만 번호 매기기

Step 1: 어떤 질문이었을까요?

언제 올라온 질문인지 모르겠지만 다음과 같은 내용의 것이 있었습니다. (혹시 다른 사이트에 올라온 것인지도 모르겠습니다)

선거 얘기가 등장하는 것으로 보아... 좀 오래 된 질문인가 봅니다. ^^ 다음 버튼을 눌러 보세요.

Step 2: 코드 살펴보기

Const strID As String = "www.iExceller.com"
' 프로시저 바깥에 상수를 하나 선언하고 값을 지정해 두었습니다.
' 이처럼 프로시저 외부에 변수나 상수를 선언하면 다른 프로시저에서도 불러와서 사용할 수
' 있게 됩니다.

Sub Numbering()

    Dim rngTarget As Range
    Dim rngArea As Range
    Dim rngCell As Range
    Dim i As Integer
    Dim strMsg As String

    Set rngTarget = Range("번호")
    ' Workplace 시트의 A3:A20 영역에 미리 이름 정의를 해 두었습니다.
    ' 동적 이름 정의를 해 두면 보다 융통성 있게 작업을 할 수 있겠지요?

    strMsg = "작업 대상 영역의 내용을 모두 지웠습니다." & vbCr
    strMsg = strMsg & "이제 순번을 새로 매깁니다."

    rngTarget.ClearContents
    MsgBox strMsg, , strID
    ' 이미 번호가 입력되어 있다면 지웁니다.

    For Each rngCell In rngTarget
        With rngCell
            Set rngArea = Range(.Offset(0, 1), .Offset(0, 5))
            ' B열에서 F열에 데이터가 들어있는지를 파악하기 위해 rngArea 변수에 해당 영역을
            ' 할당합니다.

            If WorksheetFunction.CountA(rngArea) > 0 Then
            ' 데이터가 들어있는지 여부는 워크시트 함수인 CountA를 이용합니다. 즉 CountA의
            ' 결과값이 0보다 크면 무언가 값이 들어있다는 의미가 되므로 카운터 변수 i 값을 1
            ' 증가시키고 셀에 표시합니다.

                i = i + 1
                .Value = i
            End If
        End With
    Next rngCell

    MsgBox "모두 " & i & "개의 아이템이 있습니다", , strID

End Sub

코드는 무지 간단하지요? 프로그래밍을 하기 전에 '수작업으로 한다면 어떤 프로세스로 처리가 되는가?'를 충분히 고민해 보면 답은 쉽게 나올 수 있습니다.

오늘은 여기까지…

정리 — 번호 매기기 코드 핵심

자주 묻는 질문 (FAQ)

마치며

프로그래밍을 하기 전에 수작업으로 한다면 어떤 과정을 거치는지 먼저 생각해 보면 코드는 의외로 간단하게 풀립니다. 값이 있는 행에만 번호를 매기는 이 코드도 그렇게 만들어졌습니다.