지정된 시간에 프로시저 실행하기 (OnTime)

Step 1: 프로시저 실행을 잠시 정지시키기

VBA에서 프로시저의 실행을 제어하는 방법으로는 아래와 같은 방법들이 있습니다.

• Stop 문(Statement): 프로시저의 실행을 중지
• Wait 메서드: 지정한 시간 동안 프로시저의 실행을 중지

Stop 문을 사용하면 프로시저의 실행이 중단되고 VB Editor가 나타나면서 디버그 상태가 됩니다. 예제 버튼을 누르면 메시지 상자가 나타나고, 확인을 선택하면 아래 그림과 같은 디버깅 상태가 됩니다. 이때 실행 아이콘을 누르면 나머지 코드가 계속 실행됩니다.

Sub StopStatement()

    MsgBox "Stop문을 실행하겠습니다!", , "www.iExceller.com"
    Stop
    MsgBox "Stop문을 실행하였습니다!", , "www.iExceller.com"

End Sub

아이엑셀러

Stop 문을 사용하는 것은 아래와 같이 프로그램 상에 '중단점'을 두는 것과 비슷한 역할을 수행합니다.

아이엑셀러

그런데 예를 들어 "프로시저를 5초간 실행 정지한다, 10초간 정지한다" 라고 할 때에는 Wait 메서드를 사용하면 됩니다.

Sub WaitMethod()

    MsgBox "5초 동안 프로시저 실행을 정지합니다. 확인 버튼을 누르세요", , "www.iExceller.com"
    Application.Wait Now + TimeValue("00:00:05")
    MsgBox "5초가 지났습니다!", , "www.iExceller.com"

End Sub

Wait 메서드로 실행하는 도중에는 엑셀을 손으로 조작할 수는 없게 됩니다. 다만 인쇄 등과 같은 백그라운드로 작동되는 작업은 중단없이 계속 실행됩니다.

Step 2: 지정된 시간에 프로시저 실행하기

이번에는 미리 설정한 시간에 프로시저가 실행되도록 하는 방법에 대해 살펴보도록 하겠습니다. 이 방법을 이용하면 영업장의 일일 마감이 끝난 오후 7시에 정기적인 실적 집계를 실행한다거나 하루 동안 서버에 저장해 둔 데이터를 부하가 적은 새벽 시간에 자동으로 집계하고 결과 처리를 한다거나 하는 등의 작업을 수행할 수 있게 됩니다.

이러한 기능을 구현할 때 사용하는 것이 OnTime 메서드입니다.

Sub OnTimeMethod()
    Dim Msg As String
    Msg = Msg & "10초 후에 ""영업실적집계"" 프로시저를 실행합니다" & vbCr
    Msg = Msg & "확인 버튼을 누르세요"

    MsgBox Msg, , "www.iExceller.com"
    Application.OnTime Now + TimeValue("00:00:10"), "영업실적집계"
    ' OnTime 메서드는 프로시저가 지정한 시간, 즉 하루 중 특정 시간 또는 지정한 만큼의
    ' 시간이 경과된 후에 실행되도록 해 줍니다. 여기서는 지금부터 10초 후에 "영업실적집계"
    ' 라는 프로시저를 실행하도록 설정하였습니다. 물론 이 때에는 Wait 메서드와는 달리
    ' 10초가 되기 전에도 사용자는 다른 작업을 수행할 수 있습니다.

    ' 만약 오후 7시에 "집계처리"라는 프로시저를 실행하려면 아래와 같이 하면 되겠지요?
    ' Application.OnTime TimeValue("19:00:00"), "집계처리"

    ' 앞 예제의 OnTime 설정을 해제하려면…
    ' Application.OnTime EarliestTime:=TimeValue("19:00:00"), Procedure:="집계처리", Schedule:=False

End Sub

Sub 영업실적집계()
    ' 필요한 작업들을 이 부분에 기재하시면 되겠지요?
    MsgBox "영업실적집계 프로시저가 실행되었습니다", , "www.iExceller.com"
End Sub

OnTime 메서드를 여러 번 사용하면 여러 시간대에 걸쳐 실행되는 프로시저를 각각 작성, 사용할 수 있습니다. 이 방법 외에도 다양한 용도로 응용해 보시기 바랍니다.

다음 시간에…

정리 — 시간 제어 핵심 코드

자주 묻는 질문 (FAQ)

마치며

OnTime을 여러 번 사용하면 여러 시간대에 실행되는 프로시저를 각각 예약할 수 있으니 다양한 용도로 응용해 보시기 바랍니다.