선택 영역에 화살표 그리기

Step 1: 어떤 질문이었을까요?

Step 2: 셀 서식으로 사선 그리기

화살 선은 아니고 사선이 채워지도록 할 수는 있습니다.

(1) 선을 그릴 범위를 지정하고 서식-셀 메뉴를 선택합니다. (2) 테두리 탭을 선택하고 테두리 항목에서 대각선 방향을 클릭하면 아래와 같이 사선이 그려집니다.

Step 3: 화살표를 자동으로 그리는 매크로

이 질문을 접하고 한 가지 생각나는 것이 있어 만들어 보았습니다. 아래의 버튼을 누른 다음 적당한 영역을 선택해 보세요.

Sub DrawingArrow()

    Dim rngTarget           As Range
    Dim sngLeft             As Single
    Dim sngTop              As Single
    Dim sngWidth            As Single
    On Error GoTo ET
    ' 늘 그러하듯이… 필요한 변수를 선언해 줍니다.

    Set rngTarget = Application.InputBox("화살표를 그려넣을 범위를 지정하세요", Type:=8)
    ' InputBox 메서드를 사용하여 사용자가 설정한 영역(Range)을 rngTarget 변수에 담습니다.

    With rngTarget
        sngLeft = .Left
        sngWidth = sngLeft + .Width
        sngTop = .Top + .RowHeight / 2
    End With
    ' rngTarget 영역의 왼쪽 위치, 상단 위치를 파악하여 변수에 각각 담아 둡니다.
    ' 화살표를 셀의 중간에 그리기 위해 RowHeight 속성을 반으로 나누었습니다.

    ActiveSheet.Shapes.AddLine(sngLeft, sngTop, sngWidth, sngTop).Select
    With Selection.ShapeRange.Line
        .BeginArrowheadStyle = msoArrowheadOval
        .EndArrowheadStyle = msoArrowheadTriangle
    End With
    Selection.TopLeftCell.Select
    ' 선택한 영역에 화살표를 그려주는 부분입니다.
    ' 화살표 시작 부분은 둥글게, 끝나는 부분은 삼각형으로 설정합니다.

ET:
' 실행 도중 에러가 발생한 경우에 대비한 에러 트래핑 구문입니다.

    If Err.Number <> 0 Then
        MsgBox "Error 발생 : " & Err.Number, , Err.Description
        Err.Clear
    End If

End Sub

Application.InputBox의 Type을 8로 지정하면 사용자가 마우스로 범위를 선택할 수 있습니다. 선택한 영역의 왼쪽 위치와 너비, 첫 행의 세로 중간 위치를 계산해 Shapes.AddLine으로 선을 그리고, 시작점은 원(msoArrowheadOval), 끝점은 삼각형(msoArrowheadTriangle)으로 지정했습니다.

그려지긴 하는데 항상 선택 영역의 첫번째 행에만 그려지고, 화살표의 모양새도 그렇고… 여러 가지 면에서 융통성이 없을 것입니다. 나머지 부족한 부분에 대해서는 여러분이 응용력을 발휘하여 보완해 보시기 바랍니다. 유저폼을 사용하여 사용자가 여러 가지 변화를 줄 수 있도록 사용자 입장에서 만들어 보세요. 아주 재미있지 않겠습니까? 게임이나 하면서 Time Killing 하는 것 하고는 비할 바가 아니지요.

다음 시간에…

정리 — 화살표 그리기 핵심 코드

자주 묻는 질문 (FAQ)

마치며

이 예제는 항상 선택 영역의 첫 행에만 그려지는 단순한 형태입니다. 유저폼을 활용해 사용자가 옵션을 고를 수 있도록 확장해 보시기 바랍니다.