측정할 수 있으면 개선된다

Step 1: 차트를 조금 더 똑똑하게

우리가 흔히 사용하는 차트를 조금 더 똑똑하게 만들어 볼까요? 아래 버튼을 누르신 다음 시트 이곳 저곳을 클릭해 보세요.

유효한 영역을 클릭했을 경우에는 선택된 셀(ActiveCell)의 항목별 고객만족도 조사 결과가 표시되고…

[그림 1] 유효한 영역을 선택했을 경우

아이엑셀러

그렇지 않은 경우, 즉 차트를 생성할 수 없는 위치를 클릭하면 에러 메시지가 나타나면서 차트가 표시되지 않을 것입니다.

[그림 2] 유효하지 않은 영역을 선택하였을 경우

아이엑셀러

요즘 회사나 세미나장 같은 곳에서 프리젠테이션을 할 때 파워포인트를 많이들 사용합니다. 이런 경우에 슬라이드를 엑셀과 연결해서 사용하면 보다 역동적이고 Impact한 프리젠테이션이 될 것입니다.

Step 2: 만드는 순서

(1) 소스 데이터를 이용하여 차트를 만듭니다. 이 때 차트의 옵션값을 적당히 지정하여 원하는 형태로 미리 만들어 둡니다. 물론 VBA로 차트 오브젝트의 각종 속성값을 변경할 수도 있지만 쓸데없이 코드를 복잡하게 할 필요는 없겠지요.

(2) VB Editor 상태에서 프로젝트 탐색창을 더블 클릭하고 코드 창에서 SelectionChange 이벤트를 선택한 다음 아래와 같은 코드를 작성합니다.

아이엑셀러

아이엑셀러

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim chtChartObject As ChartObject
    Dim chtChart As Chart
    Dim i As Integer
    Dim chtChartTitle As Range
    Dim rngThat As Range
    Dim rngSource As Range
    Dim rngTarget As Range
    Dim txtMsg As TextBox
    Dim strArea As String
    Set txtMsg = ActiveSheet.TextBoxes("Message")
    '''위에서 유효하지 않은 영역을 선택하면 에러 메시지가 나타났었지요? 이것은 텍스트 박스를
    '''워크시트 상에 미리 하나 그려 놓은 다음 텍스트 박스의 선과 배경색을 '없음'으로 지정하여
    '''자동으로 나타나는 것처럼 보이도록 해 준 것입니다.

    '''텍스트 박스에 이름을 정의해 둔 것 이외에도 미리 이름을 정의해 둔 것이 두개 더 있습니다.
    '''아래에서 보면 Source라는 것과 Title이라는 영역이 바로 그것입니다. 어떤 영역인지는
    '''이름 상자나 '삽입-이름' 메뉴를 사용하여 직접 확인해 보시기 바랍니다.

    Set rngTarget = [Source]
    Set chtChartObject = ActiveSheet.ChartObjects(1)
    Set chtChart = chtChartObject.Chart
    i = ActiveCell.Row

    If Application.Intersect(rngTarget, ActiveCell) Is Nothing Or ActiveCell.Row = [Title].Row Then
    '''Intersect 메서드를 사용하여 현재 선택한 셀이 유효한 영역인지 아닌지를 검사합니다.
    '''Intersect 메서드의 결과값이 Nothing이라는 말은 지정한 영역 내에 없다는 말이 되므로
    '''차트 오브젝트의 Visible 프로퍼티 값을 False로 지정합니다. 그러면 차트가 보이지 않게 됩니다.
    '''그리고는 미리 작성해 둔 텍스트 박스가 나타나도록 하는 것이지요.

        chtChartObject.Visible = False
        txtMsg.Visible = True
    Else
    '''그렇지 않으면… 즉 현재 선택한 셀이 유효한 영역 내에 있다면 아래의 코드를 실행합니다.
    '''위와는 반대로 이번에는 텍스트 박스를 숨기고 차트 오브젝트를 보이도록 합니다.

        txtMsg.Visible = False
        Set chtChartTitle = [Title]
        Set rngThat = Range(Cells(i, 1), Cells(i, 1).End(xlToRight))
        strArea = rngThat.Cells(1) & "지역 고객만족도 조사 결과"
        Set rngSource = Union(chtChartTitle, rngThat)
        '''서로 떨어져 있는 영역을 가지고 차트를 작성하기 위해 Union 메서드를 사용한 것을 눈여겨
        '''보시기 바랍니다.

        chtChart.SetSourceData Source:=rngSource, PlotBy:=xlRows
        chtChartObject.Visible = True

        With ChartObjects(1).Chart
        '''차트 오브젝트의 타이틀을 현재 선택한 셀의 지역명과 일치시켜주기 위한 작업입니다.

            .HasTitle = True
            .ChartTitle.Text = strArea
        End With
    End If
End Sub

위에서 유효하지 않은 영역을 선택하면 에러 메시지가 나타났었지요? 이것은 텍스트 박스를 워크시트 상에 미리 하나 그려 놓은 다음 텍스트 박스의 선과 배경색을 '없음'으로 지정하여 자동으로 나타나는 것처럼 보이도록 해 준 것입니다. 텍스트 박스에 이름(Message)을 정의해 둔 것 이외에도 미리 이름을 정의해 둔 것이 두 개 더 있습니다. 아래에서 보면 Source라는 것과 Title이라는 영역이 바로 그것입니다. 어떤 영역인지는 이름 상자나 '삽입-이름' 메뉴를 사용하여 직접 확인해 보시기 바랍니다.

Intersect 메서드를 사용하여 현재 선택한 셀이 유효한 영역인지 아닌지를 검사합니다. Intersect 메서드의 결과값이 Nothing이라는 말은 지정한 영역 내에 없다는 말이 되므로 차트 오브젝트의 Visible 프로퍼티 값을 False로 지정합니다. 그러면 차트가 보이지 않게 됩니다. 그리고는 미리 작성해 둔 텍스트 박스가 나타나도록 하는 것이지요. 그렇지 않으면, 즉 현재 선택한 셀이 유효한 영역 내에 있다면 이번에는 텍스트 박스를 숨기고 차트 오브젝트를 보이도록 합니다. 서로 떨어져 있는 영역을 가지고 차트를 작성하기 위해 Union 메서드를 사용한 것을 눈여겨 보시기 바랍니다. 마지막으로 차트 오브젝트의 타이틀을 현재 선택한 셀의 지역명과 일치시켜 줍니다.

다음 시간에 또…

정리 — ActiveCell 연동 차트 핵심

자주 묻는 질문 (FAQ)

마치며

측정할 수 있는 것은 데이터로 보여 주고 차트를 조금 더 똑똑하게 만들면 프레젠테이션의 임팩트도 커집니다.