데이터 위치 바꾸기

Step 1: 이번 시간의 질문

질문 자체는 아주 간결하지만 해법은… 조금 복잡할 듯 합니다. Ctrl 키를 사용하여 아래의 두 범위를 선택하신 다음 버튼을 눌러 보세요.

Step 2: ExchangeDataLocation 프로시저

Sub ExchangeDataLocation()
    Dim varThis() As Variant, varThat() As Variant
    Dim i As Integer, intNum As Integer
    Dim strErrMsg As String
    Application.ScreenUpdating = False
    '''등장 인물에 대한 캐스팅 작업… 바로 변수와 맡을 역할을 정의해 주었습니다.
    '''작업할 때마다 화면이 갱신되지 않도록 하기 위해 ScreenUpdating 속성을 False로…

    strErrMsg = "범위 선택 오류//By Exceller"
    On Error GoTo ET

    If TypeName(Selection) <> "Range" Then
        MsgBox "바꾸려는 범위를 먼저 선택하세요!", vbExclamation, strErrMsg
        Exit Sub
    End If
    '''사용자가 Range 오브젝트, 그러니까 셀이 아닌 다른 것(예를 들면 도형같은 것)을 선택하고
    '''버튼을 눌렀을 경우, 경고 메시지를 뿌리고 프로시저를 종료합니다.

    With Selection
        If .Areas.Count <> 2 Then
            MsgBox "반드시 2개의 영역을 선택하셔야 합니다!", vbExclamation, strErrMsg
            Exit Sub
        End If
        '''두 영역의 데이터를 바꾸려면 당연히 두 개의 범위를 지정해야 겠지요? 따라서 1개 또는
        '''3개 이상의 영역을 선택하고 버튼을 누를 경우에도 에러 메시지를 보여줍니다.

        If .Areas(1).Cells.Count <> .Areas(2).Cells.Count Then
            MsgBox "바꾸려는 영역의 크기가 같아야 합니다", vbExclamation, strErrMsg
            Exit Sub
        End If
        '''이 부분도 마찬가지로 에러 메시지를 보여주는 부분입니다. 이것은 무슨 뜻일까요?
        '''두 집의 크기가 같아야 1:1로 바꾸어 줄 수 있을 것입니다. 따라서 두 집의 크기가 같은지를
        '''비교하는 구문입니다.

        intNum = Selection.Areas(1).Cells.Count
        ReDim varThis(intNum)
        ReDim varThat(intNum)
        For i = 1 To intNum
            varThis(i) = .Areas(1).Cells(i)
            varThat(i) = .Areas(2).Cells(i)
        Next i
        '''바로 이 부분이 오늘의 하일라이트입니다.
        '''그런데 별로 설명드릴 만한 사항은 없을 듯 합니다. 왜냐구요? 넘 쉬우니까…
        '''장난치지 말라구요? 알겠습니다! 하지만 정말로 설명드릴 것이 없습니다.
        '''Areas(1) 영역 내에 몇 개의 셀이 있는 지 카운팅 한 다음 varThis와 varThat라는 동적
        '''배열 변수의 크기를 결정합니다. 그런 다음에 순환문을 돌면서 각 셀의 값을 하나씩
        '''담아두는 것이지요.
    End With

    For i = 1 To intNum
        Selection.Areas(1).Cells(i).Value = varThat(i)
        Selection.Areas(2).Cells(i).Value = varThis(i)
        '''다시 한번 순환문을 돌면서 두 영역의 데이터 값의 위치를
        '''서로 바꾸어 줍니다.

    Next i
ET:
    Application.ScreenUpdating = True
End Sub

마무리

방법은 조금 다릅니다만, 토끼/거북이 자리 옮기기만 잘 생각하시면 충분히 해결가능한 문제가 아닌가 생각됩니다. 쉬운 것을 어렵게 생각하고 어려운 것을 쉽게 생각하는 습관을 기르시기 바랍니다. 예측 가능한 모든 사항을 다 감안하려면 머리털 또 다 빠집니다.

다음 시간에…

정리 — 데이터 위치 교환 핵심

자주 묻는 질문 (FAQ)

마치며

임시 저장 공간을 활용한 자리 바꾸기 원리만 알면 두 영역의 데이터 교환도 쉽게 구현할 수 있습니다.