100점짜리 인생을 위하여

Step 1: 워크시트 함수로 계산기 만들기

저는 이 글을 읽으며, 이 분이 언급한 Attitude라는 것이 (일에 대한, 혹은 사물을 대하는) "열정"이 아닐까 생각해 보았습니다.

그러고 보니… 알파벳을 이용해서 진 장관이 소개한 계산기(?)를 만들어 보는 것도 재미가 있을 것 같지요?

아래 셀에 적당한 영문 단어(예: LOVE)를 입력하면 그 옆에 점수가 나타나도록 하려는 것입니다. 이 경우 LOVE는 54점입니다.

하여튼… 사용된 수식을 살펴보도록 하지요.

=SUM(CODE(MID(UPPER(MyCalc),ROW(INDIRECT("1:"&LEN(MyCalc))),1))-64) & "점입니다"

여기서 MyCalc라는 것은 해당 단어를 입력할 곳에 미리 이름 정의를 해 두고 사용한 것입니다. 그리고 수식의 양 끝에 {}가 붙은 것으로 보아… 배열 수식임을 한 눈에 짐작하시겠지요?

그리고 Code 함수는 해당 텍스트에 대한 숫자 코드 값을 구해주는 함수입니다. 대문자 A에 해당하는 숫자 코드 값은 65이고, 소문자 a는 97에 해당됩니다. 이러한 정보를 바탕으로, Row 함수와 Indirect 함수를 조합하여, 입력된 글자 수만큼 1:1로 매칭을 시켜 숫자 코드 값을 알아낸 다음, 합산을 하는 것입니다.

=SUM(CODE(MID(UPPER(MyCalc), SEQUENCE(LEN(MyCalc)), 1)) - 64) & "점입니다"

이해가 되시지요?

Step 2: VBA로 진대제식 계산기 만들기

이번에는 이것을 조금더 재미있게 만들어 볼까요? VBA를 이용해서 말입니다. 장관님의 이름을 따서 "진대제식 계산기"라고 이름을 붙여 보았습니다.

아이엑셀러

각 컨트롤에 연결된 이벤트 프로시저에 대해서는 VBE를 열어서 직접 살펴보시고… 여기서는 '확인' 버튼에 연결된 프로시저에 대해서만 설명 드리겠습니다.

Private Sub cmdOK_Click()

    Dim intLen As Integer
    Dim i As Integer
    Dim intNum As Integer
    Dim strChar As String
    On Error GoTo ET

    With Me.TextBox1
        If .Text = "" Then Exit Sub
        ' 아무 단어도 입력하지 않으면 프로시저를 빠져 나갑니다.

        intLen = Len(.Text)
        ' 입력된 단어가 있으면 그 단어의 길이를 intLen 변수에 담아둡니다.

        For i = 1 To intLen
            intNum = intNum + Asc(UCase(Mid(.Text, i, 1))) - 64
            ' 이 부분이 핵심입니다. 워크시트 함수를 사용하여 해결한 것과 동일한 로직입니다.
            ' 즉, 단어의 길이만큼 순환문을 돌면서 Asc 함수를 사용하여 해당 문자의 코드 값을
            ' 그때 그때마다 intNum 변수에 합산합니다. 여기서 64를 빼 준 이유는…
            ' 대문자 A의 문자 코드 값이 65이기 때문입니다.

        Next i

        Me.Height = 201
        ' 유저폼의 초기화 이벤트에서 유저폼의 크기를 작게 지정하였는데 단어의 결과 점수를
        ' 표시하기 위해 유저폼의 크기를 키웁니다.

        Me.Label1.Caption = UCase(.Text) & "는(은)"
        Me.Label2.Caption = intNum & "점 입니다!"

        ' 다음은 각 점수 구간별 안내 메시지를 표시하기 위한 부분입니다.
        With Me.Label3
            Select Case intNum
                Case 0 To 50
                    .Caption = "그다지 중요한 일이" & vbCr & "아니로군요!"
                Case 51 To 70
                    .Caption = "좀더 중요한 것을" & vbCr & "찾아보세요!"
                Case 71 To 80
                    .Caption = "이 정도면 만족할만도" & vbCr & "합니다만 조금더 노력을..."
                Case 81 To 90
                    .Caption = "중요한 일이군요." & vbCr & "Go for it!"
                Case 91 To 100
                    .Caption = "아주 중요한 일이군요!"
                Case Else
                    Me.Label1.Caption = ""
                    Me.Label2.Caption = ""
                    .Caption = "의미있는 단어로 다시 입력하세요!!"
            End Select
        End With

        .Text = ""
        .SetFocus
    End With

ET:
    If Err.Number <> 0 Then
        MsgBox Err.Description, , "에러 : " & Err.Number
        Err.Clear
    End If

End Sub

응용력을 발휘하셔서 재미있는 것들을 많이 만들어 보시기 바랍니다.

다음 시간에…

정리 — 알파벳 점수 계산기 코드 핵심

자주 묻는 질문 (FAQ)

마치며

워크시트 함수로 풀던 로직을 VBA로 옮기는 연습을 하면 사용자 정의 폼과 조건 분기까지 한꺼번에 익힐 수 있습니다. 응용력을 발휘해 재미있는 것들을 만들어 보세요.