웹 상의 그림파일 불러오기

Step 1: 웹에서 그림 불러오기

잊을만 하면 한번씩 들어오는 유형의 질문입니다. 뭐냐하면… 위에서 살펴보신 바와 같이, 그림 파일을 워크시트에 불러오는 방법에 대한 것입니다.

다른 워크시트 상에 있는 그림을 불러오는 방법이나 하드 디스크에 들어있는 그림 파일을 불러오는 방법에 대해서는 오래 전 강좌에서 다루었으므로 직접 찾아보시기 바랍니다. (앞의 것은 X0148 강좌, 뒤의 것은 VB0050 강좌로군요 ^^)

아래의 버튼을 클릭해 보세요!

상품코드를 선택하면 그에 따라 내용이 변경됨과 동시에, 상품의 이미지도 연동이 되어 바뀌게 됩니다. 이 때 나타나는 이미지는 하드디스크나 워크북에 저장되어 있는 것이 아니라 웹 상에서 불러온 것입니다.

대개의 경우, 이미지 파일은 파일에 몽땅 저장해 놓고 필요할 때마다 불러와서 사용하는 그런 과격한(?) 경우는 없습니다.

Step 2: 코드 살펴보기

그건 그렇고… 사용된 코드를 살펴볼까요?

Sub CallPicFromWeb()

    Application.ScreenUpdating = False
    ' 이미지 로딩 속도를 높이기 위해 화면 갱신을 중단합니다.

    Dim picPict As Picture
    Dim strPath As String
    Dim shtSheet As Worksheet
    strPath = "http://www.iExceller.com/MyXls/test_image/" & Range("Index2") & ".jpg"
    ' 이미지를 불러올 웹 사이트 및 파일 이름을 strPath 문자열 변수에 저장합니다.
    ' 이 때 파일 이름은 회전자와 연결되어 있는 셀(B35)에 입력된 것을 읽어 옵니다.

    Set shtSheet = Sheets("Preface")
    On Error Resume Next
    ' 작업 도중 오류가 발생하더라도 그냥 넘어갑니다.

    shtSheet.Pictures.Delete
    Set picPict = shtSheet.Pictures.Insert(strPath)
    ' 워크시트에 있는 이미지들을 지운 다음, 웹 상에 있는 이미지 파일을 가져옵니다.

    With picPict
    ' 이미지 파일을 붙여넣을 위치와 크기를 지정합니다.

        .Left = Range("ImageStart").Left + 3
        .Top = Range("ImageStart").Top + 3
        .Width = Range("ImageStart").Width * 4.58
        .Height = Range("ImageStart").Height * 15.6

        ' 이미지 파일의 테두리를 설정합니다.

        With .ShapeRange.Line
            .Weight = 3#
            .Visible = msoTrue
            .BackColor.RGB = RGB(255, 255, 255)
        End With

    End With
    Application.ScreenUpdating = True

End Sub

싱거우리만치 간단하군요. 조금만 응용하시면 자신만의 신상명세서나 인사기록부 등을 만드실 수 있을 것입니다.

다음 시간에 또…

정리 — 웹 이미지 불러오기 코드 핵심

자주 묻는 질문 (FAQ)

마치며

싱거우리만치 간단한 코드이지만 조금만 응용하면 이미지가 연동되는 신상명세서나 인사기록부 같은 문서를 만들 수 있습니다.