유저폼 캡션 없애기

Step 1: 캡션 없는 유저폼

엑셀이나 유저폼을 아주 넓~게, 즉 캡션을 없애고 사용하는 방법에 대해 질문을 하시는 분이 아주 가끔씩 계십니다.

워크시트 상의 경우(즉 엑셀 어플리케이션 상)라면 '보기-전체 화면' 메뉴를 선택하면 됩니다만 그렇더라도 남게 되는 메뉴바 마저도 없앤다거나 유저폼 상단의 캡션을 없애고자 할 경우에는 API 함수의 도움을 받으면 가능합니다.

버튼을 누르면 유저폼의 캡션이 사라졌다가 다시 나타납니다.

만약 질문이 단순히 "유저폼의 캡션을 없애려면 어떻게 해요?"였다면 실용성이 별로 없는 고민이라 여겨 깊이 고민하지 않았을 수도 있습니다. 하지만 구체적인 상황을 들어 질문해 주시면 한 번 더 방법을 찾아보게 됩니다. 질문은 가급적 상세하게 해 주시는 것이 답변하기에도 수월합니다.

Step 2: 유저폼 만들기

(1) VB Editor에서 유저폼을 하나 삽입하고 그림과 같이 레이블과 커맨드 버튼을 그립니다. 커맨드 버튼의 이름은 각각 cmdOK, cmdClose로 지정하였습니다.

아이엑셀러

(2) 유저폼의 바탕을 더블 클릭하고 우측 상단의 콤보 상자에서 Initialize 이벤트를 선택한 다음 아래와 같은 코드를 작성합니다.

아이엑셀러

Private Sub UserForm_Initialize()
    Me.Label1.Caption = "확인 버튼을 클릭하면 캡션이 제거됩니다."
End Sub

Step 3: 확인 버튼 코드

(3) Shift + F7 키를 누르면 유저폼으로 돌아가는데 '확인' 버튼을 더블 클릭하고 코드를 작성합니다.

Private Sub cmdOK_Click()
    Dim lngOld As Long
    Dim lngNew As Long
    Dim MyRct As MYRECT
    #If VBA7 Then
        Dim lngHwnd As LongPtr
    #Else
        Dim lngHwnd As Long
    #End If
    Dim lngX As Long
    Dim lngY As Long
    Dim lngStart As Long
    Dim lngFlags As Long
    Dim strMsg As String
    Static blnOK As Boolean
    lngHwnd = FindWindow(vbNullString, Me.Caption)
    lngOld = GetWindowLong(lngHwnd, GWL_STYLE)
    blnOK = Not blnOK
    ' 변수 선언 단계에서부터 예사롭지가 않지요? ^^
    ' MYRECT라는 것은 사용자 정의 변수라는 것입니다. 예전 강좌에서 설명드린 기억이
    ' 나는데 사용자 정의 변수는 "변수 종합 선물세트" 입니다.

    ' 그럼 이 사용자 정의 변수가 어디 있는지 궁금하시지요? 조금만 더 기다리세요.
    ' 사용자 정의 변수는 일반 모듈 시트에 선언을 해 주었는데 뒤에서 설명드립니다.

    If blnOK Then
    ' blnOK 변수는 캡션을 보여 주었다가 사라지게 하였다가 번갈아가며 설정하기 위한
    ' 역할을 수행합니다.

        lngNew = lngOld And Not WS_CAPTION
    Else
        lngNew = lngOld Or WS_CAPTION
    End If

    lngOld = SetWindowLong(lngHwnd, GWL_STYLE, lngNew)
    ' 현재 유저폼의 스타일 값을 lngOld 변수에 담아둡니다.

    GetWindowRect lngHwnd, MyRct
    ' 현재 유저폼의 좌표값을 얻어 냅니다.

    lngX = MyRct.Right - MyRct.Left
    ' 유저폼의 폭을 계산하는 과정입니다. 유저폼의 폭은 변동이 없으므로 이 과정은
    ' 의미가 없습니다.

    If blnOK Then
    ' 캡션의 상태에 따라 유저폼의 크기를 조절하고 레이블에 표시할 텍스트를 달리합니다.

        lngY = MyRct.Bottom - MyRct.Top - GetSystemMetrics(SM_CYCAPTION)
        strMsg = strMsg & "캡션을 제거하였습니다." & vbCr
        strMsg = strMsg & "확인 버튼을 누르면 다시 표시합니다."
    Else
        lngY = MyRct.Bottom - MyRct.Top + GetSystemMetrics(SM_CYCAPTION)
        strMsg = strMsg & "캡션을 표시하였습니다." & vbCr
        strMsg = strMsg & "확인 버튼을 누르면 제거됩니다."
    End If
    MoveWindow lngHwnd, MyRct.Left, MyRct.Top, lngX, lngY, True
    Me.Label1.Caption = strMsg
