숫자 데이터에만 색칠하기

Step 1: 어떤 질문이었을까요?

질문을 어디에 두었는지는 기억나지 않습니다만, 어느 분의 질문 중에 '시트에 입력된 내용 중에서 숫자에만 별도의 서식을 지정할 수 없겠는가?' 하는 것이 있었습니다.

아래 버튼을 누르면 현재 시트의 내용 중 일부분이 Workplace 시트로 옮겨짐과 동시에 'Click Me!'라는 버튼이 생기는데 이 버튼을 클릭해 보시기 바랍니다.

문장 내에서 숫자 데이터에만 빨간색이 입혀지는 것을 확인할 수 있습니다.

Step 2: 코드 살펴보기

사용된 코드를 살펴볼까요?

Sub MakeSample()

    Dim rngTestRange As Range
    Set rngTestRange = Worksheets("Preface").Range("A9:F38")

    rngTestRange.Copy
    Worksheets.Add after:=Sheets("Preface")
    ActiveSheet.Paste
    ActiveWindow.DisplayGridlines = False
    ' 대상 영역을 복사하고 Preface 시트 뒤에 새로운 시트를 한 장 삽입한 다음 붙여 넣습니다.

    Range("H2").Select
    With ActiveCell
        ActiveSheet.Buttons.Add(.Left, .Top, .Width * 2, .Height).Select
    End With
    ' 새로운 시트의 H2 셀에 버튼을 하나 삽입합니다.

    With Selection
    ' 앞에서 삽입한 버튼에 대해 캡션을 설정하고 클릭할 경우 작동할 프로시저를 연결합니다.

        .Caption = "Click Me!"
        .Font.Name = "Arial"
        .Font.Size = 11
        .OnAction = "ColoringNumber"
    End With

    Range(Selection.TopLeftCell.Address).Select
    MsgBox "연습용 시트를 만들었습니다. Click Me! 버튼을 클릭하세요!", , "www.iExceller.com"

End Sub

이번에는 'Click Me!' 버튼을 클릭할 경우 작동하게 되는 'ColoringNumber'라는 외부 프로시저를 작성합니다.

Sub ColoringNumber()

    Dim rngCell As Range
    Dim rngTarget As Range
    Dim i As Integer
    Dim intLen As Integer
    Set rngTarget = ActiveSheet.UsedRange
    ' 현재 시트 중에서 사용된 영역(UsedRange)을 작업 대상으로 합니다.

    For Each rngCell In rngTarget
        intLen = Len(rngCell.Value)

        If intLen = 0 Then
        ' intLen이 0이면, 즉 빈 셀이면 아무 것도 하지 않고…

            ' Doing Nothing
        Else
            With rngCell
                For i = 1 To intLen
                ' 빈 셀이 아니라면 한 글자씩 확인하여 숫자인 경우에는 빨간색을 지정합니다.

                    If IsNumeric(.Characters(i, 1).Text) Then
                        With .Characters(i, 1).Font
                            .ColorIndex = 3
                            .Bold = True
                        End With
                    End If
                Next i
            End With
        End If
    Next rngCell

End Sub

오늘은 여기까지…

정리 — 숫자 색칠 코드 핵심

자주 묻는 질문 (FAQ)

마치며

글자를 하나씩 검사하는 방식을 익혀 두면 문자열 속의 특정 글자만 골라 서식을 지정하는 다양한 작업에 응용할 수 있습니다.