즉석계산기능 흉내내기

Step 1: 즉석 계산기능 살펴보기

보시는 것처럼 여섯 가지의 계산 방법 중에서 하나를 선택한 다음, 숫자가 입력된 영역을 선택하면 그 결과가 바로 작업 표시줄에 나타납니다(그래서 즉석 계산기능 이라고 명명해 본 것입니다).

아이엑셀러

그건 그렇다 치고… 계산 방법을 굳이 한 가지만 선택할 것이 아니라 두 개 혹은 그 이상의 계산 결과가 동시에 나타나도록 하면 더욱 편리하지 않을까요?

눈썰미가 있는 분이라면 이미 눈치 채셨을 법도 합니다만, 숫자가 들어있는 영역을 선택하면 개수, 합계, 평균 이 세 가지 계산 방법이 함께 표시되도록 이 파일은 이미 설정이 되어 있습니다.

숫자가 들어있는 영역을 선택하신 다음, 7시 방향으로 시선을 그윽하게 내려보면 상태 표시줄에 다음과 같이 세 종류의 계산 결과가 나타나 있음을 볼 수 있습니다.

아이엑셀러

Step 2: 이벤트 프로시저 만들기

이러한 기능은 ThisWorkbook 오브젝트의 SheetSelectionChange 이벤트 핸들러 프로시저를 사용하면 가능합니다.

(1) <Alt> + F11 키를 눌러 VB Editor를 활성화시킵니다.

(2) 화면 왼쪽에 있는 프로젝트 탐색기에서 이 기능을 구현하려는 VBAProject, 즉 파일의 ThisWorkbook 개체를 더블 클릭합니다.

(3) 코드 창(Code Window)이 열리는데, 코드 창 상단에 있는 두 개의 드롭다운 버튼을 이용하여 Workbook과 SheetSelectionChange를 각각 선택하면 다음과 같이 Workbook_SheetSelectionChange 이벤트 프로시저가 생성됩니다.

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)

End Sub

여기서 파라미터(parameter, 매개변수)로 사용된 두 개의 변수 중 Sh는 해당 워크시트를, Target은 선택된 영역을 의미합니다.

(4) 이 이벤트 프로시저에 다음과 같은 코드를 작성합니다.

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)

    Dim dblCount As Double
    Dim dblSum As Double
    Dim dblAverage As Double
    Dim strCalcResult As String
    On Error GoTo ErrorHandler

    ' 상태 표시줄에 표시할 계산 결과값을 각각의 변수에 저장해 둡니다.
    dblCount = Application.WorksheetFunction.Count(Target)
    dblSum = Application.WorksheetFunction.Sum(Target)
    dblAverage = Application.WorksheetFunction.Average(Target)

    If dblCount <> 0 Then
    ' Count 함수의 계산 결과가 0이 아니면 strCalcResult 변수에 Count, Sum, Average 함수의
    ' 사용 결과값을 문자열 형태로 담아둡니다.

        strCalcResult = "개수: " & dblCount & _
            " / 합계: " & dblSum & _
            " / 평균: " & dblAverage

        Application.StatusBar = strCalcResult
        ' 상태 표시줄에 계산 결과값을 뿌려줍니다.

    Else
    ' 계산 결과값이 0이면, 즉 오류가 발생하였으면 상태 표시줄을 초기 상태(default)로
    ' 되돌리고 프로시저를 빠져 나갑니다.

        Application.StatusBar = False
    End If
    Exit Sub

ErrorHandler:
    On Error GoTo 0
    Application.StatusBar = False

End Sub

조금만 응용력을 발휘하면 분산이나 표준편차, Median값 등에 대해서도 추가하실 수 있을 것입니다. 여력이 되는 분은 여러 가지 계산 방법 중에서 사용자가 마음대로 조합을 해서 표시할 수 있도록 인터페이스를 바꾸어 보시면 재미있겠지요?

오늘은 여기까지…

정리 — 즉석 계산 코드 핵심

자주 묻는 질문 (FAQ)

마치며

조금만 응용력을 발휘하면 분산, 표준편차, 중앙값 등도 추가할 수 있고, 사용자가 원하는 계산 방법을 직접 고르도록 인터페이스를 바꿔 볼 수도 있습니다.