FIND 메서드에 대하여

Step 1: 데이터에 접근하는 방법

이번 시간에는 데이터(셀)에 접근하는 방법에 대해 알아보도록 하겠습니다.

현실 세계에서 낯선 찾아가려면 지도나 주소가 있어야 하듯이 컴퓨터도 마찬가지 입니다. 워크시트의 모든 셀에도 셀 주소가 있듯이 컴퓨터의 메모리에도 주소가 있고 하드디스크에도 수없이 많은 주소가 있습니다. 컴퓨터는 주소를 찾아다니다가 시간을 다 보내는 물건이라고 해도 과언이 아닙니다.

데이터를 가공/분석/출력을 하려면 우선 데이터가 어디에 들어있는 지를 알아야 그 다음 작업을 해도 하겠지요? 서울에서 광주까지 가는 방법은 수도 없이 많듯이 프로그래밍을 할 때에도 마찬가지입니다. 아래의 버튼들을 클릭하면 숫자를 입력하라는 메시지가 나오는데 10~99 사이의 임의의 숫자를 입력한 다음 수행 속도를 비교해 보세요. 77을 입력해 보세요.

현재는 데이터 량이 그다지 많지 않아 큰 차이를 보이지 않습니다만, 검색할 데이터 량이 많으면 많을수록 그 격차는 더욱 벌어집니다.

Step 2: 순환문으로 찾기 (SequentialAccess)

코드를 살펴보도록 하지요. 먼저, '세월아 네월아' 버튼에 연결된 코드부터 볼까요?

Sub SequentialAccess()
    Dim rngCell As Range, rngSource As Range
    Dim i As Integer, intWhatNumber As Integer
    Dim Msg As String
    Dim lngStart As Long
    lngStart = Timer
    '''필요한 등장 인물(변수)을 선언하고 현재의 시간을 lngStart 변수에 담아둡니다.

    Set rngSource = [Source]
    rngSource.Interior.ColorIndex = xlNone
    intWhatNumber = Val(InputBox("10 ~ 99 사이의 숫자를 입력하세요!", "검색값 입력//By Exceller"))
    '''데이터가 들어있는 부분에 미리 Source라는 이름을 붙여 두었습니다.
    '''워크시트에 이름을 정의해 두면 프로그래밍시 접근하기가 훨씬 용이합니다.
    '''데이터가 있는 부분의 배경색을 지운 다음 사용자로부터 검색할 값을 받습니다.

    If intWhatNumber > 99 Or intWhatNumber < 10 Then
        MsgBox "유효하지 않은 값입니다!", vbCritical, "입력 오류//By Exceller"
        Exit Sub
    End If
    '''10~99 사이의 값만 유효한 것으로 설정합니다.

    For Each rngCell In rngSource
        If rngCell = intWhatNumber Then
            rngCell.Select
            Selection.Interior.ColorIndex = 3
            i = i + 1
        End If
        '''Find라는 메서드(방법)이 없을 경우에는 위와 같이 순환문을 신나게(?) 돌려야
        '''합니다. 그래서 수행 속도가 떨어지게 되는 것이지요.

    Next rngCell
    rngSource.Cells(1).Select
    Msg = Msg & i & " 개의 셀이 발견되었습니다." & vbCr
    Msg = Msg & "작업 소요 시간은 " & Format(Timer - lngStart, "00:00:00") & "초 입니다" & vbCr & vbCr
    Msg = Msg & "이번에는 옆에 있는 ""날쌘돌이"" 버튼을 눌러 시간을 비교해 보세요"
    MsgBox Msg, vbInformation, "작업 완료//By Exceller"
End Sub

이 코드를 아래의 '날쌘돌이' 코드와 비교해 보세요.

Step 3: Find/FindNext로 찾기 (Find_FindNextAccess)

Sub Find_FindNextAccess()
    Dim rngCell As Range, rngSource As Range
    Dim i As Integer, intWhatNumber As Integer
    Dim Msg As String, strAddress As String
    Dim lngStart As Long
    lngStart = Timer
    Set rngSource = [Source]
    rngSource.Interior.ColorIndex = xlNone
    intWhatNumber = Val(InputBox("10 ~ 99 사이의 숫자를 입력하세요!", "검색값 입력//By Exceller"))

    If intWhatNumber > 99 Or intWhatNumber < 10 Then
        MsgBox "유효하지 않은 값입니다!", vbCritical, "입력 오류//By Exceller"
        Exit Sub
    End If
    '''변수를 선언하고, 사용자로 부터 데이터를 받은 다음 유효한 지 여부를 판단하는
    '''과정은 위의 '세월아 네월아' 코드와 같습니다.

    Set rngCell = rngSource.Find(What:=intWhatNumber, LookIn:=xlValues, LookAt:=xlWhole)
    '''여기서부터 차이가 있습니다. Find 메서드를 사용하여 검색 대상 영역 중에서
    '''사용자가 입력한 데이터가 있는 지 파악합니다.

    If Not rngCell Is Nothing Then
        strAddress = rngCell.Address
        '''Not rngCell Is Nothing 이라는 것은 해당되는 데이터가 있다는 의미이지요?
        '''즉 사용자로부터 입력받은 데이터와 같은 것이 있을 경우, 아래로 내려가서
        '''Do~Loop 문을 수행하게 됩니다.

        '''여기서 한 가지 주의할 점!
        '''Find나 FindNext 메서드는 해당 셀의 값이 아닌 Range 오브젝트를 돌려준다는
        '''사실입니다. 따라서 Range 오브젝트 변수의 값을 strAddress라는 문자열
        '''변수에 담아 두었습니다.

        Do
            rngCell.Select
            Selection.Interior.ColorIndex = 4
            i = i + 1
            Set rngCell = rngSource.FindNext(After:=rngCell)
            '''같은 데이터가 계속 있을 경우, FindNext 메서드를 사용하여 계속 검색을
            '''진행 합니다. 언제까지 하느냐 하면 rngCell의 주소가 strAddress 값과
            '''다를 때까지, 그러니까 같은 값이 없을 때 Do~Loop 문을 탈출하게 됩니다.

        Loop While rngCell.Address <> strAddress
    End If
    rngSource.Cells(1).Select
    Msg = Msg & i & " 개의 셀이 발견되었습니다." & vbCr
    Msg = Msg & "작업 소요 시간은 " & Format(Timer - lngStart, "00:00:00") & "초 입니다" & vbCr & vbCr
    MsgBox Msg, vbInformation, "작업 완료//By Exceller"
End Sub

마무리

보신 바와 같이, 어떤 연장을 사용하느냐에 따라 많은 차이가 있습니다. Find/FindNext라는 훌륭한 부하가 있는데 그걸 몰라서 오로지 For~Next 하고만 친하게 지내다 보면 그만큼 경쟁력이 떨어지는 것이지요. 많이 연구해 보세요.

오늘은 여기까지…

정리 — Find 메서드 핵심

자주 묻는 질문 (FAQ)

마치며

Find와 FindNext 메서드를 익혀 두면 대량의 데이터에서도 빠르게 원하는 셀을 찾을 수 있습니다.