숫자를 시간으로 바꾸기

Step 1: 어떤 질문이었을까요?

셀에 숫자가 들어 있는데 실제로는 시간입니다. 예를 들어 0930이라는 숫자를 09:30으로 바꾸어야 합니다. 그런데 숫자가 모두 자릿수가 같다면 Time 함수를 쓰면 되지만, 130처럼 세 자리로 된 값도 있어서 곤란하다는 질문이었습니다.

Step 2: 자릿수가 같다면 TIME 함수로 간단히

데이터의 자릿수가 모두 네 자리로 같다면 워크시트의 TIME 함수로 간단히 해결됩니다.

그러나 세 자리와 네 자리가 섞여 있고, 문자열 데이터나 시간으로 바꿀 수 없는 데이터까지 섞여 있다면 어떻게 해야 할까요? 예제의 표에서 버튼을 누르면 변환 가능한 값은 시간 형태로, 그렇지 않은 값은 오류 메시지로 옆 셀에 표시됩니다.

Step 3: 코드 살펴보기

잘 되지요? 코드를 볼까요?

Sub ChangeNumToTime()

    Dim i As Long
    Dim rngStart As Range
    Dim strVal As String
    Dim lngHour As Long
    Dim lngMin As Long
    Set rngStart = [Start]
    rngStart.CurrentRegion.Columns(2).ClearContents

    Do
    ' Do ~ Loop 문으로 순환을 합니다. 언제까지 순환을 하느냐 하면 rngStart 셀에서
    ' 아래로 내려 가다가 공백 셀이 나타날 때까지 합니다.

        With rngStart
        ' 셀 값을 순차적으로 접근하면서 조건 검색을 합니다.
            strVal = Trim(.Offset(i, 0).Value)

            If Not IsNumeric(strVal) Or Len(strVal) > 4 Or Len(strVal) < 3 Then
            ' 만약 셀 값이 숫자 형태가 아니거나 데이터 자리수가 4보다 크거나 3자리 보다 작으면
            ' 에러 메시지를 옆 셀에 표시합니다.
                .Offset(i, 1) = "잘못된 데이터입니다!"
            Else
                ' 뒤의 두 자리는 분, 그 앞의 한두 자리는 시간으로 처리합니다. 이 때 TimeSerial 이라는
                ' VBA 함수를 사용하였습니다. 시간이 23 이하, 분이 59 이하인 경우에만 변환합니다.
                lngMin = CLng(Right(strVal, 2))
                lngHour = CLng(Left(strVal, Len(strVal) - 2))
                If lngHour > 23 Or lngMin > 59 Then
                    .Offset(i, 1) = "잘못된 데이터입니다!"
                Else
                    .Offset(i, 1) = TimeSerial(lngHour, lngMin, 0)
                    .Offset(i, 1).NumberFormatLocal = "hh:mm"
                    ' 데이터 변환 작업이 끝났으면 셀 서식을 바꾸어 줍니다.
                End If
            End If
        End With
        i = i + 1
    Loop Until IsEmpty(rngStart.Offset(i, 0))

End Sub

세 자리 값은 앞 한 자리를 시간으로, 네 자리 값은 앞 두 자리를 시간으로 처리하고 뒤의 두 자리는 언제나 분으로 처리합니다. 숫자가 아니거나 자릿수가 맞지 않거나 시간·분의 범위를 벗어나는 값은 '잘못된 데이터입니다!'로 표시합니다.

다음 시간에 또…

정리 — 숫자를 시간으로 변환하는 핵심 코드

자주 묻는 질문 (FAQ)

마치며

데이터를 변환할 때는 정상적인 경우뿐 아니라 잘못된 값이 들어왔을 때의 처리까지 함께 고려해 두는 것이 좋습니다.