모든 폰트 보기

내 PC에 설치된 글꼴 보기

이번 시간에는 자신의 PC에 어떤 글꼴이 설치되어 있는 지 알아보도록 할까요? 버튼을 눌러 보세요.

워크시트가 한장 삽입되면서 글꼴 목록 및 샘플이 표시되지요?

ShowInstalledFonts 프로시저

Sub ShowInstalledFonts()
    Dim ctlFontList As CommandBarControl
    Dim cmdBar As CommandBar
    Dim strFontSample As String, strFontName As String
    Dim i As Integer
    On Error Resume Next
    Set ctlFontList = Application.CommandBars("Formatting").FindControl(ID:=1728)
    On Error GoTo 0
    strFontSample = "abcdefghijklmnopqrstuvwxyz1234567890"
    '''변수를 미리 선언해 주고 변수의 값을 할당(assign) 합니다.
    '''모든 CommandBar는 고유한 ID 값(Property)를 가지고 있습니다.
    '''따라서 FindControl 메서드를 사용하기 위해서는 각 컨트롤의 고유한 ID 값을
    '''알고 있어야 하는 것이지요. 그러면 이 값을 어떻게 아느냐…
    '''직접 실행창에다가 Msgbox CommandBars(1).Controls(1).ID 라고 입력하고
    '''엔터키를 탁 쳐 보세요.
    '''30002라는 값이 뜨지요? 이것은 커맨드 바의 첫번째 메뉴(컨트롤)의 ID Setting 값이
    '''30002라는 의미입니다. 마찬가지로 다른 메뉴에 대한 ID Setting값도 찾아보세요.
    '''아울러 FindControl 메서드에 대한 사항도 도움말을 참고로 정리해 두시기 바랍니다.

    Worksheets.Add after:=Worksheets("Preface")
    With [A1:B1]
        .Value = Array("Font Name", "Font Example")
        .Font.ColorIndex = 2
        .Font.Name = "Arial"
    End With
    [A2].Select
    ActiveWindow.FreezePanes = True
    '''워크시트를 한장 삽입하고 타이틀 부분을 지정한 다음 A2 셀을 기준으로
    '''틀 고정을 시킵니다.

    If ctlFontList Is Nothing Then
        Set cmdBar = Application.CommandBars.Add
        Set ctlFontList = cmdBar.Controls.Add(ID:=1728)
    End If

    For i = 1 To ctlFontList.ListCount - 1
    '''순환문을 돌면서 등록된 글꼴들을 찾습니다. 아래 부분에 대해서는 그다지
    '''어려운 구문이 없을 것입니다. 우리에게 가족 다음으로 아주 친근한 반복문일
    '''따름이니까요. ^^

        strFontName = ctlFontList.List(i + 1)
        Cells(i + 1, 1) = ctlFontList.List(i + 1)
        With Cells(i + 1, 2)
            .Formula = strFontSample
            .Font.Name = strFontName
        End With
        If i > 21 Then ActiveWindow.SmallScroll 1
    Next i

    On Error Resume Next
    cmdBar.Delete
    Columns.AutoFit
    [A1].CurrentRegion.AutoFormat Format:=xlRangeAutoFormatList2, Number:=False, _
        Font:=False, Alignment:=False, Border:=False, Pattern:=True, Width:=False
    '''글꼴을 표시한 다음 자동 서식을 입혀줍니다.

    [A2].Select
End Sub

마무리

새해 벽두부터 너무 머리아픈 것을 하면 신년맞이 기념으로 때려 치우실 지도 모르니까 이만 하도록 하지요. 시간이 없어서 제대로 설명하지 않고 건너뛴 부분은 도움말을 참고하시고 그래도 안되면 질문을 하도록 하세요.

다음 시간에…

정리 — 글꼴 목록 표시 핵심

자주 묻는 질문 (FAQ)

마치며

글꼴 콤보 상자의 ID 1728만 알면 설치된 모든 글꼴을 워크시트에 나열하는 코드를 간단히 만들 수 있습니다.