특정위치 문자로 정렬하기

Step 1: 이번 시간의 질문

예제를 보내주셨더라면 좋았을 것을… 일단 예제를 하나 만듭니다.

Start 이름은 B23 셀, Result 이름은 E31 셀에 정의되어 있습니다.

Step 2: SortnthLetter 프로시저

코드를 보도록 하지요.

Sub SortnthLetter()
    Dim rngCell As Range
    Dim rngTarget As Range, rngResult As Range
    Dim strCriteria As String
    Dim i As Integer
    Dim blnOK As Boolean
    Set rngTarget = Range([Start], [Start].End(xlDown))
    Set rngResult = [Result]
    '''등장 인물(변수)을 선언해 주고 두 개의 이름을 정의해 두었습니다.
    '''이름 상자에서 Start와 Result가 어느 셀인지 확인해 보세요.

    Do While Not blnOK
        strCriteria = InputBox("제품 유형을 입력하세요!(1~3)", "숫자 입력//By Exceller")
        If IsNumeric(strCriteria) Then
            blnOK = True
        ElseIf strCriteria = "" Then
            MsgBox "아무 것도 입력하지 않으셨으므로 종료합니다", , "작업 종료//By Exceller"
            Exit Sub
        Else
            MsgBox "숫자값을 입력하세요!!!", , "입력 오류//By Exceller"
        End If
        '''Do~Loop 순환문이 사용되었습니다. 만약 사용자가 숫자가 아닌 다른 데이터 타입을
        '''입력하였을 경우, 계속 InputBox를 화면 상에 나타나도록 하기 위한 것입니다.

    Loop

    With rngResult
        .CurrentRegion.ClearContents
        For Each rngCell In rngTarget
            If Mid(rngCell, 2, 1) = strCriteria Then
                .Offset(i, 0) = rngCell
                .Offset(i, 1) = rngCell.Offset(0, 1)
                i = i + 1
            End If
        Next rngCell
        '''사용자가 입력한 조건에 맞는 데이터를 화면 상에 뿌려주는 과정입니다.
        '''별로 어려운 부분이 없으므로 해설은 생략…

    End With

    If Len(rngResult) > 0 Then
        rngResult.CurrentRegion.Sort Key1:=rngResult, Order1:=xlAscending, Header:= _
            xlNo, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
            DataOption1:=xlSortNormal
        MsgBox i & "개의 자료를 추출하였습니다", , "작업 완료//By Exceller"
        '''유효한 데이터가 있을 경우, Sorting을 진행하고 작업이 완료되었음을 알려줍니다.

    End If
End Sub

Step 3: 마무리

원래 만들려고 하였던 것은 데이터 내의 특정한 위치에 있는 문자열을 기준으로 정렬이 되도록 하려고 하였으나 방향을 사정이 여의치 않아 방향을 바꾸었습니다. Exceller는 이번 주 내내 외부 교육 중인데 과중한 숙제(?)로 인하야… T.T

하지만 위의 코드를 약간만 수정하면 충분히 만드실 수 있을 것이므로 직접 만들어 보시기 바랍니다.

오늘은 여기까지…

정리 — 특정 위치 문자 정렬 핵심

자주 묻는 질문 (FAQ)

마치며

Mid 함수로 조건에 맞는 데이터를 추출한 뒤 Sort 메서드를 쓰면 특정 위치 문자 기준 정렬을 구현할 수 있습니다.