수식이 입력된 셀에 수식을 메모로 달기

Step 1: 무엇을 만들까요?

사업본부별, 월별 매출을 정리한 표가 있습니다. 이 표에서 분기계, 지점계 부분에는 수식이 입력되어 있습니다. 수식이 입력된 셀의 수식을 메모(주석)로 삽입해 보겠습니다.

버튼을 누르고 대상 영역을 지정하면, 영역 안에서 수식이 들어 있는 모든 셀에 메모가 삽입되면서 수식이 그대로 옮겨집니다.

Step 2: 코드 살펴보기

Sub AddFomulaToComment()

    Const strID As String = "www.iExceller.com"
    Dim rngCell             As Range
    Dim rngTarget           As Range
    Set rngTarget = Application.InputBox(prompt:="대상 영역을 선택하세요", _
        Type:=8, Default:=[Start].CurrentRegion.Address)
    ' 사용자로부터 영역을 지정받습니다.

    MsgBox "먼저, 지정하신 영역 내의 메모를 모두 지웁니다", , strID
    DelComments rngTarget
    ' 지정된 영역 내에 메모가 이미 들어있다면 이를 지우기 위한 외부 프로시저를 실행시킵니다.
    ' 이 때 rngTarget, 즉 사용자가 지정한 영역을 함께 변수로 넘겨 실행합니다.

    MsgBox "메모를 모두 제거하였습니다. 이제 수식을 메모로 옮깁니다", , strID

    For Each rngCell In rngTarget
        With rngCell
            If .HasFormula Then
            ' 셀에 수식이 들어있으면 AddComment 메서드를 사용하여 메모를 삽입합니다.
            ' 메모에 텍스트를 추가할 때에는 Text 메서드를 사용합니다.

                .AddComment Text:=.Formula
            End If
        End With
    Next rngCell
    MsgBox "수식이 들어있는 모든 셀에 메모를 삽입하였습니다", , strID

End Sub

먼저 Application.InputBox의 Type을 8로 지정해 대상 영역을 입력받고, 이미 들어 있는 메모를 지운 다음 영역의 각 셀을 순환하면서 HasFormula 속성으로 수식 여부를 확인합니다. 수식이 있는 셀에는 AddComment 메서드로 메모를 만들고 .Formula를 메모 내용으로 넣습니다.

기존 메모를 지우는 외부 프로시저 DelComments는 다음과 같이 작성할 수 있습니다. 대상 영역을 인수로 받아 메모가 있는 셀의 메모를 삭제합니다.

Sub DelComments(rngTarget As Range)

    Dim rngCell             As Range
    For Each rngCell In rngTarget
        If Not rngCell.Comment Is Nothing Then rngCell.Comment.Delete
    Next rngCell

End Sub

많이들 응용해 보세요!

다음 시간에 또…

정리 — 수식 메모 삽입 핵심 코드

자주 묻는 질문 (FAQ)

마치며

수식을 메모로 남겨 두면 복잡한 표의 계산 구조를 한눈에 확인할 수 있습니다. 다양하게 응용해 보시기 바랍니다.