OnKey 메서드에 대하여 2

Step 1: 엔터키를 내 마음대로

이번 시간에는 지난 강좌에서 소개해 드린 OnKey 메서드를 응용해 보도록 하지요. 아래 버튼을 누르시면 Stage 시트로 이동합니다. 이 때 엔터키를 계속 눌러 보세요. 이 때 엔터키는 숫자판에 있는 것 말고 큰 엔터키를 누르셔야 제대로 작동하는 것을 보실 수 있습니다.

지난 주말에 엑사모(엑셀을 사랑하는 사람들의 모임) 번팅 자리에 참석해서 이야기를 나누다가 갑자기 생각이 나서 이런 것을 한번 만들어 보았습니다.

Stage 시트에는 일차별 총생산수량, 불량수량, 불량율이 표로 정리되어 있습니다. 여기에서 사용하는 이름은 Total(총생산수량 B2:B32), Bad(불량수량 C2:C31), Percent(불량율 D2:D31), Start(B2)입니다.

Step 2: Worksheet_Activate와 SetUpOnKey

먼저 Stage 시트의 Activate 이벤트, 즉 워크시트가 활성화 되었을 때 실행될 코드를 작성합니다.

Private Sub Worksheet_Activate()
    [Start].Select
    SetUpOnKey
    '''SetUpOnKey라는 외부 프로시저를 호출합니다. 이 프로시저는 일반 모듈에 들어 있습니다.

    MsgBox "엔터키를 눌러가며 셀 포인터가 어떻게 이동하는지 유심히 살펴보세요!"
End Sub

SetUpOnKey라는 외부 프로시저를 호출합니다. 이 프로시저는 일반 모듈에 들어 있습니다.

Sub SetUpOnKey()
    Application.OnKey "~", "GoWhatYouWant"
    '''지난 시간에 설명드린 OnKey 메서드를 사용하였지요?
    '''엔터키를 누를 때마다 GoWhatYouWant 프로시저를 실행하도록 합니다.

End Sub

지난 시간에 설명드린 OnKey 메서드를 사용하였지요? 엔터키를 누를 때마다 GoWhatYouWant 프로시저를 실행하도록 합니다.

Step 3: GoWhatYouWant 프로시저

GoWhatYouWant 프로시저의 내용은 아래와 같습니다. 이 프로시저가 오늘 강좌의 핵심 부분입니다.

Sub GoWhatYouWant()
    Dim rngTarget As Range

    Set rngTarget = Intersect([Total], Selection)
    '''낯선 것이 하나 등장하였군요. Intersect 메서드는 "둘 이상의 범위에서 사각형 모양의 겹치는
    '''부분을 구해 줍니다. Stage 시트에서 Total 이라는 Range 오브젝트는 "총생산수량" 부분입니다.

    If Not rngTarget Is Nothing Then
        '''Not rngTarget이 Nothing 이라는 것은 서로 교차되는 영역이 없다는 것, 즉 선택된 셀이
        '''Total 이라는 영역 내에 있지 않다는 의미가 됩니다.

        If Selection.Row = 32 Then
            Selection.Offset(-30, 0).Select
        Else
            Selection.Offset(0, 1).Select
            '''선택된 영역이 32행이면 1일차 행으로 이동시키고 그렇지 않으면 오른쪽으로 한 칸
            '''이동시킨 다음 프로시저를 종료합니다.

        End If
        Exit Sub
    End If

    Set rngTarget = Intersect([Bad], Selection)
    '''이번에는 선택된 영역이 Bad 즉 "불량수량" 영역 내에 있는 지 확인하여 셀 포인터의 방향을
    '''결정합니다. Bad 영역 내에 있을 경우 오른쪽 으로 한 간 옮긴 다음 프로시저를 빠져 나갑니다.

    If Not rngTarget Is Nothing Then
        Selection.Offset(0, 1).Select
        Exit Sub
    End If

    Set rngTarget = Intersect([Percent], Selection)
    '''마찬가지로 Intersect 메서드를 사용하여 현재 선택된 영역이 Percent 즉 "불량율" 영역 내에
    '''있을 경우, 아래로 한 간, 왼쪽으로 두 간 이동시킵니다.

    If Not rngTarget Is Nothing Then
        Selection.Offset(1, -2).Select
        Exit Sub
    End If
End Sub

낯선 것이 하나 등장하였군요. Intersect 메서드는 둘 이상의 범위에서 사각형 모양의 겹치는 부분을 구해 줍니다. Stage 시트에서 Total 이라는 Range 오브젝트는 "총생산수량" 부분이며, Bad는 "불량수량", Percent는 "불량율" 영역입니다. 셀 포인터가 어느 영역 안에 있는지에 따라 이동 방향을 결정하는 것이 이 프로시저의 핵심입니다.

Step 4: 다른 시트에서의 에러 방지

그냥 이대로만 두면 다른 시트나 파일에서 엔터키를 눌렀을 경우 에러 메시지가 나타납니다. 따라서 워크시트나 워크북 오브젝트의 이벤트 핸들러 프로시저를 이용하여 수정해 줍니다. 이 역할을 수행하기 위해

• Workbook 오브젝트의 WindowDeactivate 이벤트
• Worksheet 오브젝트의 Deactivate 이벤트

등을 이용하여 또 어떤 작업을 해 주었습니다. 어떤 코드가 사용되었는지 직접 확인해 보시기 바랍니다.

' Stage 시트 모듈
Private Sub Worksheet_Deactivate()
    Application.OnKey "~"
End Sub

' ThisWorkbook 모듈
Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
    Application.OnKey "~"
End Sub

오늘은 여기까지…

정리 — OnKey 응용 핵심

자주 묻는 질문 (FAQ)

마치며

프로그래밍 체질이 따로 있는 것이 아니라 자기 업무를 잘 알고 매사를 따져 보는 습관이 코드를 더 잘 짜게 만듭니다.