도착시간 찾아내기

Step 1: 어떤 질문이었을까요?

이 질문에 대해 Exceller의 홈 페이지에서 어떤 분(오태호님)이 이런 답변을 주셨군요.

=IF(ISERROR(MATCH(A2,C2:C6,0)),IF(ISERROR(MATCH(A2,D2:D6,0)),"",D1),C1)

만약 수식을 아래로 복사해야 하는 경우를 감안한다면,

=IF(ISERROR(MATCH(A2,$C$2:$C$6,0)),IF(ISERROR(MATCH(A2,$D$2:$D$6,0)),"",$D$1),$C$1)

이렇게 해 주시면 되겠습니다.

그런데, 만약 차량 대수가 더 많아지고 도착시간도 7시15분, 16분, 17분,… 등과 같이 다양해진다면 이같은 수식으로는 한계가 있습니다. 이런 경우 VBA를 이용하면 보다 융통성있게 대처할 수 있습니다. 아래 버튼을 눌러 확인해 보고 돌아오시기 바랍니다.

Step 2: 코드 살펴보기

편의상 데이터 형태를 조금 바꾸었습니다. 자료도 추가해 넣고…

프로그래밍을 하기에 앞서, Stage 시트 상의 몇 군데에 이름을 정의해 두고 후속 작업을 진행합니다. '삽입-이름-정의' 메뉴를 선택하신 다음, 어느 영역에 어떤 이름들이 정의되어 있는지 살펴보십시오(3개의 이름이 정의되어 있습니다 ^^).

Sub ArrivalTime()

    ' 필요한 변수들을 선언합니다.
    Dim rngCarNumList As Range
    Dim rngArrive As Range
    Dim rngCell As Range
    Dim rngStart As Range
    Dim strTime As String
    Dim strBlank As String
    Dim strMsg As String
    Dim i As Long
    Dim intNoData As Integer

    ' 변수의 값을 지정합니다. 사전에 정의해 둔 이름을 여기서 활용합니다.
    Set rngCarNumList = Range("CarNumList")
    Set rngStart = Range("Start")
    Set rngArrive = Range("Arrive").CurrentRegion

    ' 이미 입력되어 있는 내용(도착시간)을 지웁니다.
    MsgBox "기존 입력된 데이터를 지웁니다!", , "www.iExceller.com"
    rngCarNumList.Offset(0, 1).ClearContents

    ' 오래간만에 Do ~ Loop 문을 사용해 보았습니다.
    Do
        strTime = ""

        ' rngArrive, 즉 차량들의 도착시간 데이터가 들어있는 영역 중에서 각 차량의 번호를
        ' 찾아냅니다. 이 때 Find 메서드를 사용하였군요.
        Set rngCell = rngArrive.Find(What:=Range("Start").Offset(i, 0), LookIn:=xlValues, LookAt:=xlWhole)

        ' 차량번호를 도착 시간 데이터에서 찾았느냐 못찾았느냐에 따라 조건분기 처리를 합니다.
        If Not rngCell Is Nothing Then
            strTime = rngCell.End(xlUp)
        Else
            strTime = "No Data!"
            strBlank = strBlank & Range("Start").Offset(i, 0) & vbCr
            intNoData = intNoData + 1
        End If

        Range("Start").Offset(i, 1) = strTime
        i = i + 1

    ' 루프문을 언제 종료할 지 지정합니다. Start 영역, 즉 A2 셀에서 한 간씩 아래로 내려가다가
    ' 값이 들어있지 않는 셀을 만나면 종료를 하는군요.
    Loop While Range("Start").Offset(i, 0) <> ""

    strMsg = strMsg & "작업을 완료하였습니다." & vbCr
    strMsg = strMsg & "도착기록이 없는 차량은 " & intNoData & "대 입니다" & vbCr & vbCr
    strMsg = strMsg & strBlank
    MsgBox strMsg, vbInformation, "www.iExceller.com"

End Sub

다음 시간에…

정리 — 도착시간 찾기 코드 핵심

자주 묻는 질문 (FAQ)

마치며

데이터가 많아지고 조건이 다양해지면 수식보다 VBA가 훨씬 융통성 있게 대처할 수 있습니다. Find와 End(xlUp)의 조합을 익혀 두세요.