현재 페이지 인쇄하기

Step 1: 현재 페이지 인쇄와 미리 보기

지난 시간에 설명드린 것처럼 엑셀은 페이지 개념이 아주 희박합니다. 따라서 페이지 단위로 특정 작업을 하는 것은 쉬운 일이 아닙니다. 하지만 강좌 시간에 소개하는 것을 보니 불가능하지는 않겠지요? ^^ 바로 그렇습니다!

셀 포인터를 1페이지가 아닌 다른 페이지로 옮긴 다음 코드를 실행해 보세요. 워드나 아래아 한글에서처럼 현재 페이지만 인쇄하거나 미리 볼 수 있습니다.

Step 2: PrintActivePage 프로시저

셀 포인터가 있는 셀이 몇 번째 페이지에 속하는지 HPageBreaks와 VPageBreaks로 계산하고, 그 페이지 번호를 PrintOut 메서드의 From과 To에 똑같이 지정하는 방식입니다.

Sub PrintActivePage()
    Dim intTotalPage As Integer
    Dim lngPageNum As Long
    Dim lngHPageCount As Long
    Dim lngVPageCount As Long
    Dim hpbBreak As HPageBreak
    Dim vpbBreak As VPageBreak
    Dim blnOK As Boolean
    Dim rngCurrent As Range

    If TypeName(Selection) <> "Range" Or Selection.Areas.Count > 1 Then
        MsgBox "영역이 잘못 선택되었습니다. 다시 확인하세요!", , "영역 선택 오류//www.iExceller.com"
        Exit Sub
        ' Range 오브젝트가 아닌 다른 것을 선택하였거나 하나 이상의 영역이 선택된
        ' 경우에는 프로시저를 종료합니다.

    End If
    blnOK = IIf(MsgBox("프린터로 출력할까요?", vbYesNo, "출력 방법 선택//www.iExceller.com") = vbYes, False, True)
    ' 프린터로 출력할 것인지 미리 보기만 할 것인지를 묻습니다.

    Set rngCurrent = Selection.Cells(1)
    ' 만약 여러 셀이 선택된 경우에는 첫번째 셀이 있는 페이지를 우선으로 합니다.

    On Error GoTo ET

    With ActiveSheet
        .DisplayPageBreaks = True
        ' 페이지 구분선이 모두 나타나도록 하고…

        If .PageSetup.Order = xlDownThenOver Then
        ' 페이지 순서가 행 우선이냐 열 우선이냐에 따라 출력되는 순서가 틀려집니다.
        ' 따라서 이것을 구분해야 합니다. 먼저 xlDownThenOver 즉, 행 우선인 경우에
        ' 대한 처리를 합니다.

            For Each hpbBreak In .HPageBreaks
            ' 셀 포인터가 있는 셀의 행과 수평 페이지 구분 개체를 차례대로 비교합니다.
            ' hpbBreak의 Row가 rngCurrent.Row 보다 크다는 것은 활성화 된 셀이 현재의
            ' HPageBreak 개체보다 뒤쪽에 있다는 얘기가 되겠지요?

                If hpbBreak.Location.Row > rngCurrent.Row Then
                    Exit For
                Else
                    lngPageNum = lngPageNum + 1
                End If
            Next hpbBreak

            lngPageNum = lngPageNum + 1
            lngVPageCount = .VPageBreaks.Count
            lngHPageCount = .HPageBreaks.Count

            If lngVPageCount >= 1 Then
            ' 열 방향으로 페이지가 한 열 이상이라면…

                For Each vpbBreak In .VPageBreaks
                    If vpbBreak.Location.Column <= rngCurrent.Column Then lngPageNum = lngPageNum + lngHPageCount + 1
                Next vpbBreak
            End If
        Else
        ' 이번에는 페이지 순서가 열 우선으로 설정이 되어 있는 경우에 대한 처리를
        ' 수행합니다. 기본적인 원리는 위의 것과 똑같습니다.

            For Each vpbBreak In .VPageBreaks
                If vpbBreak.Location.Column > rngCurrent.Column Then
                    Exit For
                Else
                    lngPageNum = lngPageNum + 1
                End If
            Next vpbBreak

            lngPageNum = lngPageNum + 1
            lngVPageCount = .HPageBreaks.Count
            lngHPageCount = .VPageBreaks.Count

            If lngVPageCount >= 1 Then
                For Each hpbBreak In .HPageBreaks
                    If hpbBreak.Location.Row <= rngCurrent.Row Then lngPageNum = lngPageNum + lngHPageCount + 1
                Next hpbBreak
            End If
        End If
        .PrintOut from:=lngPageNum, To:=lngPageNum, preview:=blnOK
        ' 실제로 미리보기(또는 인쇄)를 하는 부분입니다. 개체 인쇄를 담당하는 PrintOut
        ' 메서드의 from과 to를 같은 페이지로 지정함으로써 현재 페이지만 출력되도록
        ' 하는 것이 요점입니다.

    End With
    Exit Sub
ET:
    MsgBox Err.Number & "번 에러가 발생하였습니다!", , "에러 발생//www.iExceller.com"
    Err.Clear
End Sub

페이지 번호는 인쇄 순서 설정(행 우선 또는 열 우선)에 따라 계산 방법이 달라지므로 두 경우를 나누어 처리하였습니다. 핵심은 PrintOut 메서드의 From과 To를 같은 페이지로 지정하여 현재 페이지만 출력하도록 한 부분이며, Preview 인수를 이용하면 프린터로 내보내지 않고 미리 보기만 할 수도 있습니다.

다음 시간에 또…

정리 — 현재 페이지 인쇄 핵심

자주 묻는 질문 (FAQ)

마치며

페이지 개념이 희박한 엑셀이지만 쪽 나눔 오브젝트를 이용하면 워드처럼 현재 페이지만 인쇄하거나 미리 볼 수 있습니다.