일정 간격마다 밑줄 긋기

Step 1: 무엇을 만들까요?

이번 시간에는 사용자가 지정한 간격마다 자동으로 밑줄을 그리는 방법에 대해 살펴보도록 하겠습니다. 아래 버튼을 클릭하신 다음 2 ~ 10 사이의 숫자를 입력해 보시기 바랍니다.

이 범위를 벗어나는 숫자를 입력하면 InputBox가 계속 나타나므로 다음 단계로 넘어가지 않도록 설정되어 있습니다. 예제 표(세 자리 이하의 임의의 숫자가 채워진 4열 표)에 입력한 간격마다 밑줄이 그려집니다.

Step 2: 코드 살펴보기

코드를 보도록 하겠습니다.

Const ID As String = "www.iExceller.com"
' 여러 곳에서 사용되는 상수를 프로시저 외부에 선언합니다.

Sub DrawLines()

    Dim intLine As Integer
    Dim intTotalRow As Integer
    Dim i As Integer
    Dim strInput As String
    Dim rngTarget As Range
    On Error GoTo ET
    Set rngTarget = Range("MyRange")
    intTotalRow = rngTarget.Rows.Count
    ' MyRange 라는 영역을 작업 대상으로 설정합니다(MyRange가 어떤 영역인지 이름 상자를 통해
    ' 직접 확인해 보시기 바랍니다). 그런 다음 MyRange 영역의 행 수를 세어서 intTotalRow 라는
    ' 변수에 담아둡니다.

    MsgBox "영역 내의 밑줄을 지우겠습니다", , ID
    With Range("Myrange")
    ' 대상 영역 내에 이미 밑줄이 그어져 있을 지도 모르므로 일단 밑줄을 지웁니다.

        .Borders(xlEdgeBottom).LineStyle = xlNone
        .Borders(xlInsideHorizontal).LineStyle = xlNone
    End With

    Do
        strInput = InputBox("몇 라인마다 밑줄을 그릴까요?", "2~10 사이의 숫자값만 입력하세요")
        If strInput = "" Then Exit Sub
        intLine = Val(strInput)
    Loop While intLine > 10 Or intLine < 2
    ' Do ~ Loop 반복문을 사용하여 사용자가 2 ~ 10 사이의 숫자가 입력될 때까지 계속합니다.

    For i = 1 To intTotalRow
        If i Mod intLine = 0 Or i = intTotalRow Then
        ' 일정 행마다 반복된다는 것은 다른 말로 하면 일정 값으로 나누어 나머지 없이 떨어진다는
        ' 의미이겠지요? 이것을 컴퓨터(엑셀)가 알아먹을 수 있게 표현하면 위와 같이 될 것입니다.
        ' 그리고 데이터 맨 마지막 줄에는 무조건 밑줄을 그리기 위해 'Or i=intTotalRow' 라는 구문을
        ' 추가해 주었습니다.

            Range("MyRange").Rows(i).Select
            With Selection.Borders(xlEdgeBottom)
                .LineStyle = xlContinuous
                .Weight = xlThin
            End With
        End If
    Next i
    Range("MyRange").Cells(1).Select
    MsgBox "매 " & intLine & "라인마다 밑줄을 그렸습니다", , ID

ET:
' 실행 도중 예기치 않은 오류가 발생하였을 경우에 대한 에러 트래핑 구문입니다.

    If Err.Number <> 0 Then
        MsgBox Err.Description, , "에러 번호 : " & Err.Number
        Err.Clear
    End If

End Sub

핵심은 i Mod intLine = 0 조건입니다. 일정 행마다 반복된다는 것은 행 번호가 그 값으로 나누어떨어진다는 뜻이므로 Mod 연산자로 판단합니다. 그리고 마지막 행에는 항상 밑줄을 긋도록 Or i = intTotalRow 조건을 더했습니다.

생각보다 코드가 간단하지요? 많이 응용해 보시기 바랍니다.

오늘은 여기까지…

정리 — 밑줄 긋기 핵심 코드

자주 묻는 질문 (FAQ)

마치며

Mod 연산자는 일정 주기로 반복되는 작업에 자주 쓰이므로 다양하게 응용해 보시기 바랍니다.