사용 기한이 지나면 스스로 삭제되는 파일 만들기

Step 1: 무엇을 만들까요?

지난 X0280, X0281 강좌에서는 VBA를 사용하지 않고 워크시트 상에서 사용자 지정 도구모음을 만드는 방법에 대해 살펴보았습니다.

이번 시간에는 이것을 조금 응용하여 아주 재미난(생각하기 따라서…) 것을 만들어 보도록 합니다. 강좌 제목으로도 알 수 있듯이, 특정한 날짜가 되면 사용자가 추가한 '사용자 지정 메뉴'가 없어지고 더 나아가서 파일 자체도 쥐도 새도 모르게 사라지도록 해 봅니다.

사용 기한이 지나면 사라지는 시험판(체험판) 파일이나 일정 기간만 유효한 양식을 배포할 때 응용할 수 있는 아이디어입니다. 다만 파일을 삭제하는 코드이므로 예제 파일에서는 안전을 위해 파일 삭제 부분을 주석 처리해 두었습니다.

Step 2: 사용자 정의 메뉴 만들기

먼저 사용자 지정 메뉴를 만들어야 겠지요? 그래야 죽이든 살리든 할 테니까… 그런데 아마도 사용자의 환경이 다 틀릴 것입니다. 즉 어떤 분은 아주 착실하게 Exceller가 시키는(?) 대로 '나의 메뉴'라는 사용자 지정 메뉴를 추가한 분이 있는가 하면, '나의 메뉴'가 아니라 'OOO의 메뉴'와 같이 자신의 이름으로 만든 분도 있을 것이고, 메뉴를 만들었다가 깔끔한 성격에 다시 원래 상태로 되돌려 놓은 분도 있을 것입니다. 해서…

예제의 첫 번째 버튼을 누르면 '도움말' 메뉴 옆에 '나의 메뉴'라는 메뉴가 만들어집니다. 기존에 동일한 이름의 메뉴가 있었다면 지우고 새로 만듭니다. 두 번째 버튼을 누르면 '나의 메뉴'가 사라집니다. 원래 의도대로라면 사용자 정의 메뉴뿐만 아니라 지금 보고 계시는 강좌 파일도 함께 없어져야 하지만, 강좌를 진행할 수 없게 되므로 파일을 삭제하는 부분은 실행하지 않도록 해 두었습니다.

Sub RemoveMyMenuAndWorkbook()

    If Int(Now) >= DateSerial(2002, 8, 8) Then
    ' 만약 오늘 날짜가 2002년 8월 8일 이후라면…

        CommandBars("worksheet menu bar").Controls("나의 메뉴").Delete
        ' RemoveWorkbook
        ' '나의 메뉴'를 제거하고 RemoveWorkbook이라는 프로시저를 실행합니다.
        ' 위 프로시저를 실행하면 현재 강좌 파일도 날아갈 우려가 있어서
        ' 주석처리를 하였습니다.
    End If

End Sub

Step 3: 파일이 스스로 삭제되게 하기

다음은 RemoveWorkbook 프로시저의 내용입니다.

Sub RemoveWorkbook()
    Dim wrkWorkbook As Workbook
    Dim strFilename As String
    Dim intLine As Integer
    Dim i As Integer
    strFilename = ThisWorkbook.FullName
    Set wrkWorkbook = Workbooks.Add
    wrkWorkbook.VBProject.VBComponents.Add 1

    With wrkWorkbook
        For i = 1 To .VBProject.VBComponents.Count
            If .VBProject.VBComponents(i).Type = 1 Then
                intLine = .VBProject.VBComponents(i).CodeModule.CountOfLines
                With .VBProject.VBComponents(i).CodeModule
                    .InsertLines intLine + 1, "Sub killingMyself()"
                    .InsertLines intLine + 2, "Kill " & Chr(34) & strFilename & Chr(34)
                    .InsertLines intLine + 3, "ThisWorkbook.Close savechanges:=False"
                    .InsertLines intLine + 4, "End Sub"
                End With
            End If
        Next i

        Application.OnTime Now + TimeValue("00:00:01"), .Name & "!killingMyself"
    End With
    ThisWorkbook.Close savechanges:=False
    ' 자기가 자기를 제거할 수는 없으니까 자기 자신을 Book1.xls라는 파일에 잠시
    ' 복제를 해 둔 다음, ActiveWorkbook 즉 자신은 자결(?)을 하는 것입니다. 그런 다음
    ' ThisWorkbook, 즉 Book1.xls 파일을 저장하지 않고 닫아버리는 것이지요.
    ' 여기서 Book1의 역할이 인체 기증자나 유의태의 역할과 비슷하지 않습니까?
    ' 아님 말고… *^^*
End Sub

자기가 자기 자신을 삭제할 수는 없으므로 자기 자신을 삭제하는 코드를 새 통합 문서(Book1)에 작성해 두고, 원래 파일은 저장하지 않고 닫습니다. 그러면 1초 뒤에 OnTime으로 예약해 둔 killingMyself 프로시저가 실행되어 원래 파일을 삭제합니다.

아이디어 자체는 매우 단순합니다. 그렇지만 늘 그래왔듯이… 응용 여하에 따라 재미있는 일을 하도록 만들 수 있을 것입니다.

정리 — 자기 삭제 핵심 코드

자주 묻는 질문 (FAQ)

마치며

아이디어 자체는 단순하지만 응용하기에 따라 사용 기한이 있는 배포용 파일 등을 만드는 데 활용할 수 있습니다.