그림 확대하기

Step 1: 그림 확대하기 (PictureModify)

눌러 보셨지요? 어떤 현상이 생깁니까? 사진을 클릭하면 해당 사진의 크기가 확대될 것입니다. 그런데 일부 사진, 예를 들면 김유신이나 강감찬의 경우, 아래에 있는 사진에 의해 일부가 가려져서 보이지 않지요? 이런 경우에 항상 클릭한 사진이 맨 위에 놓이도록 하고 싶다는 질문입니다. 일단 코드를 보도록 합니다.

Sub PictureModify()
    AttachCode "PictureModify"
    '''AttachCode라는 외부 프로시저를 먼저 호출합니다. 이 프로시저는 Stage 시트에
    '''있는 그림들에 VBA코드를 연결하는 역할을 수행합니다.

    Dim objPic As Object
    Dim i As Integer, j As Integer, k As Integer
    Dim lngHeight As Long, lngWidth As Long
    Dim lngOldHeight As Long, lngOldWidth As Long
    Set objPic = ActiveSheet.DrawingObjects(Application.Caller)
    lngWidth = objPic.Width
    lngHeight = objPic.Height
    lngOldWidth = objPic.Width
    lngOldHeight = objPic.Height
    '''필요한 변수들을 선언해 줍니다. 나중에 그림의 크기를 원래 크기로 만들기 위해
    '''현재의 크기를 변수에 담아 둡니다.

    For i = 1 To 75
        objPic.Width = lngWidth + objPic.Width * i / 100
        objPic.Height = lngHeight + objPic.Height * i / 100
        For k = 1 To 30000: Next k
        '''순환문을 돌면서 그림의 크기를 확대합니다. For k=1 ~ Next k 이 부분은
        '''속도 조절을 위한 것일 뿐, 다른 의미는 없습니다.

    Next i
    MsgBox "그림이 확대되었습니다. 이제 다시 원래 크기로 되돌립니다"
    objPic.Width = lngOldWidth
    objPic.Height = lngOldHeight
    Set objPic = Nothing
    '''그림을 원래 크기로 되돌리고 오브젝트 변수를 초기화 시킵니다.
End Sub

Step 2: 클릭한 그림을 맨 앞으로 (PictureModify2)

이제 아래의 버튼을 다시 눌러서 좀전에 가려졌던 그림들이 제대로 나타나는지 확인해 보세요.

Sub PictureModify2()
    AttachCode "PictureModify2"
    Dim objPic As Object
    Dim i As Integer, j As Integer, k As Integer
    Dim lngHeight As Long, lngWidth As Long
    Dim lngOldHeight As Long, lngOldWidth As Long
    Set objPic = ActiveSheet.DrawingObjects(Application.Caller)
    lngWidth = objPic.Width
    lngHeight = objPic.Height
    lngOldWidth = objPic.Width
    lngOldHeight = objPic.Height

    For i = 1 To 75
        objPic.Width = lngWidth + objPic.Width * i / 100
        objPic.Height = lngHeight + objPic.Height * i / 100
        For k = 1 To 30000: Next k
        objPic.ShapeRange.ZOrder msoBringToFront
        '''다른 부분은 똑같고 이 한 줄이 추가되었습니다. 말 그대로 현재 선택된 그림을
        '''Bring To Front, 즉 맨 앞으로 가져오는 것입니다.

    Next i
    MsgBox "그림이 확대되었습니다. 이제 다시 원래 크기로 되돌립니다"
    objPic.Width = lngOldWidth
    objPic.Height = lngOldHeight
    Set objPic = Nothing
End Sub

Step 3: 그림에 코드 연결하기 (AttachCode)

두 프로시저가 호출하는 AttachCode는 Stage 시트에 있는 그림들에 매크로를 연결해 주는 프로시저입니다.

Sub AttachCode(strMacro As String)
    Dim objPic As Object
    For Each objPic In Sheets("Stage").Pictures
        objPic.OnAction = strMacro
    Next objPic
End Sub

마무리

많이 응용해 보시기 바랍니다. 다음 주에는 Exceller가 머얼~리 출장을 갑니다. 가깝고도 먼 나라로... 해서 강좌를 진행할 수 없을 것 같습니다.

다음 시간에 또...

정리 — 그림 확대 핵심

자주 묻는 질문 (FAQ)

마치며

ZOrder와 Application.Caller를 활용하면 클릭한 그림을 맨 앞으로 가져와 자연스럽게 확대하는 효과를 낼 수 있습니다.