자동고침 기능 응용 예제

Step 1: 자동 고침 목록 살펴보기

그러면 어떤 자동 고침 목록들이 현재 등록되어 있나 살펴보도록 할까요?

엄청나게 많은 목록들이 나타나지요? 어떤 목록들이 들어있나 알아보기 위해 아래와 같은 코드를 사용하였습니다.

Sub ViewAutoCorrectObject()
    Dim intX As Integer
    Dim varList As Variant
    On Error Resume Next
    Application.DisplayAlerts = False

    Worksheets("등록된 자동고침 목록").Delete
    Worksheets.Add.Name = "등록된 자동고침 목록"
    On Error GoTo 0
    '''동일한 시트가 있나없나 확인을 하는 또다른 방법입니다. 대개의 경우, For Each ~ Next
    '''순환문을 사용하여 일일이 검색을 하지만 위와 같이 On Error 문을 사용할 수도 있습니다.

    [A1:B1] = Array("입력하는 문장", "자동으로 고쳐지는 문장")
    varList = Application.AutoCorrect.ReplacementList
    For intX = 1 To UBound(varList)
        With [A1]
            .Offset(intX, 0) = varList(intX, 1)
            .Offset(intX, 1) = varList(intX, 2)
        End With
    Next intX
    Cells.Columns.AutoFit
    Cells.Font.Name = "바탕체"
    [A1].CurrentRegion.AutoFormat Format:=xlRangeAutoFormatList2, Number:=True, Font:= _
        True, Alignment:=True, Border:=True, Pattern:=True, Width:=True
    MsgBox "모두 " & UBound(varList) & "개의 자동 고침 목록이 등록되어 있습니다!" _
        , , "목록 작성 완료//By Exceller"
    Application.DisplayAlerts = True
End Sub

목록을 넣을 시트가 이미 있는지 확인하는 부분에서는 On Error 문을 사용하였습니다. 동일한 시트가 있나 없나 확인을 하는 또다른 방법입니다. 대개의 경우, For Each ~ Next 순환문을 사용하여 일일이 검색을 하지만 위와 같이 On Error 문을 사용할 수도 있습니다.

Step 2: 나만의 목록 추가하기

만약 팀원들간에 공통으로 사용하는 목록을 별도의 시트에 만들어 두고 이것을 사용할 수도 있겠지요? 예를 들어, 옆에 있는 '추가List'라는 시트에 자기 팀원들이 사용하는 리스트들을 등록해 두고 함께 사용할 수도 있습니다. 마치 야구에서 감독이 선수들에게 자기들만 아는 싸인을 사용하여 지시를 내리듯이 미리 리스트를 정의해 두고 사용할 수 있게 되는 것입니다.

Sub AddDataToAutoCorrect()
    Dim shtSheet As Worksheet
    Dim rngCell As Range
    Dim intNum As Integer
    Dim Msg As String
    Set shtSheet = Worksheets("추가List")
    intNum = shtSheet.Columns(1).SpecialCells(xlTextValues).Count

    For Each rngCell In shtSheet.UsedRange.Columns(1).Cells
        Application.AutoCorrect.AddReplacement rngCell, rngCell.Offset(0, 1)
        '''추가List 시트의 첫번째 열에 있는 데이터들을 AddReplacement 메서드를 사용하여
        '''추가를 해 줍니다.

    Next rngCell
    Msg = Msg & shtSheet.Name & "시트에 있는 " & vbCr
    Msg = Msg & intNum & "개의 목록이 추가되었습니다"
    MsgBox Msg, , "목록 추가 완료//By Exceller"
End Sub

추가List 시트의 첫번째 열에 있는 데이터들을 AddReplacement 메서드를 사용하여 추가를 해 줍니다.

Step 3: 추가한 목록 삭제하기

마지막으로… 이런 식으로 추가한 목록들을 삭제하는 방법에 대해서 살펴보도록 합니다.

Sub DeleteDataFromAutoCorrect()
    Dim varList As Variant
    Dim intNum As Integer
    varList = Application.AutoCorrect.ReplacementList

    For intNum = 1 To UBound(varList)
        If Left(varList(intNum, 1), 1) = "L" Then
            Application.AutoCorrect.DeleteReplacement varList(intNum, 1)
        End If
    Next intNum
End Sub

추가 목록을 삭제하는 코드는 전혀 어려운 부분이 없을 것입니다. 혹시 L로 시작되는 추가 목록을 이미 작성해 두신 분이 있을 경우를 대비하여 목록 삭제 코드는 버튼에 연결해 두지 않았습니다. 코드를 응용하여 사용하시기 바랍니다.

자동 고침 기능에 대해 생각나는 것은 이 정도로군요. 많이 응용해 보시고 다른 좋은 아이디어가 생각나시는 분은 알려주세요.

오늘은 여기까지… 즐거운 주말 되시기를…

정리 — 자동 고침 관리 핵심

자주 묻는 질문 (FAQ)

마치며

팀원들이 함께 사용하는 자동 고침 목록을 시트로 관리하면 마치 야구에서 감독이 선수들에게 사인을 주듯 약속된 입력을 빠르게 공유할 수 있습니다.