조건을 충족하는 모든 데이터 추출하기

Step 1: 예제 보기

예제를 보도록 하지요. 아래 버튼을 누르세요.

호수를 입력하면 FilterSheet 시트에 해당 호수의 고지서 내역이 아래와 같은 형태로 만들어집니다.

Step 2: MakeDigest 프로시저

코드는 아래와 같습니다. 시간이 없어서 최적화를 하지 못했습니다. 별로 마음에 드는 코드는 아니지만 방법을 이해하신 다음 직접 Optimizing을 시켜 보도록 하세요. 남이 짠 코드를 내 것으로 만드는 확실한 방법은 이렇게 저렇게 응용해 보는 것입니다.

Sub MakeDigest()
    Dim strName As String
    Dim shtSource As Worksheet, shtFilter As Worksheet
    Dim rngData As Range
    Dim i As Integer, intNum As Integer
    Set shtSource = Sheets("Source")
    Set shtFilter = Sheets("FilterSheet")

    shtFilter.Cells.ClearContents
    strName = InputBox("호수를 입력하세요", "호수 입력//By Exceller")
    If Len(strName) <> 3 Then
        MsgBox """호수를"" 확인하세요!", , "호수 입력 오류//By Exceller"
        Exit Sub
    End If
    '''어느 호수를 출력할 것인지 사용자로부터 자료를 입력받습니다. 만약 유효하지 않은 값이
    '''입력되면 프로그램을 종료합니다.

    Set rngData = shtSource.[A1].CurrentRegion
    shtSource.AutoFilterMode = False
    rngData.AutoFilter Field:=1, Criteria1:=strName
    '''이 작업을 수행하기 위해 자동 필터를 사용했습니다. 따라서 필터링이 이미 되어 있을지도
    '''모르므로 일단 해제를 해 준 다음 1열, 즉 호수를 기준으로 자동 필터링을 합니다. 필터링할
    '''기준은 사용자로부터 입력받은 strName입니다.

    rngData.SpecialCells(xlCellTypeVisible).Copy shtFilter.Cells(7, 1)
    shtSource.AutoFilterMode = False
    '''필터링된 데이터, 즉 조건을 충족하는 데이터들만 복사를 합니다. 그리고 나서 자동 필터를
    '''다시 원상복구 시킵니다.

    Application.Goto shtFilter.Range("a1"), True

    '''아래 부분은 코드는 길어 보입니다만 FilterSheet에 원하는 형태로 자료를 출력하기 위한
    '''것입니다. 셀에 값을 기입하고 데이터를 원하는 형태로 만듭니다.
    With shtFilter
        .Range("a3") = "호수"
        .Range("a4") = "성명"
        .Range("a5") = "주소"
        .Range("b3") = strName
        .Range("b4") = .Range("a8").Offset(0, 1).Value
        .Range("b5") = .Range("a8").Offset(0, 2).Value
        .Range("a7") = "일련번호"

        If .Cells(.Rows.Count, 4).End(xlUp).Row >= 8 Then
            .Range(.Range("d7"), .Cells(.Cells(.Rows.Count, 4).End(xlUp).Row, 7)).Cut .Range("b7")
        End If
        intNum = Application.CountA(.Range("c:c")) - 1

        If intNum = 0 Then
            MsgBox "조건에 해당되는 자료가 없습니다."
            Exit Sub
        End If
        '''만약 해당 데이터가 한 건도 없다면 메시지 박스를 보여주고 종료합니다.
        '''데이터가 있을 경우에는 For ~ Next 문을 사용하여 셀에 하나씩 뿌려 줍니다.

        For i = 1 To intNum
            .Cells(7 + i, 1) = i
        Next i
        .Range("a1").Select
    End With
    MsgBox "총 " & intNum & " 건의 자료가 추출되었습니다!", , "작업 완료//By Exceller"
End Sub

마무리

생각보다 간단하지요? 이 코드는 수정해야 할 부분이 많이 있습니다. 잘 살펴 보시고 어떤 부분들을 더 추가해 주면 좋을지 직접 해 보시기 바랍니다. 좋은 생각들이 떠오르면 메일을 주시기 바랍니다. 아니면 코드를 직접 수정해서 보내 주시든가...

만약 질문이 없으면 구렁이 담넘어가듯 스을~쩍 넘어가 버릴지도 모릅니다. ^^

다음 시간에...

정리 — 조건 데이터 추출 핵심

자주 묻는 질문 (FAQ)

마치며

자동 필터와 보이는 셀 복사를 활용하면 조건에 맞는 모든 데이터를 원하는 양식으로 쉽게 추출할 수 있습니다.