데이터 위치 바꾸기

Step 1: 두 영역의 데이터를 서로 바꿔 보기

컨트롤 키를 사용하여 아래의 '영역 1'과 '영역 2'를 선택한 다음 버튼을 눌러 보세요.

버튼을 누를 때마다 두 영역의 값이 서로 위치를 바뀝니다. 이렇게 되도록 해 달라는 질문이시지요?

Step 2: 코드를 보시기 전에…

코드를 보시기 전에… 잠시 머리 속으로 생각을 먼저 정리해 보시기 바랍니다. 어떤 Flow를 거쳐 이런 작업을 할 수 있겠는지 말입니다. 자, 1분만 생각을 해 보신 다음 아래 코드를 보세요. 여러분이 생각하신 방법과 비슷합니까? 그리고 코드가 생각보다 짧습니까 깁니까?

Step 3: ExchangeDataLocation 프로시저

Sub ExchangeDataLocation()
    Dim varThis() As Variant
    Dim varThat() As Variant
    Dim i As Integer
    Dim intNum As Integer
    Dim strErrMsg As String
    '''모두 5개의 변수를 미리 선언해 주었습니다. 여기서 동적 배열 변수를 사용한 것은
    '''왜일까요? 그것은 영역의 크기가 얼마나 될 지, 즉 몇 개의 셀을 선택할 지가 유동적이기
    '''때문에 그런 것입니다.

    Application.ScreenUpdating = False
    strErrMsg = "범위 선택 오류//By Exceller"
    On Error GoTo ET

    If TypeName(Selection) <> "Range" Then
        MsgBox "바꾸려는 범위를 먼저 선택하세요!", vbExclamation, strErrMsg
        Exit Sub
    End If
    '''만약 Range 오브젝트가 아닌 다른 것이 선택되었을 때에는 에러 표시를 하고 프로시저를
    '''종료합니다.

    With Selection
        If .Areas.Count <> 2 Then
            MsgBox "반드시 2개의 영역을 선택하셔야 합니다!", vbExclamation, strErrMsg
            Exit Sub
        End If
        If .Areas(1).Cells.Count <> .Areas(2).Cells.Count Then
            MsgBox "바꾸려는 영역의 크기가 같아야 합니다", vbExclamation, strErrMsg
            Exit Sub
        End If
        '''위의 두 개의 조건문도 사용자가 영역을 잘못 지정하였을 경우에 대비한 Error Trapping
        '''구문입니다. 2개의 영역을 선택하지 않았을 경우나 두 영역의 차원의 크기, 즉 셀 수가 서로
        '''틀릴 경우, 에러 표시를 하고 프로시저를 종료합니다.

        '''나머지 아래 부분은 간단합니다. 각 영역에 속한 셀 값을 동적 배열 변수에 차곡차곡 담은
        '''다음 서로 바꾸어 주는 것입니다.

        intNum = Selection.Areas(1).Cells.Count
        ReDim varThis(intNum)
        ReDim varThat(intNum)
        For i = 1 To intNum
            varThis(i) = .Areas(1).Cells(i)
            varThat(i) = .Areas(2).Cells(i)
        Next i
    End With
        For i = 1 To intNum
            Selection.Areas(1).Cells(i) = varThat(i)
            Selection.Areas(2).Cells(i) = varThis(i)
        Next i
ET:
End Sub

모두 5개의 변수를 미리 선언해 주었습니다. 여기서 동적 배열 변수를 사용한 것은 영역의 크기가 얼마나 될 지, 즉 몇 개의 셀을 선택할 지가 유동적이기 때문입니다. 두 개의 조건문은 사용자가 영역을 잘못 지정하였을 경우에 대비한 Error Trapping 구문으로, 2개의 영역을 선택하지 않았을 경우나 두 영역의 셀 수가 서로 틀릴 경우 에러 표시를 하고 프로시저를 종료합니다. 나머지 부분은 간단합니다. 각 영역에 속한 셀 값을 동적 배열 변수에 차곡차곡 담은 다음 서로 바꾸어 주는 것입니다.

다음 시간에 또…

정리 — 데이터 위치 바꾸기 핵심

자주 묻는 질문 (FAQ)

마치며

코드를 보기 전에 작업 순서를 먼저 그려 보고 비교해 보면 VBA 실력이 빠르게 늘어납니다.