특정 글자색 제거하기

Step 1: 어떤 질문이었을까요?

원래 저는 다른 사람의 숙제에는 전혀 관심이 없습니다만, 이번 질문은 숙제와는 조금 거리가 있는 듯 하고, 또 여러 가지로 응용이 가능할 듯 하여 강좌 시간에 다루어 볼까 합니다. ^^

숙제성 질문을 올려서 해결해 달라고 하는 것은 비록 일시적 해결책은 될 지 모르겠으나 자신의 실력 향상에는 아무런 기여를 할 수 없습니다. 또한 숙제를 내주신 분의 의도와도 어긋나게 되므로 숙제성 질문은 정중히 사양합니다. 그런데…

"어떤 것이 숙제성 질문인지 그 기준을 밝혀라!"

하고 따지는(?) 분이 계실 법 하군요.

그것은… 다년간의 경험(?)으로 척 보면 압니다(진짭니다! ^^;V).

자, 본론으로 들어갑니다. 예제에 사용된 문제지는 다음과 같은 모습입니다. 정답은 빨간색으로 표시되어 있습니다.

버튼을 누르면 빨간색 정답이 한꺼번에 지워집니다. 문제가 얼마나 되든 상관이 없습니다! 코드를 볼까요?

Step 2: 코드 살펴보기

Sub DelRedChar()

    Dim rngCell As Range
    Dim rngTarget As Range
    Dim intLen As Integer
    Dim i As Integer
    Dim strTemp As String

    Set rngTarget = Columns(1).SpecialCells(xlTextValues)
    ' 첫번째 열 중에서 값이 들어있는 영역을 작업 대상으로 합니다.

    For Each rngCell In rngTarget
        intLen = Len(rngCell)
        ' 작업 대상 범위 내의 각 셀을 돌면서 셀의 문자열 길이값을 intLen 변수에 담습니다.

        For i = 1 To intLen
            ' 문자열의 길이만큼 순환을 하면서 ColorIndex 속성값이 3인지 여부를 확인합니다.
            ' 속성값이 3, 즉 빨간색이면 공란을 strTemp라는 임시 문자열 변수값에 덧붙이고
            ' 그렇지 않으면 원래 문자열의 글자를 하나씩 strTemp 변수에 더합니다.

            If rngCell.Characters(i, 1).Font.ColorIndex = 3 Then
                strTemp = strTemp & Space(1)
            Else
                strTemp = strTemp & Mid(rngCell, i, 1)
            End If
        Next i

        rngCell = strTemp
        strTemp = ""
    Next rngCell

End Sub

싱거우리만치 간단하지요? 잘 응용하시면 여러 가지로 많이 응용하실 수 있을 것입니다.

특히 문제지가 Stage와 같이 자유방임적(?)으로 구성되어 있지 않고 조금더 체계적으로 구분되어 있다면 아주 다양하게 구성할 수 있을 것입니다. 질문주신 분과 비슷한 상황에 처한 분이 계시다면 잘 정리해 보세요.

다음에 또…

정리 — 글자색 제거 코드 핵심

자주 묻는 질문 (FAQ)

마치며

코드는 싱겁게 느껴질 만큼 간단하지만 문제지처럼 자유롭게 구성된 문서뿐 아니라 체계적으로 구분된 문서에도 다양하게 응용할 수 있습니다.