간단 달력 만들기

Step 1: 완성된 달력 살펴보기

일단 아래 버튼을 눌러서 달력의 형태를 살펴보고 오세요.

Stage 시트에는 년과 월을 고르는 두 개의 콤보 상자(YearCombo, MonthCombo)가 있고, 선택한 년/월에 맞추어 1일부터 말일까지의 날짜와 요일이 가로 방향으로 표시됩니다.

Step 2: Workbook_Open 이벤트 프로시저

VB Editor 상태(<Alt> + <F11>)에서 ThisWorkbook 개체를 더블 클릭하면 다음과 같은 Workbook_Open 이벤트 핸들러 프로시저의 내용이 나타납니다. 이것은 파일을 열 때 Stage 시트에 있는 두 개의 콤보 상자(년, 월)의 내용을 오늘 날짜(정확하게 말하자면 현재 컴퓨터 시스템에 세팅되어 있는 날짜)로 맞추기 위한 것입니다.

코드에 대한 설명은 생략합니다. 보시다가 이해가 안되는 부분이 있으면 홈 페이지 Q&A 게시판에 질문주시기 바랍니다.

Private Sub Workbook_Open()

    Dim sht As Worksheet
    Dim YearCombo As DropDown
    Dim MonthCombo As DropDown
    Dim y As Integer
    Dim m As Integer
    Dim i As Integer

    Set sht = Worksheets("Stage")

    With sht
        Set YearCombo = .DropDowns("YearCombo")
        Set MonthCombo = .DropDowns("MonthCombo")
            .DropDowns.RemoveAllItems
    End With

    For y = 2000 To 2050
        YearCombo.AddItem y
    Next y

    With YearCombo
        For i = 1 To .ListCount
            If .List(i) = Val(Year(Date)) Then
                .Selected(i) = True
            End If
        Next i
    End With

    For m = 1 To 12
        MonthCombo.AddItem m
    Next m

    With MonthCombo
        For i = 1 To .ListCount
            If .List(i) = Val(Month(Date)) Then
                .Selected(i) = True
            End If
        Next i
    End With

   Call Combo_Change

End Sub

Step 3: Combo_Change 프로시저

그 다음에는 일반 모듈시트를 한 장 삽입하고 다음과 같은 코드를 작성합니다. 이 프로시저는 앞의 Workbook_Open 이벤트 프로시저에서도 호출되었고 Stage 시트에 있는 두 개의 콤보 박스(YearCombo, MonthCombo)에도 연결되어 있습니다.

Sub Combo_Change()

    Dim sht As Worksheet
    Dim YearCombo As DropDown
    Dim MonthCombo As DropDown
    Dim rngStart As Range
    Dim MyDate As Date
    Dim r As Integer
    Dim i As Integer
    Dim intDay As Integer
    Dim yNum As Integer, mNum As Integer

    Set sht = Worksheets("Stage")

    With sht
        Set YearCombo = .DropDowns("YearCombo")
        Set MonthCombo = .DropDowns("MonthCombo")
    End With

    yNum = Val(YearCombo.List(YearCombo.ListIndex))
    mNum = Val(MonthCombo.List(MonthCombo.ListIndex))

    Set rngStart = sht.Range("Start")
    rngStart.CurrentRegion.ClearContents

    MyDate = DateSerial(yNum, mNum + 1, 0)
    intDay = Day(MyDate)

    With rngStart
        For i = 1 To intDay
            MyDate = DateSerial(yNum, mNum, i)
            .Offset(0, r) = Format(MyDate, "d")
            .Offset(1, r) = WeekdayName(Weekday(MyDate), True)
            r = r + 1
       Next i
    End With

End Sub

여러분의 많은 관심과 참여를 기다립니다. ^^

다음에 또…

정리 — 간단 달력 코드 핵심

자주 묻는 질문 (FAQ)

마치며

DateSerial과 WeekdayName만으로 간단한 달력을 만들 수 있습니다. 이 예제를 바탕으로 자신만의 달력을 만들어 보세요.