End Sub

MYRECT는 사용자 정의 변수(변수 종합 선물세트)로, 유저폼의 좌표를 담기 위한 것입니다. 이것은 일반 모듈의 맨 앞부분에 선언하며 뒤에서 설명합니다. blnOK 변수는 캡션을 제거했다가 다시 표시하는 동작을 번갈아 하기 위한 스위치이고, WS_CAPTION 속성을 제거하거나 다시 더한 뒤 캡션 높이만큼 유저폼의 크기를 조정합니다.

Step 4: API 함수 선언하기

(4) 일반 모듈 시트를 한장 삽입하고('삽입-모듈') 다음과 같은 코드를 작성합니다. 실은 코드라기보다… API 함수를 사용하기 위한 함수 및 상수를 선언하는 것입니다.

Type MYRECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type

#If VBA7 Then
    Declare PtrSafe Function GetWindowRect Lib "user32" _
        (ByVal hWnd As LongPtr, lpRect As MYRECT) As Long
    Declare PtrSafe Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As LongPtr
    Declare PtrSafe Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
        (ByVal hWnd As LongPtr, ByVal nIndex As Long) As Long
    Declare PtrSafe Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
        (ByVal hWnd As LongPtr, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    Declare PtrSafe Function GetSystemMetrics Lib "user32" _
        (ByVal nIndex As Long) As Long
    Declare PtrSafe Function MoveWindow Lib "user32" _
        (ByVal hWnd As LongPtr, ByVal x As Long, ByVal y As Long, _
        ByVal nWidth As Long, ByVal hHeight As Long, ByVal bRepaint As Long) As Long
    Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hWnd As LongPtr, _
        ByVal hWndInsertAfter As LongPtr, ByVal x As Long, ByVal y As Long, _
        ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
#Else
    Declare Function GetWindowRect Lib "user32" _
        (ByVal hWnd As Long, lpRect As MYRECT) As Long
    Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
    Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Long) As Long
    Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
    Declare Function GetSystemMetrics Lib "user32" _
        (ByVal nIndex As Long) As Long
    Declare Function MoveWindow Lib "user32" _
        (ByVal hWnd As Long, ByVal x As Long, ByVal y As Long, _
        ByVal nWidth As Long, ByVal hHeight As Long, ByVal bRepaint As Long) As Long
    Declare Function SetWindowPos Lib "user32" (ByVal hWnd As Long, _
        ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, _
        ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
#End If

Public Const GWL_STYLE = (-16)
Public Const WS_CAPTION = &HC00000
Public Const SM_CYCAPTION = 4

각 API 함수의 역할은 다음과 같습니다. GetWindowRect는 윈도우의 좌표를 얻고, FindWindow는 윈도우 캡션으로 윈도우 핸들을 찾습니다. GetWindowLong과 SetWindowLong은 윈도우의 속성을 읽고 변경하며, GetSystemMetrics는 캡션의 높이를 측정합니다. MoveWindow는 윈도우의 위치와 크기를 지정합니다.

VBA(VB도 마찬가지!)에서 API 함수를 컨트롤 하는 것은 좀 복잡합니다. 처음 접하는 분은 '뭐 이런 것이 다 있나!' 싶기도 할 것입니다만, 엑셀이 얼마나 확장성이 있는 것인지만 알고 넘어가셔도 소기의 목적은 달성하신 것입니다.

고참님들은 엑셀의 행/열 머리글만 남고 다른 것은 모두 없어지도록 하는 방법에 대해 연구해 보세요. 오늘의 숙제입니다. ^^ 질문이 들어올 경우에 한해서만 Exceller도 고민을 해 볼 작정입니다.

다음 시간에 또…

정리 — 유저폼 캡션 제거 핵심

자주 묻는 질문 (FAQ)

마치며

API 함수를 다루는 것은 조금 복잡하지만 엑셀이 얼마나 확장성 있는지 알아 두는 것만으로도 충분히 의미가 있습니다.