자료 형태 변경하기

Step 1: 어떤 질문이었을까요?

질문주신 분의 경우, 신상명세서 자료인데 보안을 요하는 사항이므로 외부에 공개하지는 말아달라고 부탁을 하셨더랬습니다. 여러분도 질문을 주실 때, 외부에 공개되어서는 곤란한 자료인 경우에는 꼭(!) 알려주시기 바랍니다.

그건 그렇고… 질문 내용은 이렇습니다. 다음과 같은 신상명세서가 있는데 '근무경력' 란을 보면, 각각의 부서가 하나의 셀에 모두 입력되어 있으며, Alt+Enter 키를 사용하여 구분되어 있습니다.

아이엑셀러

이것을 다음과 같이 바꿀 수 없겠느냐 하는 것입니다.

아이엑셀러

어떻게 하면 될까요? 버튼을 눌러 예제를 실행시켜 보고 오시기 바랍니다.

한방에 해결이 되지요? 데이터가 1000행이든 2000행이든 상관이 없습니다. 여기서는 좀더 시각적인 효과를 나타내기 위해 일부 필요한 조치를 취하지 않은 부분도 있습니다만 데이터량이 많아지면 코드를 조금더 최적화시키면 됩니다.

Step 2: 코드 살펴보기

코드를 보도록 하지요.

Sub ChangeDataForm()

    ' 필요한 변수들을 선언합니다.
    Dim wrkSource As Worksheet
    Dim wrkOutput As Worksheet
    Dim rngTarget As Range
    Dim rngTitle As Range
    Dim rngCell As Range
    Dim varTemp As Variant
    Dim i As Integer
    Dim intCount As Long

    Set wrkSource = Sheets("Source")
    Set wrkOutput = Worksheets.Add
    Set rngTitle = Range("Title")
    Set rngTarget = wrkSource.Range("A1").CurrentRegion
    ' Source 시트의 A1 셀 인접 영역을 작업 대상으로 합니다.

    rngTitle.Copy Destination:=wrkOutput.Range("A1")
    ' 표의 타이틀 부분을 복사해서 새로 삽입한 워크시트의 첫번째 행에 붙여넣습니다.
    ' '삽입-이름' 메뉴를 사용하여 이름 정의된 영역을 살펴보세요.

    intCount = 2
    ' 삽입한 시트의 2행부터 데이터를 입력하므로 변수값을 2로 지정합니다.

    For Each rngCell In rngTarget.Offset(1, 0).Resize(rngTarget.Rows.Count - 1, 1)
    ' 여기서부터 본격적인 작업에 들어갑니다. rngTarget 영역 중에서 타이틀 부분을
    ' 제외한 전체 테이블을 대상으로 순환문을 돌립니다.
    ' Resize 메서드가 오랜만에 등장을 하였군요. 범위의 크기를 재지정하기 이해 Resize
    ' 메서드를 사용한 것입니다.

        varTemp = Split(rngCell.End(xlToRight), Chr(10))
        ' Split 함수를 사용하여 Alt+Enter 구분된 내용을 대상으로 배열을 만듭니다.

        Range(rngCell, rngCell.End(xlToRight)).Copy
        ' 행 중에서 데이터가 들어있는 영역을 복사합니다.

        For i = 0 To UBound(varTemp)
        ' varTemp 변수에 저장된 값들을 대상으로 순환문을 돌립니다. varTemp 변수에는
        ' Split 함수에 의해 Alt+Enter로 구분된 문자열들이 보관되어 있는데, 이것을 차례대로
        ' 셀에 옮겨담는 과정입니다.

            wrkOutput.Cells(intCount, 1).PasteSpecial
            wrkOutput.Cells(intCount, 6) = varTemp(i)
            intCount = intCount + 1
        Next i
    Next rngCell

    ' 작성된 영역에 대해 자동 서식을 설정합니다. 아래 부분은 자동 서식을 입히는 과정을
    ' 매크로 기록기로 기록한 다음, 편집해서 사용하면 됩니다.
    Range("A1").Select
    Selection.CurrentRegion.AutoFormat Format:=xlRangeAutoFormatList2, Number:=True, Font:= _
        True, Alignment:=True, Border:=True, Pattern:=True, Width:=True

    Columns.AutoFit
    Application.CutCopyMode = False
    MsgBox "분리작업을 완료하였습니다!", , "www.iExceller.com"

End Sub

손으로 직접 작업을 할 때의 순서를 잘 생각해 보시면 이것을 어떻게 프로그래밍 할 것인가 구체화 할 수 있을 것입니다.

링컨의 말 가운데 이런 구절이 있습니다.

다음에 또…

정리 — 자료 형태 변경 코드 핵심

자주 묻는 질문 (FAQ)

마치며

손으로 직접 작업을 할 때의 순서를 잘 생각해 보면 어떻게 프로그래밍할지가 구체화됩니다. 데이터가 2000행이든 그 이상이든 같은 방식으로 한 번에 해결할 수 있습니다.