브랜드별 시트만들기

Step 1: 이번 시간의 예제

이번 강좌에서 다루어 볼 내용도 DB와 관련이 있는 내용입니다. 아래와 같은 데이터가 있다고 가정합니다. 이것은 어느 영업 지점의 담당별/브랜드별 판매 수량 집계표 입니다. 이런 식으로 실적 데이터를 엑셀 시트에 입력한 것 까지는 좋았는데… 이것을 브랜드별로 별도의 시트로 만들어야 할 경우가 있다면 어떻게 해야 할까요? 버튼을 눌러 보세요.

뭣이 휙휙 거리더니... 각 브랜드별 시트가 만들어 졌지요? 머 하느라고 휙휙 거렸는지 코드를 보도록 할까요?

Step 2: MakeSeparateTable 프로시저

Sub MakeSeparateTable()
    Dim rngCell As Range, rngItem As Range
    Dim i As Integer, intNum As Integer
    Dim r As Integer, c As Integer
    Dim bytCount As Byte
    Dim lngTotal As Long
    Dim shtSheet As Worksheet
    '''작업에 필요한 변수들을 지정해 줍니다. 어떤 분의 질문 중에,
    '''Exceller님은 어떻게 변수가 프로그램 중에 사용될 것을 미리 알고 항상
    '''프로시저 앞 부분에 다 써 줍니까?"라고 하신 분이 있더군요.

    '''그것은 필요한 모든 변수를 미리 다 생각해서 적어주는 것이 아닙니다.
    '''그런 것은 천재들이나 하는 짓(?)이지요.
    '''코드를 짜기 전에 어떤 순서를 따를 것인가를 생각하여 최소한의 변수들만
    '''도입부분에 선언해 줍니다. 그리고 나머지는 프로그래밍을 하면서 하나씩
    '''추가를 한 다음 코드가 완성되고 나서 순서를 고쳐주는 것입니다.
    '''Exceller는 천재가 아니랍니다. ^^

    Application.DisplayAlerts = False
    Set rngItem = Range([Start].Offset(0, 1), [Start].Offset(0, 1).End(xlToRight))
    '''위의 B63 셀에 미리 Start라는 이름을 정의해 준 다음 코딩시 사용합니다.
    '''rntItem 이라는 영역은 Start 셀의 바로 오른쪽의 C63셀로부터 시작하여 오른쪽으로
    '''더 이상 데이터가 없는 영역, 그러니까 파란 점선으로 둘러싼 부분입니다.

    intNum = Range([Start], [Start].End(xlDown)).Cells.Count - 1

    For Each rngCell In rngItem
        For Each shtSheet In Worksheets
            If shtSheet.Name = rngCell Then
                MsgBox rngCell & "시트는 이미 존재합니다." & vbCr & _
                    "삭제하고 다시 만듭니다!", , "동일 시트 발견//By Exceller"
                shtSheet.Delete
            End If
            '''순환문을 돌면서 같은 이름의 시트가 있나 확인하여 있으면 지웁니다.

        Next shtSheet

        Worksheets.Add after:=ActiveSheet
        bytCount = bytCount + 1
        ActiveSheet.Name = rngCell
        [A1:B1] = Array("담당명", rngCell)
        '''새로운 시트를 한장 삽입하고 시트명을 rngCell, 즉 해당 브랜드 이름으로
        '''바꾸어 줍니다. 그리고 A1 셀과 B1 셀에 담당명, 해당 브랜드명을 기입합니다.
        '''이 때 배열을 사용하여 두 개의 셀에 한꺼번에 데이터를 입력한 방법에
        '''주의해서 보시기 바랍니다.

        For i = 1 To intNum
            If rngCell.Offset(i, 0) > 0 Then
                r = r + 1
                With [A1]
                    .Offset(r, 0) = rngCell.Offset(i, -c - 1)
                    .Offset(r, 1) = rngCell.Offset(i, 0)
                End With
                lngTotal = lngTotal + rngCell.Offset(i, 0)
            End If
            '''이 부분이 오늘 코드의 핵심입니다. rngCell.Offset(I, 0)이라는 것은
            '''C63 셀에서 행 방향으로 1, 열 방향으로 0만큼 이동한 것이니까 바로
            '''C64 셀이 되겠지요? 이 셀의 값이 0보다 크면 그 다음 구문을 실행합니다.
            '''새로 삽입한 시트의 A2 셀부터 데이터를 차곡차곡 옮겨담는 과정입니다.

            '''언제나 그렇듯이 순환문이 나오면 흰 종이를 한장 펼쳐놓고 직접 숫자값을
            '''대입해 가며 순환문을 세 바퀴만 돌려보면 답이 나올 것입니다.

        Next i
        With [A1]
            .Offset(r + 1, 0) = rngCell & " 계"
            .Offset(r + 1, 1) = lngTotal
            .AutoFormat Format:=xlRangeAutoFormatList1
            '''시트에 값을 옮겨 적었으면 "계" 부분을 구하고 "자동 서식"을 입힙니다.

        End With
        r = 0
        c = c + 1
        lngTotal = 0
    Next rngCell
    Application.DisplayAlerts = True
    Application.Goto Sheets("Preface").[A50], True
    MsgBox bytCount & " 개의 시트가 만들어졌습니다", , "시트 생성 완료//By Exceller"
End Sub

Start 이름은 위의 B63 셀에 미리 정의해 준 다음 코딩 시 사용합니다. rngItem 이라는 영역은 Start 셀의 바로 오른쪽의 C63셀로부터 시작하여 오른쪽으로 더 이상 데이터가 없는 영역, 그러니까 파란 점선으로 둘러싼 부분입니다. 코드의 핵심은 rngCell.Offset(i, 0)이라는 것이 C63 셀에서 행 방향으로 1, 열 방향으로 0만큼 이동한 것이니까 바로 C64 셀이 되고, 이 셀의 값이 0보다 크면 새로 삽입한 시트의 A2 셀부터 데이터를 차곡차곡 옮겨담는 부분입니다. 언제나 그렇듯이 순환문이 나오면 흰 종이를 한 장 펼쳐놓고 직접 숫자값을 대입해 가며 순환문을 세 바퀴만 돌려보면 답이 나올 것입니다.

Step 3: 오늘 강좌의 주제는?

오늘 강좌의 주제가 무엇이었을까요? 디지털 신경망 시스템? ……………………… 땡! 브랜드별 시트 만들기?? …………………… 또 땡!!

컴퓨터를 통한 자동하는 실제 업무 과정을 최대한 자동화시켜 놓고 난 다음의 일이라는 것. 그러기 위해서라도 DB는 항상 구축하기 전에 두번 세번 생각해 보아야 한다는 것이었습니다.

오늘은 여기까지…

정리 — 브랜드별 시트 생성 핵심

자주 묻는 질문 (FAQ)

마치며

자동화는 실제 업무 과정을 최대한 정리해 놓은 다음의 일이며, 데이터베이스는 구축하기 전에 두 번 세 번 생각해야 합니다.