배율 자동 조절하기

Step 1: 결과 미리 보기

버튼을 누른 다음 마우스로 적당한 영역을 선택하면 화면 배율이 자동으로 조절되어 그 영역이 화면 가득 채워집니다. 어떻게 만들었는지 살펴보겠습니다.

Step 2: 유저폼 만들기

(1) VB Editor 상태에서 유저폼을 하나 삽입하고 그림과 같이 컨트롤을 그려 넣습니다. 척~ 보면 아시겠지만... 다섯 종류, 7개의 컨트롤이 사용되었습니다.

아이엑셀러

Step 3: Initialize 이벤트

(2) 유저폼의 빈 공간을 더블 클릭하고 Initialize 이벤트를 선택한 다음 코드를 작성합니다.

Private Const strZoom As String = "현재 화면 배율은 "

Private Sub UserForm_Initialize()
    RefEdit1.Text = Selection.CurrentRegion.Address
    ' 현재 셀 포인터가 위치해 있는 셀 주변 영역의 주소를 RefEdit 컨트롤의 기본값으로 설정합니다.

    ActiveWindow.Zoom = 100
    lblZoom.Caption = strZoom & ActiveWindow.Zoom & "% 입니다"
    ' 현재 화면의 배율을 100으로 설정하고 lblZoom 레이블에 표시를 합니다.

    With scrZoom
    ' 아래 부분은 scrZoom 스크롤 바의 기본값을 세팅하는 과정입니다.

        .Min = 25
        .Max = 400
        .SmallChange = 1
        .LargeChange = 10
        .Value = 100
    End With
    RefEdit1.SetFocus
    ' 포커스를 RefEdit1 개체로 옮깁니다.

End Sub

RefEdit 컨트롤의 기본값을 셀 포인터가 있는 인접 영역의 주소로 설정하고, 화면 배율을 100으로 초기화하여 레이블에 표시합니다. 스크롤 바의 최솟값(25), 최댓값(400), 변화량, 기본값도 여기서 설정합니다.

Step 4: 스크롤 바 Change 이벤트

(3) 개체 선택 드롭다운 버튼과 이벤트 선택 드롭다운 버튼을 각각 클릭하여 scrZoom 오브젝트의 Change 이벤트를 선택하고 해당 코드를 입력합니다.

Private Sub scrZoom_Change()
' Change 이벤트, 즉 scrZoom 컨트롤의 좌/우 버튼 등을 클릭할 때마다 Window 오브젝트의 Zoom
' 속성을 이용하여 화면의 크기를 조절하고 lblZoom 레이블에 표시를 해 줍니다.

    With ActiveWindow
        .Zoom = scrZoom.Value
        lblZoom.Caption = strZoom & .Zoom & "% 입니다"
    End With
End Sub

스크롤 바의 좌우 버튼 등을 클릭할 때마다 Window 오브젝트의 Zoom 속성으로 화면 배율을 조절하고 레이블에 표시합니다.

Step 5: 확인 버튼 코드

(4) Shift + <F7> 키를 눌러 유저폼 상태로 돌아온 다음 '확인' 버튼을 더블 클릭합니다. 아래 부분이 오늘 강좌의 핵심입니다!

Private Sub cmdOK_Click()
    Dim rngTarget As Range
    Dim lngZoom As Long
    Dim blnRow As Boolean
    Dim lngRow As Long
    Dim intCol As Integer
    lngZoom = ActiveWindow.Zoom

    On Error Resume Next
    Set rngTarget = Range(RefEdit1.Text)
    On Error GoTo 0
    If rngTarget Is Nothing Then
    ' 만약 범위가 올바르지 않으면 RefEdit1 컨트롤로 포커스를 옮기고 프로시저를 종료합니다.
        MsgBox "범위를 다시 선택하세요!", , "www.iExceller.com"
        RefEdit1.SetFocus
        Exit Sub
    End If
    lngRow = rngTarget.Rows.Count
    intCol = rngTarget.Columns.Count

    blnRow = IIf(intCol > lngRow, False, True)
    ' 행의 수와 열의 수를 비교하여 어느 것을 기준으로 화면 배율을 조절할 것인지 결정합니다.
    ' 위의 문장은 원래,
    ' If intCol>lngRow Then
    '     blnRow=False
    ' Else
    '    blnRow=True
    ' End If
    ' 이렇게 써야 할 것을 한 줄로 축약해서 표현한 것입니다.

    ChangeZoomRate rngTarget, lngZoom, blnRow
    ' ChangeZoomRate라는 프로시저를 실행시킵니다. 이 때 세 가지 인수를 함께 건네줍니다.
    ' 세 가지 인수는 각각 셀 포인터가 있는 인접 영역 주소, 화면 배율, True(또는 False) 값 입니다.

End Sub

Step 6: 배율 조절 프로시저

(5) 이번에는 '삽입-모듈' 메뉴를 선택하여 모듈 시트를 한 장 삽입하고 코드를 작성합니다. 아래 부분이 오늘 강좌의 핵심입니다!

Sub ChangeZoomRate(ByVal rngX As Range, lngX As Long, blnRow As Boolean)
    Dim winWindow As Window
    Application.ScreenUpdating = False
    Application.Goto rngX(1, 1), True
    Set winWindow = ActiveWindow

    With rngX
        If blnRow Then
            .Resize(.Rows.Count, 1).Select
        Else
            .Resize(1, .Columns.Count).Select
        End If
        ' 행 방향 셀의 수가 많은지 열 방향 셀의 수가 많은지를 파악한 다음 Resize 메서드를 사용하여
        ' 해당 방향을 선택합니다.

    End With

    With winWindow
        .Zoom = True
        ' Window 오브젝트의 Zoom 속성을 True로 지정하면 현재 선택 영역을 창 크기에 맞도록
        ' 자동으로 맞추어 줍니다.

        .VisibleRange(1, 1).Select
    End With
    Application.ScreenUpdating = True
    Unload frmZoom
    MsgBox "선택 영역을 표시하기 위한 최적 배율은 " & ActiveWindow.Zoom & "% 입니다"
End Sub

영역의 행 수와 열 수를 비교하여 더 많은 쪽 방향으로 Resize 메서드를 사용해 선택하고, Window 오브젝트의 Zoom 속성을 True로 지정하면 현재 선택 영역을 창 크기에 맞게 자동으로 조절합니다. 그런 다음 보이는 범위의 첫 셀을 선택하여 마무리합니다.

Step 7: 취소 버튼 코드

(6) 유저폼 상태에서 '취소' 버튼을 더블 클릭한 다음 필요한 유저폼을 닫기 위한 프로시저를 작성합니다.

Private Sub cmdCancel_Click()
    Unload Me
End Sub

많이 응용해 하셔서 재미있는 것을 많이 만들어 보시기 바랍니다.

오늘은 여기까지…

정리 — 배율 자동 조절 핵심

자주 묻는 질문 (FAQ)

마치며

Window.Zoom = True 한 줄이면 사용자가 지정한 영역에 맞는 최적 배율이 자동으로 계산됩니다.