억세스파일 불러오기

Step 1: 예제 준비

어짜피 억세스 DB(즉 MDB) 파일의 구조를 파악하시려면 ACCESS가 있어야 합니다만, 일단 만들어 보도록 하지요. 아래의 버튼을 누르세요. 이번 강좌는 두 개의 파일로 이루어져 있습니다. 파일의 압축을 풀 때, MyMDB.mdb 파일을 반드시 같은 폴더에 푸시기 바랍니다. 그리고 MDB 파일이 같은 폴더에 있는데도 오류가 발생하는 경우에는 VB Editor 상태에서 '도구-참조' 메뉴를 선택하신 다음 'Microsoft DAO X.XX Object Library' 항목에 체크를 해 주시기 바랍니다.

1초도 안 걸리지요? 오늘 강좌는 데이터베이스에 대한 기본 개념과 DAO에 대해 알고있어야 하므로 이제 VBA에 맛을 들이기 시작한 분은 그냥 그런 것이 있구나 하는 정도만 이해하고 넘어 가시기 바랍니다. 코드를 보면...

Step 2: TableImport 프로시저

Sub TableImport()
    Dim dbsMyDB As DAO.Database
    Dim rstMyRST As DAO.Recordset
    '''초장부터 해괴한 것들(?)이 나왔지요? 사실은 해괴한 것들이 아니고 아주 기특한
    '''것들 입니다. 데이터베이스에 접근하기 위해 DAO(Data Access Object)라고 하는
    '''녀석들의 힘을 빌리기 위한 것입니다.
    '''지정한 쿼리 테이블이나 피벗 테이블 캐시에 대한 데이터 원본으로 사용되는
    '''Recordset 개체를 설정하거나 반환합니다

    Dim i As Integer, intNum As Integer
    On Error GoTo ET
    Set dbsMyDB = OpenDatabase _
    (ThisWorkbook.Path & Application.PathSeparator & "MyMDB.mdb")
    Set rstMyRST = dbsMyDB.openrecordset("Customer")
    '''사용하는 단어만 약간 다를뿐, 기본적인 문법이나 어순(?)은 엑셀에 있는 VBA나
    '''거의 같습니다.

    Worksheets.Add after:=Sheets(1)
    For i = 0 To rstMyRST.Fields.Count - 1
        ActiveSheet.Cells(1, i + 1) = rstMyRST.Fields(i).Name
    Next i
    '''워크시트를 한장 삽입한 다음 MDB 테이블의 필드명을 새로운 시트의 A1 셀부터
    '''차례로 적어 나갑니다.

    With ActiveSheet.Range("a2")
        .CopyFromRecordset rstMyRST
        .CurrentRegion.Columns.AutoFit
        .AutoFormat Format:=xlRangeAutoFormatList1, Number:=True, Font:= _
            True, Alignment:=True, Border:=True, Pattern:=True, Width:=True
        '''CopyFromRecordset 메서드는 ADO(DAO의 아들뻘!)나 DAO Recordset 개체의
        '''내용을 워크시트에 있는 지정된 범위의 왼쪽 위 모서리부터 붙여넣는 역할을
        '''수행합니다.
        '''그런다음 워크시트 전체의 열 너비를 맞추어 주고 자동서식을 적용합니다.

    End With
    intNum = rstMyRST.RecordCount
    MsgBox "총 " & intNum & " 개의 레코드를 복사하였습니다", , "작업 완료//By Exceller"
    '''몇 개의 레코드가 있는지 Recordset 개체의 수를 카운팅하여 메시지 박스에
    '''나타내 줍니다.

    rstMyRST.Close
    dbsMyDB.Close
    '''작업이 끝나면 Recordset 개체와 Database를 닫습니다.

    Exit Sub
ET:     MsgBox "MDB 파일이 없습니다. 확인하세요", , "파일 경로 확인//By Exceller"
End Sub

마무리

몇 가지 생소한 단어가 나와서 그렇지 문법 구조 자체는 그다지 어려운 것이 없을 것입니다. VBA와 DAO만 알면 이렇게 간단하게 해결이 됩니다.

물론 이렇게 하지 않고 억세스의 데이터를 복사한 다음 엑셀로 와서 붙여넣기를 해도 됩니다. 시간이 남아 돌아서 감당하기 힘든 분이라면... ^^

다음 시간에 또...

정리 — Access 불러오기 핵심

자주 묻는 질문 (FAQ)

마치며

DAO와 CopyFromRecordset을 활용하면 Access 테이블의 데이터를 간단한 코드로 엑셀에 불러올 수 있습니다.