콤보박스 활용 테크닉

Step 1: 콤보 박스에 목록 채우기 (FillComboBox)

A열에는 강동, 강서, 강남, 강북, 부산, 대구, 대전, 광주, 제주가 입력되어 있습니다. 버튼을 누르면 왼쪽의 데이터가 콤보박스에 채워집니다.

Sub FillComboBox()
    Dim rngCell As Range
    Dim cmbComboBox As DropDown
    Dim Msg As String
    Set cmbComboBox = ActiveSheet.DropDowns("MyCombo")
    MsgBox "기존의 리스트들을 지웁니다", , "리스트 제거//By Exceller"
    cmbComboBox.RemoveAllItems

    For Each rngCell In Range("A:A").SpecialCells(xlTextValues)
        cmbComboBox.AddItem rngCell
    Next rngCell
    Msg = Msg & "콤보 박스가 채워졌습니다" & vbCr
    Msg = Msg & "콤보 박스를 클릭해 보세요"
    MsgBox Msg, , "작업 완료//By Exceller"
End Sub

코드는 그다지 어려운 부분이 없을 것입니다. 그런데 이 코드는 문제가 있어 보이는군요. 예를 들어 옆의 빨간 셀에 제주라고 입력한 다음 다시 위의 Click Me!!! 버튼을 눌러 보세요. 콤보 박스에 제주라는 항목이 두번 나타나지요? 즉 중복되는 값이 있을 경우, 리스트가 여러 번 반복되어 나타나는 문제가 있습니다. 이 문제를 해결해 보도록 하지요. 아래의 'Click Again!' 버튼을 누르신 다음 콤보 박스에 추가된 항목을 확인해 보세요.

Step 2: 중복 없이 채우기 (FillComboBoxWithUniqueItems)

잘 작동하지요? 코드를 볼까요? 하는 일이 많으니까 코드도 위의 것 보다는 좀 복잡합니다.

Sub FillComboBoxWithUniqueItems()
    Dim rngCell As Range, rngSource As Range
    Dim i As Integer, j As Integer
    Dim cmbCombo As DropDown
    Dim strItem() As String, Msg As String
    Set cmbCombo = ActiveSheet.DropDowns("MyCombo2")
    Set rngSource = ActiveSheet.Columns("A:A").SpecialCells(xlTextValues)
    MsgBox "기존의 리스트들을 지웁니다", , "리스트 제거//By Exceller"
    cmbCombo.RemoveAllItems

    For Each rngCell In rngSource
        If j > 0 Then
            For i = LBound(strItem) To UBound(strItem)
                If rngCell = strItem(i) Then GoTo StopScan
                '''rngSource는 A열 전체 중에서 값이 들어있는 모든 셀을 의미합니다.
                '''여기서 j>0이라는 것은 무엇을 뜻하는 것일까요? 현재로서는 알 수 없습니다만
                '''아래로 좀더 내려가서 살펴보면 값이 1개 이상, 그러니까 같은 값이 하나 이상
                '''있는 것을 의미합니다. 따라서 동적 배열 변수 strItem()에 기존에 들어있는 값과
                '''현재 셀의 값을 비교하여 같은 경우에는 StopScan이라는 조건 분기문으로 가라는
                '''의미입니다.

                '''이것은 초등학교 반장 선거를 할 때 어떻게 합니까? 먼저 후보자를 정하지요?
                '''그런 다음 홍길동, 갑동이, 을순이 등의 후보자를 칠판에 적어두고 투표를 합니다.
                '''개표를 할 때, 한 표씩 열어가며 이름을 부를 때마다 칠판에 있는 이름 밑에다 正자를
                '''적어 나갑니다. 이 과정과 크게 다를 것이 없습니다.

            Next i
            ReDim Preserve strItem(j)
            strItem(j) = rngCell
            cmbCombo.AddItem rngCell
            j = j + 1
        Else
            ReDim Preserve strItem(j)
            strItem(j) = rngCell
            cmbCombo.AddItem rngCell
            j = j + 1
        End If
StopScan:
    Next rngCell
    Msg = Msg & "Unique Item으로 콤보 박스를 채웠습니다" & vbCr
    Msg = Msg & "콤보 박스를 클릭해 보세요"
    MsgBox Msg, , "작업 완료//By Exceller"
End Sub

Step 3: 선택한 항목으로 시트 만들기 (DoingSomething)

개념을 조금 더 확장해 보도록 하지요. 그냥 콤보 박스에서 항목을 선택하면 선택된 내용을 보여주기만 할 것이 아니라 선택된 이름과 같은 시트를 만들어 보는 것입니다.

Sub DoingSomething()
    Dim cmbCombo As DropDown
    Dim Msg As String, strList As String
    Set cmbCombo = Sheets("Preface").DropDowns(Application.Caller)
    strList = cmbCombo.List(cmbCombo.ListIndex)
    '''콤보 박스를 통해 사용자가 선택한 값을 strList라는 문자열 변수에 담습니다.

    Msg = Msg & strList & "" & "을(를) 선택하셨습니다"
    MsgBox Msg, , "Item 선택//By Exceller"
    MakeSheet strList
    '''MakeSheet 프로시저를 호출할 때 strList라는 값을 건네주어 함께 실행시킵니다.

    Application.Goto cmbCombo.TopLeftCell
End Sub

Sub MakeSheet(XXX As String)
    Dim shtSheet As Worksheet

    For Each shtSheet In ThisWorkbook.Sheets
        If shtSheet.Name = XXX Then
            MsgBox "같은 시트가 이미 만들어져 있습니다", , "동일 시트 발견//By Exceller"
            Exit Sub
        End If
    Next shtSheet
    Worksheets.Add.Name = XXX
    MsgBox XXX & " 시트를 만들었습니다!", , "시트 생성//By Exceller"
End Sub

마무리

이번 시간에는 여기까지…

정리 — 콤보 박스 활용 핵심

자주 묻는 질문 (FAQ)

마치며

콤보 박스의 목록 채우기, 중복 제거, 선택 항목 활용을 익혀 두면 사용자 인터페이스를 훨씬 편리하게 만들 수 있습니다.