문장 내 특정글자 서식변경

Step 1: 연습용 시트 만들기

연습용 시트를 하나 만들어서 테스트 해 보도록 하지요. 아래 버튼을 누르세요!

버튼을 클릭하니까 시트가 새로 만들어지고 특정한 문자열에 대해서는 지정한 지정한 서식이 설정되지요?

먼저 시트를 생성하고 데이터를 옮기는 프로시저를 작성합니다. 여러 곳에서 공통으로 사용할 상수는 프로시저 바깥에 선언합니다.

Const strURL As String = "www.iExceller.com"
' 여러 곳에서 공통으로 사용할 상수를 선언합니다.

Sub TransferData()
' 먼저 시트를 생성하고 데이터를 옮기는 프로시저를 작성합니다.

    Dim rngCell As Range

    Worksheets("Preface").UsedRange.Copy
    Worksheets.Add after:=Sheets(Sheets.Count)
    Range("A1").PasteSpecial xlPasteValues
    ActiveWindow.DisplayGridlines = False

    Set rngCell = ActiveSheet.Range("A1").Offset(0, 7)

    ' 버튼을 만들고 프로시저를 연결하는 과정입니다.
    Range("A1").Select
    With rngCell
        With ActiveSheet.Buttons.Add(.Left, .Top, .Width * 2, .Height * 2)
            .OnAction = "ChangeFormat"
            ' 실제로 서식을 바꾸어 주는 것은 외부에 있는 ChangeFormat 프로시저입니다.

            .Caption = "여기를 누르세요!"
        End With
    End With
    MsgBox "연습용 시트를 만들었습니다. 버튼을 누르세요!", , strURL

End Sub

Step 2: 특정 문자열의 서식 바꾸기

다음은 사용자가 지정한 문자열에 대해 서식을 변경하는 프로시저입니다.

Sub ChangeFormat()

    Dim rngCell As Range
    Dim rngTarget As Range
    Dim rngDefault As Range
    Dim strWord As String
    Dim intFind As Integer
    Dim intLen As Integer
    Dim intStart As Integer
    On Error Resume Next

    strWord = InputBox("검색할 단어를 입력하세요! ""강아지""라고 넣어 볼까요?", strURL, "강아지")
    ' 서식을 변경할 단어를 입력받습니다. 기본값으로 '강아지'라는 단어가 들어가도록 설정하였습니다.

    intLen = Len(strWord)
    If strWord = "" Then Exit Sub
    Set rngDefault = ActiveSheet.UsedRange
    Set rngTarget = Application.InputBox("검색 범위를 지정하세요!", strURL, Type:=8, Default:=rngDefault.Address)
    ' 검색 대상 영역을 설정합니다. 기본값으로 UsedRange, 즉 현재 시트에서 사용된 범위를
    ' 대상 영역으로 하였습니다.

    For Each rngCell In rngTarget
    ' 이제부터 For Each ~ Next 순환문을 이용하여 영역 내의 모든 셀을 대상으로 '강아지'라는
    ' 문자열이 들어있나 없나 찾은 다음, 발견될 경우 서식을 변경합니다.

        intStart = 1

        Do While InStr(intStart, rngCell, strWord)
        ' 한 셀 안에 여러 개의 같은 문자열이 있을 경우에 대비, Do ~ Loop 순환문을 한번더
        ' 사용합니다.

            intFind = InStr(intStart, rngCell, strWord)
            ' 찾고자 하는 단어가 문장 내에서 몇번째에 위치하는가를 파악하여 intFind 변수에
            ' 담아두고...

            With rngCell.Characters(Start:=intFind, Length:=intLen).Font

                ' 검색한 단어의 Bold 속성이 지정되어 있지 않다면 굵은 글씨, 붉은색으로 지정합니다.
                ' Bold 속성이 이미 지정되어 있으면 해제하고 글씨색을 검정색으로 바꿉니다.
                If .Bold = False Then
                    .Bold = True
                    .ColorIndex = 3
                Else
                    .Bold = False
                    .ColorIndex = 1
                End If
            End With

            intStart = intFind + intLen
            ' 다음 단어가 있을 경우 검색을 위해 해당 단어수만큼 더해 줍니다.

        Loop
    Next rngCell

End Sub

많이 응용해 보시기 바랍니다.

다음 시간에 또...

정리 — 특정 글자 서식 변경 코드 핵심

자주 묻는 질문 (FAQ)

마치며

InStr 함수로 위치를 찾고 Characters 속성으로 서식을 지정하는 조합만 익혀 두면 웹 검색처럼 검색어를 강조하는 기능을 쉽게 만들 수 있습니다.