엑셀 캡션 없애기

Step 1: 전체 화면 보기의 한계

도구 모음이나 수식 표시줄, 상태 표시줄, 시트 탭 등을 화면에서 사라지도록 하여 워크시트 작업 공간을 최대화 하려면 '보기-전체 화면' 메뉴를 선택하면 됩니다.

그러나 전체 화면 보기를 해도 상단의 메뉴는 그대로 남아 있게 됩니다. '보기-전체 화면' 메뉴를 눌러 직접 확인해 보세요. 확인해 보셨으면 다시 '보기-전체 화면'을 누르면 원래 상태로 되돌아 옵니다.

그러나 위 메뉴가 그대로 남는 것이 아쉽다면 API 함수를 이용해 엑셀 창 자체의 캡션까지 제거할 수 있습니다. 코드를 실행하면 엑셀의 캡션은 물론 한 줄 남아 있던 메뉴도 제거됩니다. 원래 상태로 되돌리려면 같은 코드를 한 번 더 실행하면 됩니다.

Step 2: 선언부

지난 시간의 코드와 거의 비슷합니다. 먼저 사용자 정의 변수와 API 함수, 상수를 선언합니다.

Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type

#If VBA7 Then
    Declare PtrSafe Function GetWindowRect Lib "user32" _
        (ByVal hWnd As LongPtr, lpRect As RECT) As Long
    Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
    Declare PtrSafe Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
        (ByVal hWnd As LongPtr, ByVal nIndex As Long) As Long
    Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
        (ByVal hWnd As LongPtr, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    Declare PtrSafe Function GetSystemMetrics Lib "user32" _
        (ByVal nIndex As Long) As Long
    Declare PtrSafe Function MoveWindow Lib "user32" _
        (ByVal hWnd As LongPtr, ByVal x As Long, ByVal y As Long, _
        ByVal nWidth As Long, ByVal hHeight As Long, ByVal bRepaint As Long) As Long
    Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hWnd As LongPtr, _
        ByVal hWndInsertAfter As LongPtr, ByVal x As Long, ByVal y As Long, _
        ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
#Else
    Declare Function GetWindowRect Lib "user32" _
        (ByVal hWnd As Long, lpRect As RECT) As Long
    Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Long) As Long
    Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    Declare Function GetSystemMetrics Lib "user32" _
        (ByVal nIndex As Long) As Long
    Declare Function MoveWindow Lib "user32" _
        (ByVal hWnd As Long, ByVal x As Long, ByVal y As Long, _
        ByVal nWidth As Long, ByVal hHeight As Long, ByVal bRepaint As Long) As Long
    Declare Function SetWindowPos Lib "user32" (ByVal hWnd As Long, _
        ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, _
        ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
#End If

Public Const GWL_STYLE = (-16)
Public Const WS_CAPTION = &HC00000
Public Const SM_CYCAPTION = 4
Const HWND_TOPMOST = -1
Const HWND_NOTOPMOST = -2

Step 3: HideAndShowExcelCaption 프로시저

Sub HideAndShowExcelCaption()
    Dim lngOld As Long
    Dim lngNew As Long
    Dim rct As RECT
    #If VBA7 Then
        Dim lngHwnd As LongPtr
    #Else
        Dim lngHwnd As Long
    #End If
    Dim lngX As Long
    Dim lngY As Long
    Dim lngSt As Long
    Dim lngFlags As Long
    Static blnOK As Boolean
    Application.DisplayFullScreen = False
    lngHwnd = FindWindow(vbNullString, Application.Caption)
    lngOld = GetWindowLong(lngHwnd, GWL_STYLE)
    blnOK = Not blnOK

    If blnOK Then
    ' blnOK 변수는 캡션을 보여 주었다가 사라지게 하였다가 번갈아가며 설정하기 위한
    ' 역할을 수행합니다.

    ' 이하의 코드는 지난 시간에 알려드린 것과 동일합니다.

        lngNew = lngOld And Not WS_CAPTION
    Else
        lngNew = lngOld Or WS_CAPTION
    End If

    lngOld = SetWindowLong(lngHwnd, GWL_STYLE, lngNew)
    GetWindowRect lngHwnd, rct
    lngX = rct.Right - rct.Left

    If blnOK Then
        lngY = rct.Bottom - rct.Top - GetSystemMetrics(SM_CYCAPTION)
    Else
        lngY = rct.Bottom - rct.Top + GetSystemMetrics(SM_CYCAPTION)
    End If

    MoveWindow lngHwnd, rct.Left, rct.Top, lngX, lngY, True
    If blnOK Then
        lngSt = SetWindowPos(lngHwnd, HWND_NOTOPMOST, 0, 0, rct.Right, rct.Bottom, lngFlags)
        Application.DisplayFullScreen = True
        ' 화면 크기를 '전체 화면' 모드로 설정하고…

        MsgBox "엑셀 캡션 및 메뉴까지 제거하여 작업 공간을 최대로 하였습니다." & vbCr _
            & "Click Me!!! 버튼을 다시 누르시면 원래 상태로 되돌아갑니다", , "VB0156//www.iExceller.com"

    End If
End Sub

blnOK 변수가 캡션을 없앴다가 다시 보여 주는 동작을 번갈아 하도록 합니다. 캡션을 제거한 경우에는 SetWindowPos로 창 위치를 정리하고 Application.DisplayFullScreen = True로 전체 화면 모드를 설정하여 메뉴까지 없앱니다.

다음 시간에 또…

정리 — 엑셀 캡션 제거 핵심

자주 묻는 질문 (FAQ)

마치며

API 함수를 함께 사용하면 전체 화면 보기로도 남던 메뉴까지 없애 작업 공간을 최대한 넓힐 수 있습니다.