엑셀로 못하는게 머야 시리즈(2) - 주소록 관리

Step 1: 이번 시간의 질문

당연히 있겠지요? 버튼을 눌러 예제를 살펴보고 오세요.

Step 2: 버튼 만들기

그럼 만들어 보도록 하지요. (1) '보기-도구 모음-양식'을 선택하여 양식 도구모음이 나타나도록 합니다.

(2) '단추' 아이콘을 클릭하고 적당한 크기로 단추를 하나 그립니다. 한글의 자음이 14개니까 14개의 버튼을 그려야 겠군요. 일일이 그리기가 귀찮으면 복사를 하시든가...

(3) 14개의 버튼을 그리셨으면 각 버튼의 캡션을 ㄱ, ㄴ, ㄷ,... 등과 같이 바꾸어 줍니다.

(4) 이제 각 버튼의 이름을 지어 줍니다. 가, 나, 다,... 하 이런 식으로. 버튼의 이름을 어떻게 지어 주냐구요? 이러면 곤란한데... 버튼을 그린 다음 '이름 상자'에 '가'라고 입력하고 엔터키를 탁 치시면 되지요?

아이엑셀러

Step 3: ConsonantOrderFiltering 프로시저

(5) 14개 버튼에 대해 캡션과 이름 정의가 끝났으면 이제부터 코딩 작업에 들어갑니다. Alt + <F11> 키를 눌러 VB Editor 상태를 만듭니다. '삽입- 모듈' 메뉴를 클릭하여 모듈 시트를 한장 삽입하고 아래와 같은 코드를 작성합니다.

Sub ConsonantOrderFiltering()
    With ActiveSheet
        .[G1:K1].EntireColumn.ClearContents
        '''[G1:K1]은 Range("G1:K1")의 다른 표현입니다.

        Select Case .Buttons(Application.Caller).Caption
            Case "ㄱ"
                Call FilterByConsonant("ㄱ", "가", "깋")
                '''Workplace 시트에 있는 버튼 중 하나를 클릭하면 Application.Caller, 즉
                '''눌려진 버튼의 캡션을 파악합니다. 그래서 ㄱ 버튼이 눌려 졌으면 다른
                ''' 프로시저를 호출합니다. 이 때 앞에 Call이라는 명령어는 아주 예전에
                '''BASIC(Visual Basic 말고) 시절부터 사용되던 것으로 다른 프로시저를
                '''호출한다는 것을 시각적으로 알려주는 단서(Visual Clue)가 되는 것입니다.
                '''생략해도 프로그램의 실행과는 아무 상관이 없습니다. 다만 인수를 넘겨
                '''주지 않을 때에는 그냥 Call FilterByConsonant와 같이 사용하지만 인수를
                '''넘길 때에는 반드시 괄호로 둘러싸 주어야 한다는 점에 주의하세요.

                '''나머지 아래 구문은 같은 내용이 반복되는 것입니다. 어떤 버튼이 선택되어
                '''졌느냐에 따라 넘겨주는 인수의 값이 약간씩 다를 뿐입니다.

            Case "ㄴ"
                Call FilterByConsonant("ㄴ", "나", "닣")
            Case "ㄷ"
                Call FilterByConsonant("ㄷ", "다", "띻")
            Case "ㄹ"
                Call FilterByConsonant("ㄹ", "라", "링")
            Case "ㅁ"
                Call FilterByConsonant("ㅁ", "마", "밓")
            Case "ㅂ"
                Call FilterByConsonant("ㅂ", "바", "삫")
            Case "ㅅ"
                Call FilterByConsonant("ㅅ", "사", "앃")
            Case "ㅇ"
                Call FilterByConsonant("ㅇ", "아", "잏")
            Case "ㅈ"
                Call FilterByConsonant("ㅈ", "자", "찧")
            Case "ㅊ"
                Call FilterByConsonant("ㅊ", "차", "칳")
            Case "ㅋ"
                Call FilterByConsonant("ㅋ", "카", "킿")
            Case "ㅌ"
                Call FilterByConsonant("ㅌ", "타", "팋")
            Case "ㅍ"
                Call FilterByConsonant("ㅍ", "파", "핗")
            Case "ㅎ"
                Call FilterByConsonant("ㅎ", "하", "힣")
            Case Else
                '''Doing Nothing
        End Select
    End With
End Sub

Step 4: FilterByConsonant 프로시저

(6) 위에서 호출한 FilterByConsonant 프로시저를 작성합니다.

Sub FilterByConsonant(strFilter As String, strFirst As String, strSecond As String)
'''위의 프로시저에서 세 개의 변수를 넘겨주었으므로 받을 때도 세 개의 변수를 받습니다.

    Dim rngCell As Range, rngTarget As Range
    Dim r As Integer
    Dim Msg As String
    Set rngTarget = Range([B2], [B2].End(xlDown))
    '''주소록의 이름이 들어있는 부분을 rngTarget이라는 Range 오브젝트로 지정합니다.

    [G7:K7] = Array("NO", "고객명", "주소", "전화번호", "성별")

    For Each rngCell In rngTarget
        Select Case Left(rngCell, 1)
        '''rngTarget 오브젝트 내의 각 셀값을 하나씩 검사하여 지정한 조건을 충족하는
        '''경우에만 아래의 작업을 수행합니다.

            Case strFirst To strSecond
            '''만약 'ㄱ' 버튼을 클릭하였다면 strFirst에는 "가", strSecond 변수에는 "갛"이라는
            '''값이 들어가 있겠지요? 그러므로 rngCell값의 맨 앞 글자값이 가~갛 범위 내에
            '''포함되는 지를 검사하여 조건을 충족하면 소스 테이블 내의 해당 레코드 중에서
            '''다른 필드값을 가져오는 것입니다.

                With [Start]
                    .Offset(r, 0) = rngCell.Offset(0, -1)
                    .Offset(r, 1) = rngCell.Offset(0, 0)
                    .Offset(r, 2) = rngCell.Offset(0, 1)
                    .Offset(r, 3) = rngCell.Offset(0, 2)
                    .Offset(r, 4) = rngCell.Offset(0, 3)
                End With
                r = r + 1
            Case Else
            '''Doing Nothing
        End Select
    Next rngCell
    Msg = Msg & """" & strFilter & """(으)로 시작되는 이름은 모두 " & r & " 명 입니다"
    MsgBox Msg, , "작업 완료//By Exceller"
End Sub

마무리

처음 생각해 내기가 어렵지 그 나머지는 아무 것도 아닙니다. 문제를 구체화, 단순화 시키는 노력들을 많이 해 보시기 바랍니다. 잘 정리된 문제는 반은 해결된 것이지요.

다음 시간에 또...

정리 — 주소록 자음 필터 핵심

자주 묻는 질문 (FAQ)

마치며

문제를 구체화하고 단순화하면 자음 버튼 하나로 이름을 골라 보는 주소록도 간단히 만들 수 있습니다.