사용자정의 메뉴에 대하여

Step 1: 사용자 정의 메뉴란

본론으로 들어가서... 사용자 정의 메뉴에 대해 질문을 해 오신 분이 심심찮게 있으므로 별도의 강좌를 통해 설명을 드릴까 합니다. 유저 인터페이스(User Interface)에는 여러 가지 종류가 있지만 가장 대표적인 것이 대화상자(Dialog Box)와 오늘 설명드릴 메뉴(ToolBar)라고 할 수 있습니다. 앞으로는 메뉴라는 이름 대신에 툴바라고 부르도록 하겠습니다.

엑셀 97버전으로 넘어오면서 기존 버전에 비해 획기적으로 바뀐 점이 많이 있는데 그 중에는 바로 이 사용자 정의 메뉴를 핸들링하는 부분도 포함이 됩니다. 하지만 아직 우리 주변에는 VBA가 무엇인지도 모르고 살아가는 사람이 대부분이지요. 엑셀(그리고 VBA)이 가진 기능을 30%도 제대로 사용하지 못하는 사람들이 그만큼 많다는 얘기입니다. 자기가 가진 것이 무엇인지도 모른 채 남의 것(즉 다른 것)을 탐하는 일은 없어야 할 것입니다(꼭 성경말씀 같지요? ^^)

일단 아래의 버튼을 눌러 보세요.

고개를 약간 돌려 1시 방향을 샥~ 올려다 보면 기본 메뉴 중에서 도움말 메뉴 오른쪽에 '사용자 정의 메뉴(U)'라는 것이 보이실 것입니다. 그것을 눌러 보세요. 하위 메뉴들이 나타나지요? 이번 시간에는 이것을 만들어 보도록 합니다.

Step 2: 메뉴 만들기 (MakeUserDefinedMenu)

Sub MakeUserDefinedMenu()
    Dim cmdBar As CommandBar
    Set cmdBar = CommandBars("worksheet menu bar")
    On Error Resume Next
    '''커맨드바 오브젝트 변수를 선언해 주었습니다.
    '''worksheet menu bar는 내장(built-in) 메뉴바로 워크시트가 활성화되면 화면에
    '''나타나는 메뉴입니다. 만약 차트 메뉴바에 나타나도록 하려면 이 부분을
    '''Set cmdBar = CommandBars("chart menu bar")로 고쳐주시면 되겠습니다.

    cmdBar.Controls("사용자 정의 메뉴(&U)").Delete
    With cmdBar.Controls.Add(Type:=msoControlPopup, Temporary:=True)
    '''동일한 사용자 정의 메뉴가 이미 만들어져 있는지 확인하여 있으면 삭제합니다.
    '''만약 만들어 진 것이 없다면 "사용자 정의 메뉴(U)"라는 메뉴를 만들고 필요한
    '''컨트롤들을 추가합니다. 이 때 메뉴를 선택하면 그에 딸려 있는 하위 메뉴가
    '''나타나는 구조를 가진 메뉴를 팝업(Pop-up) 메뉴라고 부릅니다. 그래서
    '''Type:=msoControlPopup 입니다.
        .Caption = "사용자 정의 메뉴(&U)"
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "사용자 정의 메뉴1"
            .OnAction = "사용자정의메뉴연습"
            .BeginGroup = True
            .FaceId = 31
            '''추가한 하위 메뉴에 대해 캡션과 OnAction(메뉴를 클릭했을 때 실행될
            '''메뉴 지정), BeginGroup, FaceId 속성 등을 지정합니다.

        End With
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "사용자 정의 메뉴2"
            .OnAction = "사용자정의메뉴연습"
        End With
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "사용자 정의 메뉴3"
            .OnAction = "사용자정의메뉴연습"
        End With
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "메뉴 원래대로(&R)"
            .OnAction = "CallReset"
            .FaceId = 37
            .BeginGroup = True
        End With
    End With
    MsgBox "사용자 정의 메뉴가 만들어 졌습니다//By Exceller"
End Sub

하위 메뉴를 선택했을 때 실행되는 프로시저(OnAction)는 다음과 같이 간단하게 만들 수 있습니다.

Sub 사용자정의메뉴연습()
    MsgBox "선택하신 메뉴는 [" & Application.CommandBars.ActionControl.Caption & "] 입니다", , "메뉴 선택//By Exceller"
End Sub

Step 3: 메뉴 원래대로 되돌리기 (CallReset)

'메뉴 원래대로'라는 하위 메뉴를 선택했을 때 추가된 메뉴를 원래 상태로 되돌리기 위한 코드는 아래와 같습니다.

Sub CallReset()
    Dim Msg As String
    Dim cmdBar As CommandBar
    Set cmdBar = CommandBars("worksheet menu bar")

    Msg = "이 작업은 현존하는 사용자 정의 메뉴를 " & vbCr
    Msg = Msg & "Reset시키는 작업이므로 주의를 요합니다. " & vbCr
    Msg = Msg & "정말 계속하시겠습니까?"
    If MsgBox(Msg, vbYesNo, "메뉴 초기화//By Exceller") = vbNo Then Exit Sub
    cmdBar.Reset
End Sub

마무리

사용자 정의 메뉴에 대해서는 좀더 살펴보아야 할 사항이 많으므로 다음 강좌시간에 계속해서 다루도록 하겠습니다.

오늘은 여기까지...

정리 — 사용자 정의 메뉴 핵심

자주 묻는 질문 (FAQ)

마치며

CommandBars와 OnAction을 이해하면 엑셀 메뉴에 원하는 기능을 직접 추가할 수 있습니다.