VBA로 VBA 코드 작성하기

Step 1: 어떤 질문이었을까요?

라벨과 텍스트박스, 체크박스, 커맨드버튼 등을 VBA 코드로 만들어 넣는 데까지는 성공했는데, 이 개체들의 이벤트는 어떻게 설정하느냐는 질문이었습니다. 디자인 모드에서 개체를 만들면 마우스 클릭 몇 번으로 Private Sub cmd_Cancel_Click() 같은 이벤트 프로시저가 자동으로 생기는데, 코드로 생성한 개체의 이름은 어떻게 알 수 있고 이벤트는 어떻게 설정하느냐는 것입니다.

Step 2: VBA로 VBA 코드 작성하기

개체의 이름은 개체를 삽입할 때마다 자동으로 부여가 됩니다. 개체의 이름은 해당 개체의 Name 속성을 사용하시면 되겠지요? 이번 시간에는 VBA 코드를 VBA로 작성하는 방법에 대해 설명드리겠습니다.

혹 매크로 바이러스 코드를 잘 살펴보신 분이 계시다면 짐작하시겠지만, 매크로 바이러스가 바로 질문하신 것과 같은 방식으로 코드를 복제하므로 우려가 되지 않는 것은 아닙니다만, Exceller의 홈을 찾아주시는 분들이라면 바이러스를 만들어 유포하는 색다른(?) 취미를 가진 분은 없으리라 믿고 힌트를 드립니다. ^^ 아래 버튼을 눌러 보세요.

새로운 시트가 생성됨과 동시에 그 시트의 Code Module에도 코드가 생성되었지요?

아이엑셀러

먼저, 위의 'Click Me!!!' 버튼에 연결된 코드입니다.

Private Sub CommandButton1_Click()

    On Error Resume Next
    AddCode
    ' 일반 모듈에 있는 AddCode 프로시저를 호출합니다.

    If Err <> 0 Then
        MsgBox "오류가 발생하였습니다", , "www.iExceller.com"
    Else
        MsgBox "상단의 버튼을 누르시면 원래 시트로 되돌아갑니다", , "www.iExceller.com"
    End If

End Sub

이번에는 AddCode 프로시저의 내용을 보도록 하지요.

Sub AddCode()

    Dim shtNewSheet As Worksheet
    Dim btnButton As OLEObject
    Dim strNewSheet As String
    Dim strCode As String
    Dim intLines As Integer
    Set shtNewSheet = Worksheets.Add
    strNewSheet = shtNewSheet.CodeName
    Set btnButton = shtNewSheet.OLEObjects.Add("Forms.CommandButton.1")
    ' 워크시트를 한 장 추가하고 CommandButton 컨트롤을 삽입합니다.

    With btnButton
        .Left = 0
        .Top = 0
        .Width = 100
        .Height = 25
        .Object.Caption = "<<Back"
    End With
    ' 커맨드 버튼의 위치와 크기, 캡션 속성을 설정하고...

    strCode = strCode & "Private Sub CommandButton1_Click()" & vbCr
    strCode = strCode & "    On Error Resume Next" & vbCr & vbCr
    strCode = strCode & "    Sheets(""Preface"").Activate" & vbCr
    strCode = strCode & "    If Err <> 0 Then" & vbCr
    strCode = strCode & "        MsgBox ""오류가 발생하였습니다!""" & vbCr
    strCode = strCode & "    End If" & vbCr
    strCode = strCode & "End Sub"
    ' Code Module에 삽입할 코드를 strCode라는 문자열 변수에 담아 둡니다.

    With ThisWorkbook.VBProject.VBComponents(strNewSheet).CodeModule
        intLines = .CountOfLines + 1
        .InsertLines intLines, strCode
    End With
    ' intLines 변수는 현재 모듈 내의 코드 라인 수를 파악한 다음 거기에 1을 더한 값을 가집니다.
    ' 이렇게 하는 이유는, 만약 사용자의 PC가 모듈이 삽입될 때마다 Option Explicit 이라는
    ' 구문을 추가하도록 세팅되어 있다면 오류가 발생하기 때문입니다.
    ' 그런 다음 InsertLines 메서드를 사용하여 모듈의 마지막 부분에 strCode, 즉 코드를 추가해
    ' 나가는 것입니다.

End Sub

핵심은 VBProject.VBComponents(...).CodeModule의 InsertLines 메서드입니다. 새 시트의 CodeName으로 해당 시트의 코드 모듈에 접근한 뒤, 그 안에 문자열로 만든 코드를 삽입하는 방식입니다. 개체의 이름은 삽입될 때 자동으로 부여되며 Name 속성으로 확인할 수 있으므로, 처음 만든 커맨드 버튼은 CommandButton1이라는 이름의 이벤트 프로시저를 가지게 됩니다.

삽입 위치를 CountOfLines에 1을 더한 값으로 지정한 이유는, 사용자 PC가 모듈 생성 시 Option Explicit 구문을 자동으로 추가하도록 설정되어 있더라도 오류가 나지 않게 하기 위해서입니다.

다음 시간에 또...

정리 — 코드로 코드 작성하기 핵심

자주 묻는 질문 (FAQ)

마치며

코드를 코드로 작성하는 방법은 강력한 만큼 신중하게 사용해야 합니다. 이벤트를 동적으로 연결해야 하는 개체 생성 작업에 응용해 보시기 바랍니다.