짝수 페이지 데이터 이동시키기

Step 1: 실행 결과

세로로 배치되어 있던 6 페이지가 가로 방향 3페이지로 줄어들었지요?

Step 2: MoveEvenPage 프로시저

코드를 보면...

Sub MoveEvenPage()
    Dim lngRow() As Long
    Dim intPage As Integer
    Dim i As Integer
    On Error GoTo ET
    '''변수를 선언해 줍니다. lngRow()라는 동적 배열 변수는 현재 시트의 각 페이지가
    '''시작되는 행 번호를 담아두기 위한 것입니다.

    Call GoToStage
    '''Stage 시트로 이동하기 위한 프로시저를 호출합니다.

    With Application
        .Cursor = xlWait
        .StatusBar = "Moving... "
        .ScreenUpdating = False
    End With
    '''작업을 진행하는 동안 커서의 모양을 모래시계 모양으로 설정하고 상태 표시줄에
    '''메시지를 표시합니다. 그리고 작업 도중 화면 갱신을 하지 않습니다. 그래야
    '''작업 시간이 조금이나마 단축됩니다.

    ActiveWindow.View = xlPageBreakPreview
    intPage = ActiveSheet.HPageBreaks.Count + 1
    ReDim lngRow(1 To intPage + 1)
    '''페이지 나누기 미리 보기 상태로 전환하여 몇 개의 페이지로 구성되어 있는지를
    '''파악합니다. 그런 다음 동적 배열 변수의 크기를 확정합니다.

    lngRow(1) = 1
    For i = 2 To intPage
        lngRow(i) = ActiveSheet.HPageBreaks(i - 1).Location.Row
    Next i
    lngRow(intPage + 1) = ActiveSheet.UsedRange.Row + ActiveSheet.UsedRange.Rows.Count
    '''순환문을 돌면서 수평 페이지 나누기가 된 행 번호를 동적 배열 변수에 하나씩
    '''담아 둡니다.

    For i = 2 To intPage Step 2
        Range("A" & lngRow(i) & ":C" & lngRow(i + 1) - 1).Copy
        Range("E" & lngRow(i - 1)).PasteSpecial xlPasteAll
    Next i
    '''짝수 번째 페이지에 있는 내용들을 복사하여 바로 앞 홀수 페이지의 오른쪽에
    '''붙여 넣습니다. 2페이지는 1페이지 옆에, 4페이지는 3페이지 옆에 놓이는 셈입니다.

    For i = intPage - (intPage Mod 2) To 2 Step -2
        Rows(lngRow(i) & ":" & lngRow(i + 1) - 1).Delete
    Next i
    Application.CutCopyMode = False
    '''붙여 넣기를 하였으면 원래의 짝수 페이지 데이터는 삭제합니다. 아래쪽부터 지워야
    '''앞쪽 페이지의 행 번호가 바뀌지 않습니다.

    ActiveWindow.View = xlNormalView
    '''화면을 기본보기 상태로 되돌립니다.
    '''아래 부분은 에러가 발생했을 경우 에러를 처리하기 위한 부분과 커서모양,
    '''화면 갱신 여부 등을 원래 상태로 되돌려 놓습니다.

ET:
    If Err > 0 Then
        MsgBox Err.Description, vbInformation, "에러 발생//By Exceller"
    Else
        MsgBox "데이터 이동작업이 완료되었습니다", vbInformation, "작업 완료//By Exceller"
    End If

    With Application
        .StatusBar = False
        .Cursor = xlDefault
        .ScreenUpdating = True
    End With
End Sub

Sub GoToStage()
    Worksheets("Stage").Select
End Sub

마무리

많이들 응용해 보시기 바랍니다.

다음 시간에...

정리 — 페이지 이동 핵심

자주 묻는 질문 (FAQ)

마치며

페이지 나누기 위치를 배열에 담아 두면 세로로 늘어선 데이터를 원하는 모양으로 다시 배치할 수 있습니다.